Handle running configure ourselves and be stricter with feature flags so they are respected #435410 by Ambroz Bizjak.

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key D2E96200)

2 files changed, 69 insertions, 2 deletions

diff --git a/app-arch/zip/ChangeLog b/app-arch/zip/ChangeLog
index 52297c7a3d59..0281b702e49f 100644
--- a/app-arch/zip/ChangeLog
+++ b/app-arch/zip/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-arch/zip
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-arch/zip/ChangeLog,v 1.101 2013/02/18 22:42:54 zmedico Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/zip/ChangeLog,v 1.102 2014/01/05 18:26:15 vapier Exp $
+
+*zip-3.0-r2 (05 Jan 2014)
+
+  05 Jan 2014; Mike Frysinger <vapier@gentoo.org> +zip-3.0-r2.ebuild:
+  Handle running configure ourselves and be stricter with feature flags so they
+  are respected #435410 by Ambroz Bizjak.
 
   18 Feb 2013; Zac Medico <zmedico@gentoo.org> zip-3.0-r1.ebuild:
   Add ~arm-linux keyword.
diff --git a/app-arch/zip/zip-3.0-r2.ebuild b/app-arch/zip/zip-3.0-r2.ebuild
new file mode 100644
index 000000000000..04ee003e8521
--- /dev/null
+++ b/app-arch/zip/zip-3.0-r2.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-arch/zip/zip-3.0-r2.ebuild,v 1.1 2014/01/05 18:26:15 vapier Exp $
+
+EAPI="4"
+inherit toolchain-funcs eutils flag-o-matic
+
+MY_P="${PN}${PV//.}"
+DESCRIPTION="Info ZIP (encryption support)"
+HOMEPAGE="http://www.info-zip.org/"
+SRC_URI="mirror://sourceforge/infozip/${MY_P}.zip"
+
+LICENSE="Info-ZIP"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~arm-linux"
+IUSE="bzip2 crypt natspec unicode"
+
+RDEPEND="bzip2? ( app-arch/bzip2 )
+	natspec? ( dev-libs/libnatspec )"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	epatch "${FILESDIR}"/${PN}-3.0-no-crypt.patch #238398
+	epatch "${FILESDIR}"/${PN}-3.0-pic.patch
+	epatch "${FILESDIR}"/${PN}-3.0-exec-stack.patch
+	epatch "${FILESDIR}"/${PN}-3.0-build.patch
+	use natspec && epatch "${FILESDIR}"/${PN}-3.0-natspec.patch #275244
+}
+
+src_configure() {
+	append-cppflags \
+		-DLARGE_FILE_SUPPORT \
+		-DUIDGID_NOT_16BIT \
+		-D$(usex bzip2 '' NO)BZIP2_SUPPORT \
+		-D$(usex crypt '' NO)CRYPT \
+		-D$(usex unicode '' NO)UNICODE_SUPPORT
+	# Third arg disables bzip2 logic as we handle it ourselves above.
+	sh ./unix/configure "$(tc-getCC)" "-I. -DUNIX ${CFLAGS} ${CPPFLAGS}" "${T}" || die
+	if use bzip2 ; then
+		sed -i -e "s:LFLAGS2=:&'-lbz2 ':" flags || die
+	fi
+}
+
+src_compile() {
+	emake \
+		CPP="$(tc-getCPP)" \
+		-f unix/Makefile generic
+}
+
+src_install() {
+	dobin zip zipnote zipsplit
+	doman man/zip{,note,split}.1
+	if use crypt ; then
+		dobin zipcloak
+		doman man/zipcloak.1
+	fi
+	dodoc BUGS CHANGES README* TODO WHATSNEW WHERE proginfo/*.txt
+}