Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F3CFD2BD)

2 files changed, 132 insertions, 1 deletions

diff --git a/app-office/akonadi-server/ChangeLog b/app-office/akonadi-server/ChangeLog
index 4052ed21c9c6..ae863ebfb962 100644
--- a/app-office/akonadi-server/ChangeLog
+++ b/app-office/akonadi-server/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-office/akonadi-server
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v 1.130 2013/12/11 20:31:10 ago Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/ChangeLog,v 1.131 2013/12/18 18:02:26 johu Exp $
+
+*akonadi-server-1.11.0 (18 Dec 2013)
+
+  18 Dec 2013; Johannes Huber <johu@gentoo.org> +akonadi-server-1.11.0.ebuild:
+  Version bump.
 
   11 Dec 2013; Agostino Sarubbo <ago@gentoo.org> akonadi-server-1.10.3.ebuild:
   Stable for ppc64, wrt bug #484884
diff --git a/app-office/akonadi-server/akonadi-server-1.11.0.ebuild b/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
new file mode 100644
index 000000000000..95e9e3da66c3
--- /dev/null
+++ b/app-office/akonadi-server/akonadi-server-1.11.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-office/akonadi-server/akonadi-server-1.11.0.ebuild,v 1.1 2013/12/18 18:02:26 johu Exp $
+
+EAPI=5
+
+if [[ $PV = *9999* ]]; then
+	scm_eclass=git-2
+	EGIT_REPO_URI="git://anongit.kde.org/akonadi"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	SRC_URI="mirror://kde/stable/${PN/-server/}/src/${PN/-server/}-${PV}.tar.bz2 -> ${P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${P/-server/}"
+fi
+
+inherit cmake-utils ${scm_eclass}
+
+DESCRIPTION="The server part of Akonadi"
+HOMEPAGE="http://pim.kde.org/akonadi"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="+mysql postgres +qt4 qt5 sqlite test"
+
+REQUIRED_USE="^^ ( qt4 qt5 ) || ( sqlite mysql postgres )"
+
+CDEPEND="
+	dev-libs/boost:=
+	>=dev-libs/soprano-2.6.51
+	x11-misc/shared-mime-info
+	qt4? (
+		>=dev-qt/qtcore-4.8.5:4
+		>=dev-qt/qtdbus-4.8.5:4
+		>=dev-qt/qtgui-4.8.5:4
+		>=dev-qt/qtsql-4.8.5:4[mysql?,postgres?]
+		>=dev-qt/qttest-4.8.5:4
+	)
+	qt5? (
+		>=dev-libs/soprano-2.6.51[-qt4,qt5]
+		dev-qt/qtcore:5
+		dev-qt/qtdbus:5
+		dev-qt/qtgui:5
+		dev-qt/qtnetwork:5
+		dev-qt/qtsql:5[mysql?,postgres?]
+		dev-qt/qttest:5
+		dev-qt/qtwidgets:5
+		dev-qt/qtxml:5
+	)
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${CDEPEND}
+	dev-libs/libxslt
+	>=dev-util/automoc-0.9.88
+	test? ( sys-apps/dbus )
+"
+RDEPEND="${CDEPEND}
+	postgres? ( dev-db/postgresql-server )
+"
+
+pkg_setup() {
+	# Set default storage backend in order: MySQL, SQLite PostgreSQL
+	# reverse driver check to keep the order
+	if use postgres; then
+		DRIVER="QPSQL"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	if use sqlite; then
+		DRIVER="QSQLITE3"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	if use mysql; then
+		DRIVER="QMYSQL"
+		AVAILABLE+=" ${DRIVER}"
+	fi
+
+	# Notify about MySQL is recommend by upstream
+	if use sqlite || has_version "<${CATEGORY}/${P}[sqlite]"; then
+		ewarn
+		ewarn "We strongly recommend you change your Akonadi database backend to MySQL in your"
+		ewarn "user configuration. This is the backend recommended by KDE upstream."
+		ewarn "In particular, kde-base/kmail-4.10 does not work properly with the sqlite"
+		ewarn "backend anymore."
+		ewarn "You can select the backend in your ~/.config/akonadi/akonadiserverrc."
+		ewarn "Available drivers are:${AVAILABLE}"
+		ewarn
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DAKONADI_USE_STRIGI_SEARCH=OFF
+		-DINSTALL_QSQLITE_IN_QT_PREFIX=ON
+		$(cmake-utils_use test AKONADI_BUILD_TESTS)
+		$(cmake-utils_use sqlite AKONADI_BUILD_QSQLITE)
+		$(cmake-utils_use qt5 QT5_BUILD)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	export $(dbus-launch)
+	cmake-utils_src_test
+}
+
+src_install() {
+	# Who knows, maybe it accidentally fixes our permission issues
+	cat <<-EOF > "${T}"/akonadiserverrc
+[%General]
+Driver=${DRIVER}
+EOF
+	insinto /usr/share/config/akonadi
+	doins "${T}"/akonadiserverrc
+
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	elog "${DRIVER} has been set as your default akonadi storage backend."
+	elog "You can override it in your ~/.config/akonadi/akonadiserverrc."
+	elog "Available drivers are: ${AVAILABLE}"
+}