Version bump, bug #411401. Add myself to maintainers.

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key C6085806)

3 files changed, 97 insertions, 18 deletions

diff --git a/app-office/gtg/ChangeLog b/app-office/gtg/ChangeLog
index 3eab9ddf7785..fc14f289cc3b 100644
--- a/app-office/gtg/ChangeLog
+++ b/app-office/gtg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-office/gtg
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/gtg/ChangeLog,v 1.13 2013/02/03 13:21:53 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/gtg/ChangeLog,v 1.14 2013/02/04 23:16:31 eva Exp $
+
+*gtg-0.3 (04 Feb 2013)
+
+  04 Feb 2013; Gilles Dartiguelongue <eva@gentoo.org> +gtg-0.3.ebuild,
+  metadata.xml:
+  Version bump, bug #411401. Add myself to maintainers.
 
   03 Feb 2013; Pacho Ramos <pacho@gentoo.org> metadata.xml:
   Cleanup after talking with leio
diff --git a/app-office/gtg/gtg-0.3.ebuild b/app-office/gtg/gtg-0.3.ebuild
new file mode 100644
index 000000000000..6017a645a7f1
--- /dev/null
+++ b/app-office/gtg/gtg-0.3.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/gtg/gtg-0.3.ebuild,v 1.1 2013/02/04 23:16:31 eva Exp $
+
+EAPI="5"
+PYTHON_COMPAT=( python2_{6,7} )
+
+inherit eutils fdo-mime gnome2-utils distutils-r1 versionator
+
+MY_PV="$(get_version_component_range 1-2)"
+DESCRIPTION="Personal organizer for the GNOME desktop environment"
+HOMEPAGE="http://gtg.fritalk.com/"
+SRC_URI="http://launchpad.net/${PN}/${MY_PV}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-python/liblarch[${PYTHON_USEDEP}]
+	dev-python/configobj[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:2[${PYTHON_USEDEP}]
+	dev-python/pygtk[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+	dev-python/pyxdg[${PYTHON_USEDEP}]
+	dev-python/simplejson[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+python_prepare_all() {
+	# Plugins are voluntarily left automagic as application has a nice way
+	# to suggest missing dependencies. We only remove the ones that cannot
+	# work on gentoo.
+	# Backends should be enabled via USE flag when pulling extra deps
+
+	# tweepy: missing python-r1 support
+	# geoloc: uses removed from tree bindings
+	sed -e "/GTG.backends.tweepy/d" \
+		-e "/GTG.plugins.geolocalized_tasks',/d" \
+		-e "/geolocalized-tasks.gtg-plugin/d" \
+		-i setup.py || die
+
+	# launchpad: missing dependency
+	# mantis: missing python-r1 support
+	# evolution: missing python-r1 support
+	rm GTG/backends/backend_launchpad.py \
+		GTG/backends/backend_mantis.py \
+		GTG/backends/backend_evolution.py \
+		GTG/backends/backend_twitter.py \
+		|| die
+}
+
+pkg_preinst() {
+	gnome2_icon_savelist
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+	fdo-mime_mime_database_update
+	gnome2_icon_cache_update
+}
diff --git a/app-office/gtg/metadata.xml b/app-office/gtg/metadata.xml
index 690389c712a2..0e6392700a85 100644
--- a/app-office/gtg/metadata.xml
+++ b/app-office/gtg/metadata.xml
@@ -1,23 +1,26 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<maintainer>
-<email>steev@gentoo.org</email>
-</maintainer>
-<maintainer>
-<email>leio@gentoo.org</email>
-<description>Backup maintainer, CC on bugs, assign to remaming</description>
-</maintainer>
-<longdescription lang="en">
-	Getting Things Gnome! (gtg) is a personal organizer for the GNOME desktop that
-	was inspired by the Getting Things Done methodology (GTD). It is not a GTD only
-	software as it aims for flexibility, adaptability and ease of use.
+	<maintainer>
+		<email>eva@gentoo.org</email>
+	</maintainer>
+	<maintainer>
+		<email>steev@gentoo.org</email>
+	</maintainer>
+	<maintainer>
+		<email>leio@gentoo.org</email>
+		<description>Backup maintainer, CC on bugs, assign to remaming</description>
+	</maintainer>
+	<longdescription lang="en">
+		Getting Things Gnome! (gtg) is a personal organizer for the GNOME desktop that
+		was inspired by the Getting Things Done methodology (GTD). It is not a GTD only
+		software as it aims for flexibility, adaptability and ease of use.
 
-	GTG wants to help you to track everything you need to do and need to know, from
-	very small tasks to big projects.
+		GTG wants to help you to track everything you need to do and need to know, from
+		very small tasks to big projects.
 
-	GTG uses a very handy text edition system for task creation and edition.
-	The task editor can automatically recognize metadata such as tags and subtasks
-	only by the use of a very simple syntax.
-</longdescription>
+		GTG uses a very handy text edition system for task creation and edition.
+		The task editor can automatically recognize metadata such as tags and subtasks
+		only by the use of a very simple syntax.
+	</longdescription>
 </pkgmetadata>