Version bump

(Portage version: 2.1.11.9/cvs/Linux x86_64)

2 files changed, 63 insertions, 1 deletions

diff --git a/app-emulation/virt-viewer/ChangeLog b/app-emulation/virt-viewer/ChangeLog
index b34e91616223..64fa1d9ae959 100644
--- a/app-emulation/virt-viewer/ChangeLog
+++ b/app-emulation/virt-viewer/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-emulation/virt-viewer
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-emulation/virt-viewer/ChangeLog,v 1.17 2012/05/29 20:29:09 dev-zero Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virt-viewer/ChangeLog,v 1.18 2012/09/18 01:37:27 cardoe Exp $
+
+*virt-viewer-0.5.4 (18 Sep 2012)
+
+  18 Sep 2012; Doug Goldstein <cardoe@gentoo.org> +virt-viewer-0.5.4.ebuild:
+  Version bump
 
 *virt-viewer-0.5.3 (29 May 2012)
 
diff --git a/app-emulation/virt-viewer/virt-viewer-0.5.4.ebuild b/app-emulation/virt-viewer/virt-viewer-0.5.4.ebuild
new file mode 100644
index 000000000000..c5107439beec
--- /dev/null
+++ b/app-emulation/virt-viewer/virt-viewer-0.5.4.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-emulation/virt-viewer/virt-viewer-0.5.4.ebuild,v 1.1 2012/09/18 01:37:28 cardoe Exp $
+
+EAPI=4
+inherit eutils gnome2 toolchain-funcs
+
+DESCRIPTION="Graphical console client for connecting to virtual machines"
+HOMEPAGE="http://virt-manager.org/"
+SRC_URI="http://virt-manager.org/download/sources/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="gtk3 nsplugin sasl +spice +vnc"
+
+RDEPEND=">=app-emulation/libvirt-0.9.7
+	>=dev-libs/libxml2-2.6
+	gtk3? ( x11-libs/gtk+:3 )
+	!gtk3? (
+		>=x11-libs/gtk+-2.18:2
+		>=gnome-base/libglade-2.6
+		)
+	nsplugin? (
+		>=dev-libs/nspr-4
+		>=x11-libs/gtk+-2.18:2
+		>=gnome-base/libglade-2.6
+		)
+	spice? ( >=net-misc/spice-gtk-0.12[sasl?,gtk3=] )
+	vnc? ( >=net-libs/gtk-vnc-0.4.3 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nsplugin? ( >=net-misc/npapi-sdk-0.27 )"
+
+REQUIRED_USE="|| ( spice vnc )
+	nsplugin? ( !gtk3 )
+	gtk3? ( !nsplugin )"
+
+pkg_setup() {
+	G2CONF="$(use_enable nsplugin plugin) $(use_with spice spice-gtk)"
+	G2CONF="${G2CONF} $(use_with vnc gtk-vnc)"
+	use gtk3 && G2CONF="${G2CONF} --with-gtk=3.0"
+	use gtk3 || G2CONF="${G2CONF} --with-gtk=2.0"
+}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-0.5.x-npapi-sdk.patch
+}
+
+src_configure() {
+	if use nsplugin; then
+		export MOZILLA_PLUGIN_CFLAGS="$($(tc-getPKG_CONFIG) --cflags npapi-sdk nspr)"
+		export MOZILLA_PLUGIN_LIBS="$($(tc-getPKG_CONFIG) --libs npapi-sdk nspr)"
+	fi
+
+	gnome2_src_configure
+}