version bump as per bug #255537 thanks to Arfrever Frehtes Taifersar Arahesis

(Portage version: 2.2_rc23/cvs/Linux x86_64)

4 files changed, 103 insertions, 7 deletions

diff --git a/app-crypt/gnupg/ChangeLog b/app-crypt/gnupg/ChangeLog
index a5185e15201d..bf930572284e 100644
--- a/app-crypt/gnupg/ChangeLog
+++ b/app-crypt/gnupg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-crypt/gnupg
 # Copyright 2002-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.335 2009/01/30 11:24:42 dragonheart Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/ChangeLog,v 1.336 2009/02/15 05:10:20 dragonheart Exp $
+
+*gnupg-2.0.10 (15 Feb 2009)
+
+  15 Feb 2009; Daniel Black <dragonheart@gentoo.org> gnupg-2.0.9.ebuild,
+  gnupg-2.0.9-r1.ebuild, +gnupg-2.0.10.ebuild:
+  version bump as per bug #255537 thanks to Arfrever Frehtes Taifersar Arahesis
 
   30 Jan 2009; Daniel Black <dragonheart@gentoo.org>
   -files/gnupg-1.4.3-keyserver.patch, -files/gnupg-1.4.3-selftest.patch,
diff --git a/app-crypt/gnupg/gnupg-2.0.10.ebuild b/app-crypt/gnupg/gnupg-2.0.10.ebuild
new file mode 100644
index 000000000000..5690a672c6e8
--- /dev/null
+++ b/app-crypt/gnupg/gnupg-2.0.10.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.10.ebuild,v 1.1 2009/02/15 05:10:20 dragonheart Exp $
+
+inherit flag-o-matic toolchain-funcs
+
+DESCRIPTION="The GNU Privacy Guard, a GPL pgp replacement"
+HOMEPAGE="http://www.gnupg.org/"
+SRC_URI="mirror://gnupg/gnupg/${P}.tar.bz2"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="bzip2 caps doc ldap nls openct pcsc-lite static selinux smartcard"
+
+COMMON_DEPEND_LIBS="
+	>=dev-libs/pth-1.3.7
+	>=dev-libs/libgcrypt-1.4
+	>=dev-libs/libksba-1.0.2
+	>=dev-libs/libgpg-error-1.4
+	>=net-misc/curl-7.7.2
+	bzip2? ( app-arch/bzip2 )
+	pcsc-lite? ( >=sys-apps/pcsc-lite-1.3.0 )
+	openct? ( >=dev-libs/openct-0.5.0 )
+	ldap? ( net-nds/openldap )"
+COMMON_DEPEND_BINS="app-crypt/pinentry"
+
+# existence of bins are checked during configure
+DEPEND="${COMMON_DEPEND_LIBS}
+	${COMMON_DEPEND_BINS}
+	>=dev-libs/libassuan-1.0.4
+	nls? ( sys-devel/gettext )
+	doc? ( sys-apps/texinfo )"
+
+RDEPEND="!static? ( ${COMMON_DEPEND_LIBS} )
+	${COMMON_DEPEND_BINS}
+	virtual/mta
+	!app-crypt/gpg-agent
+	!<=app-crypt/gnupg-2.0.1
+	selinux? ( sec-policy/selinux-gnupg )
+	nls? ( virtual/libintl )"
+
+src_compile() {
+	# 'USE=static' support was requested:
+	# gnupg1: bug #29299
+	# gnupg2: bug #159623
+	use static && append-ldflags -static
+
+	econf \
+		--docdir="/usr/share/doc/${PF}" \
+		--enable-symcryptrun \
+		--enable-gpg \
+		--enable-gpgsm \
+		--enable-agent \
+		$(use_enable bzip2) \
+		$(use_enable smartcard scdaemon) \
+		$(use_enable nls) \
+		$(use_enable ldap) \
+		$(use_enable static) \
+		$(use_enable caps capabilities) \
+		CC_FOR_BUILD=$(tc-getBUILD_CC)
+	emake || die "emake failed"
+	if use doc; then
+		cd doc
+		emake html || die "emake html failed"
+	fi
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed"
+	dodoc ChangeLog NEWS README THANKS TODO VERSION
+
+	mv "${D}/usr/share/gnupg"/help* "${D}/usr/share/doc/${PF}"
+
+	dosym gpg2 /usr/bin/gpg
+	dosym gpgv2 /usr/bin/gpgv
+	dosym gpg2keys_hkp /usr/libexec/gpgkeys_hkp
+	dosym gpg2keys_finger /usr/libexec/gpgkeys_finger
+	dosym gpg2keys_curl /usr/libexec/gpgkeys_curl
+	use ldap && dosym gpg2keys_ldap /usr/libexec/gpgkeys_ldap
+	echo ".so man1/gpg2.1" > "${D}/usr/share/man/man1/gpg.1"
+	echo ".so man1/gpgv2.1" > "${D}/usr/share/man/man1/gpgv.1"
+
+	use doc && dohtml doc/gnupg.html/* doc/*jpg doc/*png
+}
+
+pkg_postinst() {
+	elog "If you wish to view images emerge:"
+	elog "media-gfx/xloadimage, media-gfx/xli or any other viewer"
+	elog "Remember to use photo-viewer option in configuration file to activate"
+	elog "the right viewer"
+}
diff --git a/app-crypt/gnupg/gnupg-2.0.9-r1.ebuild b/app-crypt/gnupg/gnupg-2.0.9-r1.ebuild
index bceb5f3a2635..230302eff860 100644
--- a/app-crypt/gnupg/gnupg-2.0.9-r1.ebuild
+++ b/app-crypt/gnupg/gnupg-2.0.9-r1.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.9-r1.ebuild,v 1.2 2008/09/09 19:12:23 mr_bones_ Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.9-r1.ebuild,v 1.3 2009/02/15 05:10:20 dragonheart Exp $
 
 inherit flag-o-matic eutils toolchain-funcs
 
@@ -79,7 +79,6 @@ src_install() {
 	dodoc ChangeLog NEWS README THANKS TODO VERSION
 
 	mv "${D}/usr/share/gnupg"/{help*,faq*,FAQ} "${D}/usr/share/doc/${PF}"
-	prepalldocs
 
 	dosym gpg2 /usr/bin/gpg
 	dosym gpgv2 /usr/bin/gpgv
diff --git a/app-crypt/gnupg/gnupg-2.0.9.ebuild b/app-crypt/gnupg/gnupg-2.0.9.ebuild
index a92f21cbd073..a0d7dc3dcbd9 100644
--- a/app-crypt/gnupg/gnupg-2.0.9.ebuild
+++ b/app-crypt/gnupg/gnupg-2.0.9.ebuild
@@ -1,6 +1,6 @@
-# Copyright 1999-2008 Gentoo Foundation
+# Copyright 1999-2009 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.9.ebuild,v 1.10 2008/10/27 05:43:17 vapier Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/gnupg/gnupg-2.0.9.ebuild,v 1.11 2009/02/15 05:10:20 dragonheart Exp $
 
 inherit flag-o-matic eutils toolchain-funcs
 
@@ -70,7 +70,6 @@ src_install() {
 	dodoc ChangeLog NEWS README THANKS TODO VERSION
 
 	mv "${D}/usr/share/gnupg"/{help*,faq*,FAQ} "${D}/usr/share/doc/${PF}"
-	prepalldocs
 
 	dosym gpg2 /usr/bin/gpg
 	dosym gpgv2 /usr/bin/gpgv