More clean ups and fixed with a ton of input from Vincent Béron.

3 files changed, 109 insertions, 1 deletions

diff --git a/app-emulation/wine/ChangeLog b/app-emulation/wine/ChangeLog
index 8ceb7e317e62..52cd3985136f 100644
--- a/app-emulation/wine/ChangeLog
+++ b/app-emulation/wine/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/wine
 # Copyright 2002-2004 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.81 2004/10/31 01:19:34 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/ChangeLog,v 1.82 2004/11/01 14:00:01 vapier Exp $
+
+*wine-20041019-r3 (01 Nov 2004)
+
+  01 Nov 2004; Mike Frysinger <vapier@gentoo.org> +wine-20041019-r3.ebuild:
+  More clean ups and fixed with a ton of input from Vincent Béron.
 
 *wine-20041019-r2 (30 Oct 2004)
 
diff --git a/app-emulation/wine/files/digest-wine-20041019-r3 b/app-emulation/wine/files/digest-wine-20041019-r3
new file mode 100644
index 000000000000..6269db774bcc
--- /dev/null
+++ b/app-emulation/wine/files/digest-wine-20041019-r3
@@ -0,0 +1 @@
+MD5 412d0e6f2e364c43d8c77b5904c70da9 Wine-20041019.tar.gz 11058180
diff --git a/app-emulation/wine/wine-20041019-r3.ebuild b/app-emulation/wine/wine-20041019-r3.ebuild
new file mode 100644
index 000000000000..c8239c31b300
--- /dev/null
+++ b/app-emulation/wine/wine-20041019-r3.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2004 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/wine/wine-20041019-r3.ebuild,v 1.1 2004/11/01 14:00:01 vapier Exp $
+
+inherit eutils flag-o-matic
+
+DESCRIPTION="free implementation of Windows(tm) on Unix - CVS snapshot"
+HOMEPAGE="http://www.winehq.com/"
+SRC_URI="mirror://sourceforge/${PN}/Wine-${PV}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="-*"
+IUSE="X alsa arts cups debug nas opengl gif glut jack jpeg oss ncurses doc"
+
+RDEPEND=">=media-libs/freetype-2.0.0
+	ncurses? ( >=sys-libs/ncurses-5.2 )
+	jack? ( media-sound/jack-audio-connection-kit )
+	X? ( virtual/x11 )
+	arts? ( kde-base/arts )
+	alsa? ( media-libs/alsa-lib )
+	nas? ( media-libs/nas )
+	cups? ( net-print/cups )
+	opengl? ( virtual/opengl )
+	gif? ( media-libs/libungif )
+	jpeg? ( media-libs/jpeg )
+	glut? ( virtual/glut )"
+DEPEND="${RDEPEND}
+	>=sys-apps/sed-4
+	sys-devel/bison
+	sys-devel/gcc
+	doc? ( app-text/docbook-sgml-utils app-text/jadetex )
+	sys-devel/flex"
+
+src_unpack() {
+	unpack Wine-${PV}.tar.gz
+
+	cd ${S}
+	epatch ${FILESDIR}/winearts-kdecvs-fix.patch
+	sed -i '/^UPDATE_DESKTOP_DATABASE/s:=.*:=true:' tools/Makefile.in
+
+	test_flag -fstack-protector && epatch ${FILESDIR}/${PV}-no-stack.patch #66002
+}
+
+config_cache() {
+	local h ans="no"
+	use ${1} && ans="yes"
+	shift
+	for h in "$@" ; do
+		export ac_cv_${h}=${ans}
+	done
+}
+
+src_compile() {
+	export LDCONFIG=/bin/true
+	config_cache jack header_jack_jack_h
+	config_cache cups header_cups_cups_h
+	config_cache alsa header_alsa_asoundlib_h header_sys_asoundlib_h lib_asound_snd_pcm_open
+	config_cache arts path_ARTSCCONFIG
+	config_cache nas header_audio_audiolib_h header_audio_soundlib_h
+	config_cache gif header_gif_lib_h
+	config_cache glut lib_glut_glutMainLoop
+	config_cache jpeg header_jpeglib_h
+	config_cache oss sys_soundcard_h header_machine_soundcard_h header_soundcard_h
+
+	strip-flags
+
+	#	$(use_enable amd64 win64)
+	econf \
+		--sysconfdir=/etc/wine \
+		$(use_with ncurses curses) \
+		$(use_with opengl) \
+		$(use_with X x) \
+		$(use_enable debug trace) \
+		$(use_enable debug) \
+		|| die "configure failed"
+
+	emake -j1 depend || die "depend"
+	emake all || die "all"
+	if use doc ; then
+		emake -C documentation doc || die "docs"
+	fi
+}
+
+src_install() {
+	make \
+		prefix=${D}/usr \
+		bindir=${D}/usr/bin \
+		datadir=${D}/usr/share \
+		includedir=${D}/usr/include/wine \
+		sysconfdir=${D}/etc/wine \
+		mandir=${D}/usr/share/man \
+		libdir=${D}/usr/lib \
+		dlldir=${D}/usr/lib/wine \
+		install || die
+	use doc && dodoc documentation/*.pdf
+
+	insinto /usr/share/wine
+	doins documentation/samples/config || die "doins config"
+
+	dodoc ANNOUNCE AUTHORS BUGS ChangeLog DEVELOPERS-HINTS README
+}