Version bump with stricter error handling. Respect USE=-introspection. Enable vala bindings. Add missing dependencies for the test suite.

(Portage version: 2.2.0_alpha141/cvs/Linux x86_64, signed Manifest commit with key CF0ADD61)

3 files changed, 80 insertions, 1 deletions

diff --git a/app-crypt/libsecret/ChangeLog b/app-crypt/libsecret/ChangeLog
index 8a05f3949a05..36ca4fd75a80 100644
--- a/app-crypt/libsecret/ChangeLog
+++ b/app-crypt/libsecret/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for app-crypt/libsecret
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/libsecret/ChangeLog,v 1.1 2012/09/25 10:06:41 tetromino Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/libsecret/ChangeLog,v 1.2 2012/10/24 08:01:30 tetromino Exp $
+
+*libsecret-0.11 (24 Oct 2012)
+
+  24 Oct 2012; Alexandre Rostovtsev <tetromino@gentoo.org>
+  +libsecret-0.11.ebuild, metadata.xml:
+  Version bump with stricter error handling. Respect USE=-introspection. Enable
+  vala bindings. Add missing dependencies for the test suite.
 
 *libsecret-0.10 (25 Sep 2012)
 
diff --git a/app-crypt/libsecret/libsecret-0.11.ebuild b/app-crypt/libsecret/libsecret-0.11.ebuild
new file mode 100644
index 000000000000..8f55ee52b89e
--- /dev/null
+++ b/app-crypt/libsecret/libsecret-0.11.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/libsecret/libsecret-0.11.ebuild,v 1.1 2012/10/24 08:01:30 tetromino Exp $
+
+EAPI="4"
+VALA_MIN_API_VERSION=0.18
+VALA_USE_DEPEND=vapigen
+
+inherit eutils gnome2 python vala virtualx
+
+DESCRIPTION="GObject library for accessing the freedesktop.org Secret Service API"
+HOMEPAGE="https://live.gnome.org/Libsecret"
+
+LICENSE="LGPL-2.1+ Apache-2.0" # Apache-2.0 license is used for tests only
+SLOT="0"
+IUSE="+crypt debug +introspection test vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.31.0:2
+	crypt? ( >=dev-libs/libgcrypt-1.2.2 )
+	introspection? ( >=dev-libs/gobject-introspection-1.29 )"
+RDEPEND="${COMMON_DEPEND}
+	>=gnome-base/gnome-keyring-3"
+# Add ksecrets to RDEPEND when it's added to portage
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35.0
+	sys-devel/gettext
+	virtual/pkgconfig
+	test? ( introspection? (
+		=dev-lang/python-2*
+		>=dev-libs/gjs-1.32
+		dev-python/pygobject:3
+	) )
+	vala? ( $(vala_depend) )"
+
+pkg_setup() {
+	# python is only needed for tests
+	if use test && use introspection; then
+		python_pkg_setup
+		python_set_active_version 2
+	fi
+}
+
+src_prepare() {
+	DOCS="AUTHORS ChangeLog NEWS README"
+	G2CONF="
+		--enable-manpages
+		--disable-strict
+		--disable-coverage
+		--disable-static
+		$(use_enable crypt gcrypt)
+		$(use_enable introspection)
+		$(use_enable vala)"
+
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_test() {
+	Xemake check
+}
+
+src_install() {
+	gnome2_src_install
+	prune_libtool_files --all
+}
diff --git a/app-crypt/libsecret/metadata.xml b/app-crypt/libsecret/metadata.xml
index 0b6b5da045eb..38f7f9e56a56 100644
--- a/app-crypt/libsecret/metadata.xml
+++ b/app-crypt/libsecret/metadata.xml
@@ -5,5 +5,6 @@
 <use>
 	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
 		for introspection</flag>
+	<flag name="vala">Enable bindings for <pkg>dev-lang/vala</pkg></flag>
 </use>
 </pkgmetadata>