Version bump.

(Portage version: 2.1.2.4)

1 files changed, 73 insertions, 0 deletions

diff --git a/app-editors/scite/scite-1.73.ebuild b/app-editors/scite/scite-1.73.ebuild
new file mode 100644
index 000000000000..1d12dea52fbd
--- /dev/null
+++ b/app-editors/scite/scite-1.73.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/scite/scite-1.73.ebuild,v 1.1 2007/04/17 09:13:31 nelchael Exp $
+
+inherit toolchain-funcs eutils
+
+MY_PV=${PV//./}
+DESCRIPTION="A very powerful editor for programmers"
+HOMEPAGE="http://scintilla.sourceforge.net/SciTE.html"
+SRC_URI="mirror://sourceforge/scintilla/${PN}${MY_PV}.tgz"
+
+LICENSE="Scintilla"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~sparc ~x86"
+IUSE="lua"
+
+RDEPEND=">=x11-libs/gtk+-2
+	lua? ( >=dev-lang/lua-5 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	>=sys-apps/sed-4"
+
+S=${WORKDIR}/${PN}/gtk
+
+src_unpack() {
+	unpack ${A}
+	cd ${WORKDIR}/scintilla/gtk
+	sed -i makefile \
+		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
+		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
+		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
+		|| die "error patching makefile"
+
+	cd ${S}
+	sed -i makefile \
+		-e 's#usr/local#usr#g' \
+		-e 's#/gnome/apps/Applications#/applications#' \
+		-e "s#^CXXFLAGS=#CXXFLAGS=${CXXFLAGS} #" \
+		-e "s#^\(CXXFLAGS=.*\)-Os#\1#" \
+		-e "s#^CC =\(.*\)#CC = $(tc-getCXX)#" \
+		-e 's#${D}##' \
+		-e 's#-g root#-g 0#' \
+		|| die "error patching makefile"
+	epatch ${FILESDIR}/${P}-install.patch
+}
+
+src_compile() {
+	make -C ../../scintilla/gtk || die "prep make failed"
+	if use lua; then
+		emake || die "make failed"
+	else
+		emake NO_LUA=1 || die "make failed"
+	fi
+}
+
+src_install() {
+	dodir /usr/bin
+	dodir /usr/share/{pixmaps,applications}
+
+	make prefix=${D}/usr install || die
+
+	# we have to keep this because otherwise it'll break upgrading
+	mv ${D}/usr/bin/SciTE ${D}/usr/bin/scite
+	dosym /usr/bin/scite /usr/bin/SciTE
+
+	# replace .desktop file with our own working version
+	insinto /usr/share/applications
+	rm -f ${D}/usr/share/applications/SciTE.desktop
+	doins ${FILESDIR}/scite.desktop
+
+	doman ../doc/scite.1
+	dodoc ../README
+}