New version (#107289). Add support for translations.

(Portage version: 2.0.51.22-r3)

1 files changed, 82 insertions, 0 deletions

diff --git a/app-text/bibletime/bibletime-1.5.1.ebuild b/app-text/bibletime/bibletime-1.5.1.ebuild
new file mode 100644
index 000000000000..5b1804770cd1
--- /dev/null
+++ b/app-text/bibletime/bibletime-1.5.1.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2005 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-text/bibletime/bibletime-1.5.1.ebuild,v 1.1 2005/10/11 12:42:06 greg_g Exp $
+
+inherit kde eutils
+
+DESCRIPTION="KDE Bible study application using the SWORD library."
+HOMEPAGE="http://www.bibletime.info/"
+SRC_URI="mirror://sourceforge/bibletime/${P}.tar.bz2"
+LICENSE="GPL-2"
+
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND=">=app-text/sword-1.5.8"
+
+LANGS="af bg cs da de en_GB es fi fr hu it ko nl nn_NO no pl pt_BR ro ru sk ua"
+LANGS_DOC="bg cs de fi fr it ko nl pt_BR ru"
+
+for X in ${LANGS}; do
+	SRC_URI="${SRC_URI} linguas_${X}? ( mirror://sourceforge/bibletime/${PN}-i18n-${PV}.tar.bz2 )"
+done
+
+need-kde 3
+
+pkg_setup() {
+	if ! built_with_use app-text/sword curl; then
+		echo
+		ewarn "The SWORD library may not have been compiled with curl support."
+		ewarn "If you wish to use BibleTime's ability to download modules"
+		ewarn "straight from the SWORD website, please make sure app-text/sword"
+		ewarn "was compiled with USE=\"curl\"."
+		ewarn "Press ctrl+c to abort the merge of BibleTime if you want to"
+		ewarn "recompile SWORD with curl support."
+		echo
+		ebeep 5
+	fi
+}
+
+src_unpack() {
+	kde_src_unpack
+
+	local MAKE_LANGS MAKE_LANGS_DOC
+	for X in ${LANGS}; do
+		use linguas_${X} && MAKE_LANGS="${MAKE_LANGS} ${X/pt_BR/pt_br}.po"
+	done
+	for X in ${LANGS_DOC}; do
+		use linguas_${X} && MAKE_LANGS_DOC="${MAKE_LANGS_DOC} ${X/pt_BR/pt-br}"
+	done
+
+	if [ -d "${WORKDIR}/${PN}-i18n-${PV}" ]; then
+		cd ${WORKDIR}/${PN}-i18n-${PV}/
+		sed -i -e "s,^POFILES.*,POFILES = ${MAKE_LANGS}," po/Makefile.am
+		sed -i -e "s,^SUBDIRS.*,SUBDIRS = ${MAKE_LANGS_DOC}," docs/Makefile.am
+		make -f admin/Makefile.common || die
+	fi
+}
+
+src_compile() {
+	kde_src_compile
+
+	local _S="${S}"
+	if [ -d "${WORKDIR}/${PN}-i18n-${PV}" ]; then
+		S="${WORKDIR}/${PN}-i18n-${PV}"
+		cd "${S}"
+		kde_src_compile
+	fi
+	S="${_S}"
+}
+
+src_install() {
+	kde_src_install
+
+	local _S="${S}"
+	if [ -d "${WORKDIR}/${PN}-i18n-${PV}" ]; then
+		S="${WORKDIR}/${PN}-i18n-${PV}"
+		cd "${S}"
+		kde_src_install
+	fi
+	S="${_S}"
+}