Version bump.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key 4AB3E85B4F064CA3)

2 files changed, 72 insertions, 1 deletions

diff --git a/app-forensics/afflib/ChangeLog b/app-forensics/afflib/ChangeLog
index ff01d4b87b30..a82140c81673 100644
--- a/app-forensics/afflib/ChangeLog
+++ b/app-forensics/afflib/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-forensics/afflib
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-forensics/afflib/ChangeLog,v 1.45 2013/11/10 07:31:14 radhermit Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/afflib/ChangeLog,v 1.46 2013/12/17 10:38:30 radhermit Exp $
+
+*afflib-3.7.4 (17 Dec 2013)
+
+  17 Dec 2013; Tim Harder <radhermit@gentoo.org> +afflib-3.7.4.ebuild:
+  Version bump.
 
 *afflib-3.7.3 (10 Nov 2013)
 
diff --git a/app-forensics/afflib/afflib-3.7.4.ebuild b/app-forensics/afflib/afflib-3.7.4.ebuild
new file mode 100644
index 000000000000..8991927910a6
--- /dev/null
+++ b/app-forensics/afflib/afflib-3.7.4.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-forensics/afflib/afflib-3.7.4.ebuild,v 1.1 2013/12/17 10:38:30 radhermit Exp $
+
+EAPI=5
+PYTHON_COMPAT=( python2_{6,7} )
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_PRUNE_LIBTOOL_FILES=modules
+
+inherit autotools-utils python-single-r1
+
+MY_PN=AFFLIBv3
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Library that implements the AFF image standard"
+HOMEPAGE="https://github.com/simsong/AFFLIBv3/"
+SRC_URI="https://github.com/simsong/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~x86"
+IUSE="fuse ncurses python qemu readline s3 static-libs threads"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="dev-libs/expat
+	dev-libs/openssl
+	sys-libs/zlib
+	fuse? ( sys-fs/fuse )
+	ncurses? ( sys-libs/ncurses )
+	python? ( ${PYTHON_DEPS} )
+	readline? ( sys-libs/readline )
+	s3? ( net-misc/curl )"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-3.7.1-python-module.patch
+	"${FILESDIR}"/${PN}-3.6.12-pyaff-header.patch
+)
+
+S=${WORKDIR}/${MY_P}
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+	sed -i '/FLAGS/s: -g::' configure.ac || die
+	sed -i '/-static/d' tools/Makefile.am || die
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	# Hacks for automagic dependencies
+	use ncurses || export ac_cv_lib_ncurses_initscr=no
+	use readline || export ac_cv_lib_readline_readline=no
+
+	local myeconfargs=(
+		$(use_enable fuse)
+		$(use_enable python)
+		$(use_enable qemu)
+		$(use_enable s3)
+		$(use_enable threads threading)
+	)
+	autotools-utils_src_configure
+}