Version bump wrt #467914 by Chris Slycord

(Portage version: 2.2.0_alpha174/cvs/Linux x86_64, signed Manifest commit with key 4868F14D)

1 files changed, 57 insertions, 0 deletions

diff --git a/app-pda/libimobiledevice/libimobiledevice-1.1.5.ebuild b/app-pda/libimobiledevice/libimobiledevice-1.1.5.ebuild
new file mode 100644
index 000000000000..36a8cfc91280
--- /dev/null
+++ b/app-pda/libimobiledevice/libimobiledevice-1.1.5.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-pda/libimobiledevice/libimobiledevice-1.1.5.ebuild,v 1.1 2013/05/11 21:57:49 ssuominen Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_7 )
+inherit autotools eutils python-r1 multilib
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="http://www.libimobiledevice.org/"
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="0/4"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86"
+IUSE="gnutls python"
+
+RDEPEND=">=app-pda/libplist-1.10[python?,${PYTHON_USEDEP}]
+	>=app-pda/usbmuxd-1.0.8
+	gnutls? (
+		dev-libs/libgcrypt
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0
+		)
+	!gnutls? ( dev-libs/openssl:0 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? (
+		${PYTHON_DEPS}
+		>=dev-python/cython-0.17[${PYTHON_USEDEP}]
+		)"
+
+DOCS=( AUTHORS NEWS README )
+
+pkg_setup() {
+	# Prevent linking to the installed copy
+	if has_version "<${CATEGORY}/${P}"; then
+		rm -f "${EROOT}"/usr/$(get_libdir)/${PN}$(get_libname)
+	fi
+}
+
+src_configure() {
+	use python && python_export_best
+
+	local myconf
+	use gnutls && myconf='--disable-openssl'
+	use python || myconf+=' --without-cython'
+
+	econf --disable-static ${myconf}
+}
+
+src_install() {
+	default
+	dohtml docs/html/*
+
+	prune_libtool_files --all
+}