Update to EAPI=4. Support epatch_user. Enable colorization by default.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key FB7C4156)

2 files changed, 85 insertions, 1 deletions

diff --git a/app-editors/nano/ChangeLog b/app-editors/nano/ChangeLog
index 217167dd5a94..630e9c5dd1f3 100644
--- a/app-editors/nano/ChangeLog
+++ b/app-editors/nano/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-editors/nano
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.302 2013/09/28 11:13:54 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/ChangeLog,v 1.303 2013/11/28 23:06:33 vapier Exp $
+
+*nano-2.3.2-r1 (28 Nov 2013)
+
+  28 Nov 2013; Mike Frysinger <vapier@gentoo.org> +nano-2.3.2-r1.ebuild:
+  Update to EAPI=4.  Support epatch_user.  Enable colorization by default.
 
   28 Sep 2013; Mike Frysinger <vapier@gentoo.org>
   files/nano-2.3.1-gentoo-nanorc.patch:
diff --git a/app-editors/nano/nano-2.3.2-r1.ebuild b/app-editors/nano/nano-2.3.2-r1.ebuild
new file mode 100644
index 000000000000..7d7e4748e918
--- /dev/null
+++ b/app-editors/nano/nano-2.3.2-r1.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/nano/nano-2.3.2-r1.ebuild,v 1.1 2013/11/28 23:06:33 vapier Exp $
+
+EAPI="4"
+
+inherit eutils autotools
+if [[ ${PV} == "9999" ]] ; then
+	ESVN_REPO_URI="svn://svn.savannah.gnu.org/nano/trunk/nano"
+	inherit subversion autotools
+else
+	MY_P=${PN}-${PV/_}
+	SRC_URI="http://www.nano-editor.org/dist/v${PV:0:3}/${MY_P}.tar.gz"
+fi
+
+DESCRIPTION="GNU GPL'd Pico clone with more functionality"
+HOMEPAGE="http://www.nano-editor.org/ http://www.gentoo.org/doc/en/nano-basics-guide.xml"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~hppa-hpux ~ia64-hpux ~x86-interix ~amd64-linux ~arm-linux ~ia64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug justify +magic minimal ncurses nls slang spell unicode"
+
+RDEPEND=">=sys-libs/ncurses-5.9-r1[unicode?]
+	magic? ( sys-apps/file )
+	nls? ( virtual/libintl )
+	!ncurses? ( slang? ( sys-libs/slang ) )"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig"
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-2.3.1-ncurses-pkg-config.patch
+	epatch "${FILESDIR}"/${PN}-2.3.2-bind-unbind-docs.patch
+	epatch "${FILESDIR}"/${PN}-2.3.1-{shell,gentoo}-nanorc.patch
+	epatch_user
+	eautoreconf
+}
+
+src_configure() {
+	eval export ac_cv_{header_magic_h,lib_magic_magic_open}=$(usex magic)
+	local myconf=()
+	case ${CHOST} in
+	*-gnu*|*-uclibc*) myconf+=( "--with-wordbounds" ) ;; #467848
+	esac
+	econf \
+		--bindir="${EPREFIX}"/bin \
+		$(use_enable !minimal color) \
+		$(use_enable !minimal multibuffer) \
+		$(use_enable !minimal nanorc) \
+		--disable-wrapping-as-root \
+		$(use_enable spell speller) \
+		$(use_enable justify) \
+		$(use_enable debug) \
+		$(use_enable nls) \
+		$(use_enable unicode utf8) \
+		$(use_enable minimal tiny) \
+		$(usex ncurses --without-slang $(use_with slang)) \
+		"${myconf[@]}"
+}
+
+src_install() {
+	default
+	rm -rf "${ED}"/usr/share/nano/man-html
+
+	dodoc ChangeLog README doc/nanorc.sample AUTHORS BUGS NEWS TODO
+	dohtml doc/faq.html
+	insinto /etc
+	newins doc/nanorc.sample nanorc
+	if ! use minimal ; then
+		# Enable colorization by default.
+		sed -i \
+			-e '/^# include /s:# *::' \
+			"${ED}"/etc/nanorc || die
+	fi
+
+	dodir /usr/bin
+	dosym /bin/nano /usr/bin/nano
+}