Use getopt-long on non-linux systems (bug #409811, thanks to Stuart Shelton, Fabian Groffen, Naohiro Aota).

(Portage version: 2.2.0_alpha120/cvs/Linux x86_64)

2 files changed, 59 insertions, 1 deletions

diff --git a/app-text/rarian/ChangeLog b/app-text/rarian/ChangeLog
index 0ab0ce26842a..9c17c4f08581 100644
--- a/app-text/rarian/ChangeLog
+++ b/app-text/rarian/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-text/rarian
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-text/rarian/ChangeLog,v 1.54 2012/04/30 19:04:11 grobian Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-text/rarian/ChangeLog,v 1.55 2012/08/08 18:32:12 tetromino Exp $
+
+*rarian-0.8.1-r2 (08 Aug 2012)
+
+  08 Aug 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +rarian-0.8.1-r2.ebuild:
+  Use getopt-long on non-linux systems (bug #409811, thanks to Stuart Shelton,
+  Fabian Groffen, Naohiro Aota).
 
   30 Apr 2012; Fabian Groffen <grobian@gentoo.org> rarian-0.8.1-r1.ebuild:
   Fix for Prefix, add Prefix keywords
diff --git a/app-text/rarian/rarian-0.8.1-r2.ebuild b/app-text/rarian/rarian-0.8.1-r2.ebuild
new file mode 100644
index 000000000000..756742ad3d06
--- /dev/null
+++ b/app-text/rarian/rarian-0.8.1-r2.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/rarian/rarian-0.8.1-r2.ebuild,v 1.1 2012/08/08 18:32:12 tetromino Exp $
+
+EAPI=4
+
+inherit eutils libtool
+
+DESCRIPTION="A documentation metadata library"
+HOMEPAGE="http://rarian.freedesktop.org/"
+SRC_URI="http://${PN}.freedesktop.org/Releases/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="dev-libs/libxslt
+	|| ( sys-apps/util-linux app-misc/getopt )"
+DEPEND="${RDEPEND}
+	!<app-text/scrollkeeper-9999"
+
+DOCS=( ChangeLog NEWS README )
+
+src_prepare() {
+	# Fix uri of omf files produced by rarian-sk-preinstall, see bug #302900
+	epatch "${FILESDIR}/${P}-fix-old-doc.patch"
+
+	# remove unneeded line, bug #240564
+	sed "s/ (foreign dist-bzip2 dist-gzip)//" -i configure || die "sed failed"
+
+	# bug #409811, https://bugs.freedesktop.org/show_bug.cgi?id=53264
+	# sed to avoid autoreconf
+	if ! has_version sys-apps/util-linux; then
+		sed -e 's/getopt -/getopt-long -/' \
+			-i util/rarian-sk-update.in || die "sed 2 failed"
+	fi
+
+	elibtoolize ${ELTCONF}
+}
+
+src_configure() {
+	econf \
+		--localstatedir="${EPREFIX}"/var \
+		$(use_enable static-libs static)
+}
+
+src_install() {
+	default
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}