Bump to 2.24.2. Bug fixes and translation updates. Allow to move to a line relative to the current line.

(Portage version: 2.2_rc15/cvs/Linux 2.6.24-gentoo-r8-mactel x86_64)

2 files changed, 89 insertions, 1 deletions

diff --git a/app-editors/gedit/ChangeLog b/app-editors/gedit/ChangeLog
index 49d71b1435a7..7a3af5536c78 100644
--- a/app-editors/gedit/ChangeLog
+++ b/app-editors/gedit/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-editors/gedit
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.252 2008/11/17 19:28:26 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/ChangeLog,v 1.253 2008/11/24 20:45:23 eva Exp $
+
+*gedit-2.24.2 (24 Nov 2008)
+
+  24 Nov 2008; Gilles Dartiguelongue <eva@gentoo.org> +gedit-2.24.2.ebuild:
+  Bump to 2.24.2. Bug fixes and translation updates. Allow to move to a line
+  relative to the current line.
 
 *gedit-2.24.1 (17 Nov 2008)
 
diff --git a/app-editors/gedit/gedit-2.24.2.ebuild b/app-editors/gedit/gedit-2.24.2.ebuild
new file mode 100644
index 000000000000..8d0506a224f1
--- /dev/null
+++ b/app-editors/gedit/gedit-2.24.2.ebuild
@@ -0,0 +1,82 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-editors/gedit/gedit-2.24.2.ebuild,v 1.1 2008/11/24 20:45:23 eva Exp $
+
+inherit gnome2 python eutils autotools
+
+DESCRIPTION="A text editor for the GNOME desktop"
+HOMEPAGE="http://www.gnome.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="doc python spell xattr"
+
+RDEPEND=">=gnome-base/gconf-2
+	xattr? ( sys-apps/attr )
+	>=x11-libs/libSM-1.0
+	>=dev-libs/libxml2-2.5.0
+	>=dev-libs/glib-2.16
+	>=x11-libs/gtk+-2.13
+	>=x11-libs/gtksourceview-2.2
+	spell? (
+		>=app-text/enchant-1.2
+		>=app-text/iso-codes-0.35
+	)
+	python? (
+		>=dev-python/pygobject-2.15.4
+		>=dev-python/pygtk-2.12
+		>=dev-python/pygtksourceview-2.2
+	)"
+
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=dev-util/pkgconfig-0.9
+	>=app-text/scrollkeeper-0.3.11
+	>=dev-util/intltool-0.35
+	>=app-text/gnome-doc-utils-0.3.2
+	gnome-base/gnome-common
+	doc? ( dev-util/gtk-doc )"
+# gnome-common needed to eautoreconf
+
+DOCS="AUTHORS BUGS ChangeLog MAINTAINERS NEWS README"
+
+if [[ "${ARCH}" == "PPC" ]] ; then
+	# HACK HACK HACK: someone fix this garbage
+	MAKEOPTS="${MAKEOPTS} -j1"
+fi
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--disable-scrollkeeper
+		$(use_enable python)
+		$(use_enable spell)
+		$(use_enable xattr attr)"
+}
+
+src_unpack() {
+	gnome2_src_unpack
+
+	# Remove symbols that are not meant to be part of the docs, and
+	# break compilation if USE="doc -python" (bug #158638).
+	if use !python && use doc; then
+		epatch "${FILESDIR}"/${PN}-2.16.2-no_python_module_docs.patch
+	fi
+
+	# fixes failing python test due to libtool 2.2, bug #216110
+	epatch "${FILESDIR}/${PN}-2.22.1-fix-libtool-2.2.patch"
+
+	# disable pyc compiling
+	mv "${S}"/py-compile "${S}"/py-compile.orig
+	ln -s $(type -P true) "${S}"/py-compile
+
+	eautoreconf
+}
+
+pkg_postinst() {
+	use python && python_mod_optimize /usr/$(get_libdir)/gedit-2/plugins
+}
+
+pkg_postrm() {
+	use python && python_mod_cleanup /usr/$(get_libdir)/gedit-2/plugins
+}