Version bump. Fix dependency on rdtool to match emacs USE flag, fixing bug 426924.

(Portage version: 2.1.10.65/cvs/Linux x86_64)

2 files changed, 83 insertions, 1 deletions

diff --git a/app-office/rabbit/ChangeLog b/app-office/rabbit/ChangeLog
index c9d9759db8ce..2635b3c471f9 100644
--- a/app-office/rabbit/ChangeLog
+++ b/app-office/rabbit/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/rabbit
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/rabbit/ChangeLog,v 1.18 2012/06/16 16:35:04 ssuominen Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/rabbit/ChangeLog,v 1.19 2012/07/20 18:55:01 graaff Exp $
+
+*rabbit-1.0.8 (20 Jul 2012)
+
+  20 Jul 2012; Hans de Graaff <graaff@gentoo.org> +rabbit-1.0.8.ebuild:
+  Version bump. Fix dependency on rdtool to match emacs USE flag, fixing bug
+  426924.
 
   16 Jun 2012; Samuli Suominen <ssuominen@gentoo.org> rabbit-0.9.2.ebuild,
   rabbit-1.0.6.ebuild, metadata.xml:
diff --git a/app-office/rabbit/rabbit-1.0.8.ebuild b/app-office/rabbit/rabbit-1.0.8.ebuild
new file mode 100644
index 000000000000..2335479c8af0
--- /dev/null
+++ b/app-office/rabbit/rabbit-1.0.8.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/rabbit/rabbit-1.0.8.ebuild,v 1.1 2012/07/20 18:55:01 graaff Exp $
+
+EAPI=4
+USE_RUBY="ruby18"
+
+inherit ruby-ng elisp-common eutils
+
+DESCRIPTION="An application to do presentation with RD document"
+HOMEPAGE="http://rabbit-shockers.org/"
+SRC_URI="http://rabbit-shockers.org/download/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="nls migemo tgif enscript emacs markdown postscript"
+
+CDEPEND="emacs? ( virtual/emacs )"
+DEPEND="${DEPEND} ${CDEPEND}"
+RDEPEND="${RDEPEND} ${CDEPEND}
+	nls? ( dev-ruby/ruby-gettext )
+	postscript? ( app-text/ghostscript-gpl )
+	migemo? ( app-text/migemo )
+	enscript? ( app-text/enscript )
+	tgif? ( media-gfx/tgif )"
+
+ruby_add_rdepend "
+	>=dev-ruby/coderay-1.0.0
+	>=dev-ruby/ruby-gdkpixbuf2-0.15.0
+	dev-ruby/ruby-gtk2
+	dev-ruby/ruby-poppler
+	>=dev-ruby/ruby-rsvg-1.0.3
+	dev-ruby/rdtool[emacs?]
+	dev-ruby/haml
+	markdown? ( dev-ruby/kramdown )
+	dev-ruby/sinatra
+	enscript? ( dev-ruby/nokogiri )
+	emacs? ( dev-ruby/nokogiri ) "
+
+each_ruby_configure() {
+	${RUBY} setup.rb config --prefix=/usr || die
+	${RUBY} setup.rb setup || die
+}
+
+all_ruby_compile() {
+	if use emacs; then
+		cd "${S}/misc/emacs"
+		elisp-compile rabbit-mode.el
+	fi
+}
+
+each_ruby_install() {
+	${RUBY} setup.rb install --prefix="${D}"
+}
+
+all_ruby_install() {
+	dodoc -r doc
+
+	insinto /usr/share/doc/${PF}
+	doins -r sample
+
+	if use emacs; then
+		cd "${S}/misc/emacs"
+		elisp-install rabbit-mode rabbit-mode.el{,c}
+		elisp-site-file-install "${FILESDIR}/50rabbit-mode-gentoo.el"
+	fi
+}
+
+pkg_postinst() {
+	use emacs && elisp-site-regen
+}
+
+pkg_postrm() {
+	use emacs && elisp-site-regen
+}