Version bump

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key 67C78E1D)

2 files changed, 57 insertions, 1 deletions

diff --git a/app-backup/cyphertite/ChangeLog b/app-backup/cyphertite/ChangeLog
index 2ad8fe721bcc..949fcdedee25 100644
--- a/app-backup/cyphertite/ChangeLog
+++ b/app-backup/cyphertite/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for app-backup/cyphertite
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v 1.7 2014/09/28 16:20:39 grknight Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/ChangeLog,v 1.8 2014/12/06 01:42:11 grknight Exp $
+
+*cyphertite-2.0.4 (06 Dec 2014)
+
+  06 Dec 2014; Brian Evans <grknight@gentoo.org> +cyphertite-2.0.4.ebuild:
+  Version bump
 
 *cyphertite-2.0.2-r5 (28 Sep 2014)
 
diff --git a/app-backup/cyphertite/cyphertite-2.0.4.ebuild b/app-backup/cyphertite/cyphertite-2.0.4.ebuild
new file mode 100644
index 000000000000..73618034f600
--- /dev/null
+++ b/app-backup/cyphertite/cyphertite-2.0.4.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-backup/cyphertite/cyphertite-2.0.4.ebuild,v 1.1 2014/12/06 01:42:11 grknight Exp $
+
+EAPI=5
+
+inherit toolchain-funcs eutils multilib
+
+DESCRIPTION="High Security, Zero-Knowledge Online Backup"
+HOMEPAGE="https://www.cyphertite.com/"
+SRC_URI="https://www.cyphertite.com/snapshots/source/${PV}/${PN}-full-${PV}.tar.gz"
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+DEPEND="
+	app-arch/xz-utils:0=
+	dev-db/sqlite:3=
+	>=dev-libs/openssl-1.0.1g:0=[-bindist]
+	dev-libs/expat:0=
+	dev-libs/libbsd:0=
+	dev-libs/libedit:0=
+	dev-libs/libevent:0=
+	>=dev-libs/lzo-2.0:2=
+	>=net-misc/curl-7.15.1:0=[ssl]
+	sys-libs/zlib:0=
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	# Fix build system that assumes that modules are installed to the live system
+	epatch "${FILESDIR}/${PN}-2.0.2-fix-build.patch" "${FILESDIR}/${PN}-2.0.2-cflags.patch"
+}
+
+src_compile() {
+	# Package has a home grown Makefile system. Make it work for Gentoo
+	emake INCDIR="${S}" WARNFLAGS="-Wall" OPTLEVEL="" DEBUG="" CC="$(tc-getCC)" \
+		AR="$(tc-getAR)" LOCALBASE="/usr" LIB.LINKSTATIC="" LIB.LINKDYNAMIC=""
+}
+
+src_install() {
+	# Only the main executable needs to be installed
+	emake -C cyphertite/cyphertite DESTDIR="${D}" LOCALBASE="usr" LIBDIR="usr/$(get_libdir)" LNFORCE="-s" install
+
+	# Fix up broken man symlinks
+	rm "${D}"usr/share/man/man1/ct*.1 || die
+	newman "${D}"usr/share/man/man1/cyphertite.1 ct.1
+	newman "${D}"usr/share/man/man1/cyphertitectl.1 ctctl.1
+	newman "${D}"usr/share/man/man1/cyphertitefb.1 ctfb.1
+}