Version bump and preparation for new app-emulation/virtualbox ebuild

(Portage version: 2.2.0_alpha13/cvs/Linux x86_64)

5 files changed, 326 insertions, 11 deletions

diff --git a/app-emulation/virtualbox-bin/ChangeLog b/app-emulation/virtualbox-bin/ChangeLog
index b4d5f408526d..ad61b2f1ee7b 100644
--- a/app-emulation/virtualbox-bin/ChangeLog
+++ b/app-emulation/virtualbox-bin/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-emulation/virtualbox-bin
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/ChangeLog,v 1.96 2010/12/31 14:43:36 hwoarang Exp $
+# Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/ChangeLog,v 1.97 2011/01/06 22:16:32 polynomial-c Exp $
+
+*virtualbox-bin-4.0.0 (06 Jan 2011)
+
+  06 Jan 2011; Lars Wendler <polynomial-c@gentoo.org>
+  virtualbox-bin-3.1.8.ebuild, virtualbox-bin-3.2.10-r1.ebuild,
+  virtualbox-bin-3.2.12-r1.ebuild, +virtualbox-bin-4.0.0.ebuild:
+  Version bump and preparation for new app-emulation/virtualbox ebuild.
 
   31 Dec 2010; Markos Chandras <hwoarang@gentoo.org>
   virtualbox-bin-3.2.12-r1.ebuild:
diff --git a/app-emulation/virtualbox-bin/virtualbox-bin-3.1.8.ebuild b/app-emulation/virtualbox-bin/virtualbox-bin-3.1.8.ebuild
index a2880cc73ada..02bc5ab900dc 100644
--- a/app-emulation/virtualbox-bin/virtualbox-bin-3.1.8.ebuild
+++ b/app-emulation/virtualbox-bin/virtualbox-bin-3.1.8.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-3.1.8.ebuild,v 1.6 2010/07/17 10:52:07 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-3.1.8.ebuild,v 1.7 2011/01/06 22:16:32 polynomial-c Exp $
 
 EAPI=2
 
@@ -23,7 +23,8 @@ RESTRICT="mirror"
 
 DEPEND="app-arch/unzip"
 
-RDEPEND="!!app-emulation/virtualbox-ose
+RDEPEND="!!app-emulation/virtualbox
+	!!app-emulation/virtualbox-ose
 	!app-emulation/virtualbox-ose-additions
 	~app-emulation/virtualbox-modules-${PV}
 	!headless? (
diff --git a/app-emulation/virtualbox-bin/virtualbox-bin-3.2.10-r1.ebuild b/app-emulation/virtualbox-bin/virtualbox-bin-3.2.10-r1.ebuild
index bca7dc15ddec..eccf69298da1 100644
--- a/app-emulation/virtualbox-bin/virtualbox-bin-3.2.10-r1.ebuild
+++ b/app-emulation/virtualbox-bin/virtualbox-bin-3.2.10-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-3.2.10-r1.ebuild,v 1.1 2010/10/22 21:14:05 polynomial-c Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-3.2.10-r1.ebuild,v 1.2 2011/01/06 22:16:32 polynomial-c Exp $
 
 EAPI=2
 
@@ -24,7 +24,8 @@ RESTRICT="mirror"
 
 DEPEND="app-arch/unzip"
 
-RDEPEND="!!app-emulation/virtualbox-ose
+RDEPEND="!!app-emulation/virtualbox
+	!!app-emulation/virtualbox-ose
 	!app-emulation/virtualbox-ose-additions
 	~app-emulation/virtualbox-modules-${PV}
 	!headless? (
diff --git a/app-emulation/virtualbox-bin/virtualbox-bin-3.2.12-r1.ebuild b/app-emulation/virtualbox-bin/virtualbox-bin-3.2.12-r1.ebuild
index 21508c0dc56d..4ed3b22abb41 100644
--- a/app-emulation/virtualbox-bin/virtualbox-bin-3.2.12-r1.ebuild
+++ b/app-emulation/virtualbox-bin/virtualbox-bin-3.2.12-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2010 Gentoo Foundation
+# Copyright 1999-2011 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-3.2.12-r1.ebuild,v 1.2 2010/12/31 14:43:36 hwoarang Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-3.2.12-r1.ebuild,v 1.3 2011/01/06 22:16:32 polynomial-c Exp $
 
 EAPI=2
 
@@ -24,7 +24,8 @@ RESTRICT="mirror"
 
 DEPEND="app-arch/unzip"
 
-RDEPEND="!!app-emulation/virtualbox-ose
+RDEPEND="!!app-emulation/virtualbox
+	!!app-emulation/virtualbox-ose
 	!app-emulation/virtualbox-ose-additions
 	~app-emulation/virtualbox-modules-${PV}
 	!headless? (
diff --git a/app-emulation/virtualbox-bin/virtualbox-bin-4.0.0.ebuild b/app-emulation/virtualbox-bin/virtualbox-bin-4.0.0.ebuild
new file mode 100644
index 000000000000..6b1d428c528f
--- /dev/null
+++ b/app-emulation/virtualbox-bin/virtualbox-bin-4.0.0.ebuild
@@ -0,0 +1,305 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virtualbox-bin/virtualbox-bin-4.0.0.ebuild,v 1.1 2011/01/06 22:16:32 polynomial-c Exp $
+
+EAPI=2
+
+inherit eutils fdo-mime pax-utils
+
+MY_PV=${PV}-69151
+SDK_PV=${MY_PV}
+MY_P=VirtualBox-${MY_PV}-Linux
+
+DESCRIPTION="Family of powerful x86 virtualization products for enterprise as well as home use"
+HOMEPAGE="http://www.virtualbox.org/"
+SRC_URI="amd64? ( http://download.virtualbox.org/virtualbox/${PV}/${MY_P}_amd64.run )
+	x86? ( http://download.virtualbox.org/virtualbox/${PV}/${MY_P}_x86.run )
+	sdk? ( http://download.virtualbox.org/virtualbox/${PV}/VirtualBoxSDK-${SDK_PV}.zip )"
+
+LICENSE="PUEL"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+additions +chm headless python sdk vboxwebsrv rdesktop-vrdp"
+RESTRICT="mirror"
+
+DEPEND="app-arch/unzip"
+
+RDEPEND="!!app-emulation/virtualbox
+	!!app-emulation/virtualbox-ose
+	!app-emulation/virtualbox-ose-additions
+	~app-emulation/virtualbox-modules-${PV}
+	!headless? (
+		x11-libs/libXcursor
+		media-libs/libsdl[X]
+		x11-libs/libXrender
+		x11-libs/libXfixes
+		media-libs/libpng
+		x11-libs/libXi
+		x11-libs/libXrandr
+		x11-libs/libXinerama
+		x11-libs/libXft
+		media-libs/freetype
+		media-libs/fontconfig
+		x11-libs/libXext
+		dev-libs/glib
+		chm? ( dev-libs/expat )
+	)
+	x11-libs/libXt
+	dev-libs/libxml2
+	x11-libs/libXau
+	x11-libs/libX11
+	x11-libs/libXmu
+	x11-libs/libSM
+	x11-libs/libICE
+	x11-libs/libXdmcp
+	python? ( || (
+			dev-lang/python:2.7
+			dev-lang/python:2.6
+			dev-lang/python:2.5
+			dev-lang/python:2.4
+		) )"
+
+S=${WORKDIR}
+
+QA_TEXTRELS_amd64="opt/VirtualBox/VBoxVMM.so"
+QA_TEXTRELS_x86="opt/VirtualBox/VBoxGuestPropSvc.so
+	opt/VirtualBox/VBoxSDL.so
+	opt/VirtualBox/VBoxDbg.so
+	opt/VirtualBox/VBoxSharedFolders.so
+	opt/VirtualBox/VBoxDD2.so
+	opt/VirtualBox/VBoxOGLrenderspu.so
+	opt/VirtualBox/VBoxPython.so
+	opt/VirtualBox/VBoxPython2_3.so
+	opt/VirtualBox/VBoxPython2_4.so
+	opt/VirtualBox/VBoxPython2_5.so
+	opt/VirtualBox/VBoxPython2_6.so
+	opt/VirtualBox/VBoxPython2_7.so
+	opt/VirtualBox/VBoxPython3_0.so
+	opt/VirtualBox/VBoxPython3_1.so
+	opt/VirtualBox/VBoxDD.so
+	opt/VirtualBox/VBoxVRDP.so
+	opt/VirtualBox/VBoxDDU.so
+	opt/VirtualBox/VBoxREM64.so
+	opt/VirtualBox/VBoxSharedClipboard.so
+	opt/VirtualBox/VBoxHeadless.so
+	opt/VirtualBox/VBoxRT.so
+	opt/VirtualBox/VRDPAuth.so
+	opt/VirtualBox/VBoxREM.so
+	opt/VirtualBox/VBoxSettings.so
+	opt/VirtualBox/VBoxKeyboard.so
+	opt/VirtualBox/VBoxSharedCrOpenGL.so
+	opt/VirtualBox/VBoxVMM.so
+	opt/VirtualBox/VirtualBox.so
+	opt/VirtualBox/VBoxOGLhosterrorspu.so
+	opt/VirtualBox/components/VBoxC.so
+	opt/VirtualBox/components/VBoxSVCM.so
+	opt/VirtualBox/VBoxREM32.so
+	opt/VirtualBox/VBoxPython2_5.so
+	opt/VirtualBox/VBoxXPCOMC.so
+	opt/VirtualBox/VBoxOGLhostcrutil.so
+	opt/VirtualBox/VBoxNetDHCP.so
+	opt/VirtualBox/VBoxGuestControlSvc.so"
+QA_PRESTRIPPED="opt/VirtualBox/VBoxDD.so
+	opt/VirtualBox/VBoxDD2.so
+	opt/VirtualBox/VBoxDDU.so
+	opt/VirtualBox/VBoxDbg.so
+	opt/VirtualBox/VBoxGuestControlSvc.so
+	opt/VirtualBox/VBoxGuestPropSvc.so
+	opt/VirtualBox/VBoxHeadless
+	opt/VirtualBox/VBoxHeadless.so
+	opt/VirtualBox/VBoxKeyboard.so
+	opt/VirtualBox/VBoxManage
+	opt/VirtualBox/VBoxNetAdpCtl
+	opt/VirtualBox/VBoxNetDHCP
+	opt/VirtualBox/VBoxNetDHCP.so
+	opt/VirtualBox/VBoxOGLhostcrutil.so
+	opt/VirtualBox/VBoxOGLhosterrorspu.so
+	opt/VirtualBox/VBoxOGLrenderspu.so
+	opt/VirtualBox/VBoxPython.so
+	opt/VirtualBox/VBoxPython2_3.so
+	opt/VirtualBox/VBoxPython2_4.so
+	opt/VirtualBox/VBoxPython2_5.so
+	opt/VirtualBox/VBoxPython2_6.so
+	opt/VirtualBox/VBoxPython2_7.so
+	opt/VirtualBox/VBoxPython3_0.so
+	opt/VirtualBox/VBoxPython3_1.so
+	opt/VirtualBox/VBoxREM.so
+	opt/VirtualBox/VBoxREM32.so
+	opt/VirtualBox/VBoxREM64.so
+	opt/VirtualBox/VBoxRT.so
+	opt/VirtualBox/VBoxSDL
+	opt/VirtualBox/VBoxSDL.so
+	opt/VirtualBox/VBoxSVC
+	opt/VirtualBox/VBoxSettings.so
+	opt/VirtualBox/VBoxSharedClipboard.so
+	opt/VirtualBox/VBoxSharedCrOpenGL.so
+	opt/VirtualBox/VBoxSharedFolders.so
+	opt/VirtualBox/VBoxTestOGL
+	opt/VirtualBox/VBoxTunctl
+	opt/VirtualBox/VBoxVMM.so
+	opt/VirtualBox/VBoxVRDP.so
+	opt/VirtualBox/VBoxXPCOM.so
+	opt/VirtualBox/VBoxXPCOMC.so
+	opt/VirtualBox/VBoxXPCOMIPCD
+	opt/VirtualBox/VRDPAuth.so
+	opt/VirtualBox/VirtualBox
+	opt/VirtualBox/VirtualBox.so
+	opt/VirtualBox/accessible/libqtaccessiblewidgets.so
+	opt/VirtualBox/components/VBoxC.so
+	opt/VirtualBox/components/VBoxSVCM.so
+	opt/VirtualBox/components/VBoxXPCOMIPCC.so
+	opt/VirtualBox/kchmviewer
+	opt/VirtualBox/libQtCoreVBox.so.4
+	opt/VirtualBox/libQtGuiVBox.so.4
+	opt/VirtualBox/libQtNetworkVBox.so.4
+	opt/VirtualBox/libQtOpenGLVBox.so.4
+	opt/VirtualBox/vboxwebsrv"
+
+src_unpack() {
+	unpack_makeself ${MY_P}_${ARCH}.run
+	unpack ./VirtualBox.tar.bz2
+
+	if use sdk; then
+		unpack VirtualBoxSDK-${SDK_PV}.zip
+	fi
+}
+
+src_install() {
+	# create virtualbox configurations files
+	insinto /etc/vbox
+	newins "${FILESDIR}/${PN}-config" vbox.cfg
+
+	if ! use headless ; then
+		newicon VBox.png ${PN}.png
+		newmenu "${FILESDIR}"/${PN}.desktop-2 ${PN}.desktop
+	fi
+
+	insinto /opt/VirtualBox
+	dodir /opt/bin
+
+	doins UserManual.pdf
+
+	if use sdk ; then
+		doins -r sdk || die
+	fi
+
+	if use additions; then
+		doins -r additions || die
+	fi
+
+	if use vboxwebsrv; then
+		doins vboxwebsrv || die
+		fowners root:vboxusers /opt/VirtualBox/vboxwebsrv
+		fperms 0750 /opt/VirtualBox/vboxwebsrv
+		dosym /opt/VirtualBox/VBox.sh /opt/bin/vboxwebsrv
+		newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
+		newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
+	fi
+
+	if use rdesktop-vrdp; then
+		doins rdesktop-vrdp || die
+		doins -r rdesktop-vrdp-keymaps || die
+		fperms 0750 /opt/VirtualBox/rdesktop-vrdp
+	fi
+
+	if ! use headless && use chm; then
+		doins kchmviewer VirtualBox.chm || die
+		fowners root:vboxusers /opt/VirtualBox/kchmviewer
+		fperms 0750 /opt/VirtualBox/kchmviewer
+	fi
+
+	if use python; then
+		local pyver
+		for pyver in 2.4 2.5 2.6 2.7 3.0 3.1 ; do
+			if has_version "=dev-lang/python-${pyver}*" && [ -f "${S}/VBoxPython${pyver/./_}.so" ] ; then
+				doins VBoxPython${pyver/./_}.so || die
+			fi
+		done
+	fi
+
+	rm -rf src rdesktop* deffiles install* routines.sh runlevel.sh \
+		vboxdrv.sh VBox.sh VBox.png vboxnet.sh additions VirtualBox.desktop \
+		VirtualBox.tar.bz2 LICENSE VBoxSysInfo.sh rdesktop* vboxwebsrv \
+		webtest kchmviewer VirtualBox.chm vbox-create-usb-node.sh \
+		90-vbox-usb.fdi uninstall.sh vboxshell.py vboxdrv-pardus.py \
+		VBoxPython?_*.so
+
+	if use headless ; then
+		rm -rf VBoxSDL VirtualBox VBoxKeyboard.so
+	fi
+
+	doins -r * || die
+
+	# create symlinks for working around unsupported $ORIGIN/.. in VBoxC.so (setuid)
+	dosym /opt/VirtualBox/VBoxVMM.so /opt/VirtualBox/components/VBoxVMM.so
+	dosym /opt/VirtualBox/VBoxREM.so /opt/VirtualBox/components/VBoxREM.so
+	dosym /opt/VirtualBox/VBoxRT.so /opt/VirtualBox/components/VBoxRT.so
+	dosym /opt/VirtualBox/VBoxDDU.so /opt/VirtualBox/components/VBoxDDU.so
+	dosym /opt/VirtualBox/VBoxXPCOM.so /opt/VirtualBox/components/VBoxXPCOM.so
+
+	local each
+	for each in VBox{Manage,SVC,XPCOMIPCD,Tunctl,NetAdpCtl,NetDHCP,TestOGL}; do
+		fowners root:vboxusers /opt/VirtualBox/${each}
+		fperms 0750 /opt/VirtualBox/${each}
+		pax-mark -m "${D}"/opt/VirtualBox/${each}
+	done
+	# VBoxNetAdpCtl and VBoxNetDHCP binaries need to be suid root in any case..
+	fperms 4750 /opt/VirtualBox/VBoxNetAdpCtl
+	fperms 4750 /opt/VirtualBox/VBoxNetDHCP
+
+	if ! use headless ; then
+		# Hardened build: Mark selected binaries set-user-ID-on-execution
+		for each in VBox{SDL,Headless} VirtualBox; do
+			fowners root:vboxusers /opt/VirtualBox/${each}
+			fperms 4510 /opt/VirtualBox/${each}
+			pax-mark -m "${D}"/opt/VirtualBox/${each}
+		done
+
+		dosym /opt/VirtualBox/VBox.sh /opt/bin/VirtualBox
+		dosym /opt/VirtualBox/VBox.sh /opt/bin/VBoxSDL
+	else
+		# Hardened build: Mark selected binaries set-user-ID-on-execution
+		fowners root:vboxusers /opt/VirtualBox/VBoxHeadless
+		fperms 4510 /opt/VirtualBox/VBoxHeadless
+		pax-mark -m "${D}"/opt/VirtualBox/VBoxHeadless
+	fi
+
+	if use rdesktop-vrdp; then
+		dosym /opt/VirtualBox/rdesktop-vrdp /opt/bin/rdesktop-vrdp
+	fi
+
+	exeinto /opt/VirtualBox
+	newexe "${FILESDIR}/${PN}-3-wrapper" "VBox.sh" || die
+	fowners root:vboxusers /opt/VirtualBox/VBox.sh
+	fperms 0750 /opt/VirtualBox/VBox.sh
+
+	dosym /opt/VirtualBox/VBox.sh /opt/bin/VBoxManage
+	dosym /opt/VirtualBox/VBox.sh /opt/bin/VBoxVRDP
+	dosym /opt/VirtualBox/VBox.sh /opt/bin/VBoxHeadless
+	dosym /opt/VirtualBox/VBoxTunctl /opt/bin/VBoxTunctl
+
+	# set an env-variable for 3rd party tools
+	echo -n "VBOX_APP_HOME=/opt/VirtualBox" > "${T}/90virtualbox"
+	doenvd "${T}/90virtualbox"
+}
+
+pkg_postinst() {
+	fdo-mime_desktop_database_update
+	elog ""
+	if ! use headless ; then
+		elog "To launch VirtualBox just type: \"VirtualBox\""
+		elog ""
+	fi
+	elog "You must be in the vboxusers group to use VirtualBox."
+	elog ""
+	elog "For advanced networking setups you should emerge:"
+	elog "net-misc/bridge-utils and sys-apps/usermode-utilities"
+	elog ""
+	elog "Please visit http://www.virtualbox.org/wiki/Editions for"
+	elog "an overview about the different features of ${PN}"
+	elog "and virtualbox-ose"
+}
+
+pkg_postrm() {
+	fdo-mime_desktop_database_update
+}