Version bump to development release in order to get rid of the media-libs/libmp4v2 dependency problem.

(Portage version: 2.2.0_alpha109/cvs/Linux x86_64)

2 files changed, 106 insertions, 1 deletions

diff --git a/app-pda/gtkpod/ChangeLog b/app-pda/gtkpod/ChangeLog
index ef0920e950ed..9017e03c74aa 100644
--- a/app-pda/gtkpod/ChangeLog
+++ b/app-pda/gtkpod/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-pda/gtkpod
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v 1.104 2012/05/10 07:25:01 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/ChangeLog,v 1.105 2012/06/07 00:35:44 ssuominen Exp $
+
+*gtkpod-2.1.2_beta2 (07 Jun 2012)
+
+  07 Jun 2012; Samuli Suominen <ssuominen@gentoo.org>
+  +gtkpod-2.1.2_beta2.ebuild:
+  Version bump to development release in order to get rid of the
+  media-libs/libmp4v2 dependency problem.
 
   10 May 2012; Samuli Suominen <ssuominen@gentoo.org> -gtkpod-2.1.1-r2.ebuild:
   old
diff --git a/app-pda/gtkpod/gtkpod-2.1.2_beta2.ebuild b/app-pda/gtkpod/gtkpod-2.1.2_beta2.ebuild
new file mode 100644
index 000000000000..423b1aed74f2
--- /dev/null
+++ b/app-pda/gtkpod/gtkpod-2.1.2_beta2.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/gtkpod/gtkpod-2.1.2_beta2.ebuild,v 1.1 2012/06/07 00:35:44 ssuominen Exp $
+
+EAPI=4
+inherit eutils gnome2-utils
+
+DESCRIPTION="A graphical user interface to the Apple productline"
+HOMEPAGE="http://gtkpod.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P/_/-}.tar.gz"
+
+LICENSE="GPL-2 FDL-1.2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="aac clutter curl cdr flac gstreamer mp3 vorbis webkit"
+
+COMMON_DEPEND="dev-libs/gdl:3
+	>=dev-libs/glib-2.28.5
+	>=dev-libs/libxml2-2.7.7
+	>=dev-util/anjuta-2.91
+	>=media-libs/libgpod-0.7.0
+	>=media-libs/libid3tag-0.15
+	>=x11-libs/gtk+-3.0.8:3
+	aac? ( media-libs/faad2 )
+	clutter? ( media-libs/clutter-gtk:1.0 )
+	curl? ( >=net-misc/curl-7.10 )
+	cdr? (
+		>=app-cdr/brasero-3
+		media-libs/musicbrainz:3
+		)
+	flac? ( media-libs/flac )
+	gstreamer? ( >=media-libs/gst-plugins-base-0.10.25:0.10 )
+	mp3? ( media-sound/lame )
+	vorbis? (
+		media-libs/libvorbis
+		media-sound/vorbis-tools
+		)
+	webkit? ( >=net-libs/webkit-gtk-1.3:3 )"
+RDEPEND="${COMMON_DEPEND}
+	gstreamer? ( media-plugins/gst-plugins-meta:0.10 )"
+DEPEND="${COMMON_DEPEND}
+	dev-util/intltool
+	sys-devel/flex
+	sys-devel/gettext
+	virtual/os-headers
+	virtual/pkgconfig"
+
+# Dpn't even try to bother with versionator.eclass for this one beta exception.
+S=${WORKDIR}/${PN}-2.1.2~bafd316
+
+src_prepare() {
+	# Make sure SLOT="4" is not used. Everyone should move from "3" to "5" directly.
+	sed -i -e '/PKG_CONFIG/s:libmusicbrainz4:&sLoT4iSdEpReCaTeD:' configure || die
+
+	# /path/to/install: '/path/to/app-pda/gtkpod-2.1.2_beta2/image/usr/share/gtkpod/data/rhythmbox.gep’: File exists
+	sed -i -e '/^dist_profiles_DATA/s:=.*:=:' plugins/sjcd/data/Makefile.in || die
+}
+
+src_configure() {
+	econf \
+		--disable-static \
+		$(use_enable webkit plugin-coverweb) \
+		$(use_enable clutter plugin-clarity) \
+		$(use_enable gstreamer plugin-media-player) \
+		$(use_enable cdr plugin-sjcd) \
+		$(use_with curl) \
+		$(use_with vorbis ogg) \
+		$(use_with flac) \
+		$(use_with aac mp4)
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		docdir=/usr/share/doc/${PF}/html \
+		figuresdir=/usr/share/doc/${PF}/html/figures \
+		install
+
+	dodoc AUTHORS ChangeLog NEWS README TODO TROUBLESHOOTING
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+	rm -f "${ED}"/usr/share/gtkpod/data/{AUTHORS,COPYING}
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+	gnome2_schemas_savelist
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}