Version bump wrt bug #530794.

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 0x06B1F38DCA45A1EC!)

2 files changed, 74 insertions, 1 deletions

diff --git a/app-office/kmymoney/ChangeLog b/app-office/kmymoney/ChangeLog
index abc75ab247a2..b317e14642e2 100644
--- a/app-office/kmymoney/ChangeLog
+++ b/app-office/kmymoney/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/kmymoney
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/kmymoney/ChangeLog,v 1.53 2014/06/22 18:01:30 kensington Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/kmymoney/ChangeLog,v 1.54 2014/11/27 07:51:24 kensington Exp $
+
+*kmymoney-4.7.1 (27 Nov 2014)
+
+  27 Nov 2014; Michael Palimaka <kensington@gentoo.org> +kmymoney-4.7.1.ebuild:
+  Version bump wrt bug #530794.
 
 *kmymoney-4.6.6 (22 Jun 2014)
 
diff --git a/app-office/kmymoney/kmymoney-4.7.1.ebuild b/app-office/kmymoney/kmymoney-4.7.1.ebuild
new file mode 100644
index 000000000000..e08bf9037243
--- /dev/null
+++ b/app-office/kmymoney/kmymoney-4.7.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/kmymoney/kmymoney-4.7.1.ebuild,v 1.1 2014/11/27 07:51:24 kensington Exp $
+
+EAPI=5
+
+KDE_LINGUAS="bs ca ca@valencia cs da de el en_GB es et eu fi fr gl
+hu it kk nds nl pl pt pt_BR ro ru sv uk zh_TW"
+KDE_HANDBOOK="optional"
+VIRTUALX_REQUIRED="test"
+VIRTUALDBUS_TEST="true"
+inherit kde4-base
+
+DESCRIPTION="Personal finance manager for KDE"
+HOMEPAGE="http://kmymoney2.sourceforge.net/"
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/src/${P}.tar.xz"
+fi
+
+LICENSE="GPL-2"
+SLOT="4"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug calendar doc hbci ofx quotes"
+
+COMMON_DEPEND="
+	app-crypt/gpgme
+	>=app-office/libalkimia-4.3.2
+	dev-libs/gmp:0
+	dev-libs/libgpg-error
+	$(add_kdebase_dep kdepimlibs)
+	x11-misc/shared-mime-info
+	calendar? ( dev-libs/libical:= )
+	hbci? (
+		>=net-libs/aqbanking-5.0.1
+		>=sys-libs/gwenhywfar-4.0.1[qt4]
+	)
+	ofx? ( >=dev-libs/libofx-0.9.4 )
+"
+RDEPEND="${COMMON_DEPEND}
+	quotes? ( dev-perl/Finance-Quote )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-libs/boost
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_QT_DESIGNER=OFF
+		$(cmake-utils_use_enable calendar LIBICAL)
+		$(cmake-utils_use_use doc DEVELOPER_DOC)
+		$(cmake-utils_use_enable hbci KBANKING)
+		$(cmake-utils_use_enable ofx LIBOFX)
+	)
+	kde4-base_src_configure
+}
+
+src_compile() {
+	kde4-base_src_compile
+
+	use doc && kde4-base_src_compile apidoc
+}
+
+src_install() {
+	use doc && HTML_DOCS=("${BUILD_DIR}/apidocs/html/")
+	kde4-base_src_install
+}