Version bump for Gnome 3.16. Clean up old revision.

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key C6085806)

3 files changed, 72 insertions, 51 deletions

diff --git a/app-accessibility/at-spi2-core/ChangeLog b/app-accessibility/at-spi2-core/ChangeLog
index 715b668aa5f0..f872d4590e67 100644
--- a/app-accessibility/at-spi2-core/ChangeLog
+++ b/app-accessibility/at-spi2-core/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-accessibility/at-spi2-core
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/ChangeLog,v 1.85 2015/06/07 10:07:43 maekke Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/ChangeLog,v 1.86 2015/06/09 09:52:21 eva Exp $
+
+*at-spi2-core-2.16.0 (09 Jun 2015)
+
+  09 Jun 2015; Gilles Dartiguelongue <eva@gentoo.org>
+  -at-spi2-core-2.10.2.ebuild, +at-spi2-core-2.16.0.ebuild:
+  Version bump for Gnome 3.16. Clean up old revision.
 
   07 Jun 2015; Markus Meier <maekke@gentoo.org> at-spi2-core-2.14.1.ebuild:
   arm stable, bug #534012
diff --git a/app-accessibility/at-spi2-core/at-spi2-core-2.10.2.ebuild b/app-accessibility/at-spi2-core/at-spi2-core-2.10.2.ebuild
deleted file mode 100644
index 98ef324cd34d..000000000000
--- a/app-accessibility/at-spi2-core/at-spi2-core-2.10.2.ebuild
+++ /dev/null
@@ -1,50 +0,0 @@
-# Copyright 1999-2014 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/at-spi2-core-2.10.2.ebuild,v 1.14 2014/04/21 10:28:26 ago Exp $
-
-EAPI="5"
-GCONF_DEBUG="no"
-GNOME2_LA_PUNT="yes"
-
-inherit eutils gnome2
-
-DESCRIPTION="D-Bus accessibility specifications and registration daemon"
-HOMEPAGE="http://live.gnome.org/Accessibility"
-
-LICENSE="LGPL-2+"
-SLOT="2"
-IUSE="+X +introspection"
-KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos"
-
-# x11-libs/libSM is needed until upstream #719808 is solved either
-# making the dep unneeded or fixing their configure
-# Only libX11 is optional right now
-RDEPEND="
-	>=dev-libs/glib-2.28:2
-	>=sys-apps/dbus-1
-	x11-libs/libSM
-	x11-libs/libXi
-	x11-libs/libXtst
-	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
-	X? ( x11-libs/libX11 )
-"
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.9
-	>=dev-util/intltool-0.40
-	virtual/pkgconfig
-"
-
-src_prepare() {
-	# disable teamspaces test since that requires Novell.ICEDesktop.Daemon
-	epatch "${FILESDIR}/${PN}-2.0.2-disable-teamspaces-test.patch"
-
-	gnome2_src_prepare
-}
-
-src_configure() {
-	# xevie is deprecated/broken since xorg-1.6/1.7
-	gnome2_src_configure \
-		--disable-xevie \
-		$(use_enable introspection) \
-		$(use_enable X x11)
-}
diff --git a/app-accessibility/at-spi2-core/at-spi2-core-2.16.0.ebuild b/app-accessibility/at-spi2-core/at-spi2-core-2.16.0.ebuild
new file mode 100644
index 000000000000..2219359ff127
--- /dev/null
+++ b/app-accessibility/at-spi2-core/at-spi2-core-2.16.0.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-accessibility/at-spi2-core/at-spi2-core-2.16.0.ebuild,v 1.1 2015/06/09 09:52:21 eva Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+inherit eutils gnome2 multilib-minimal
+
+DESCRIPTION="D-Bus accessibility specifications and registration daemon"
+HOMEPAGE="http://live.gnome.org/Accessibility"
+
+LICENSE="LGPL-2+"
+SLOT="2"
+IUSE="+X +introspection"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos"
+
+# x11-libs/libSM is needed until upstream #719808 is solved either
+# making the dep unneeded or fixing their configure
+# Only libX11 is optional right now
+COMMON_DEPEND="
+	>=dev-libs/glib-2.36:2[${MULTILIB_USEDEP}]
+	>=sys-apps/dbus-1[${MULTILIB_USEDEP}]
+	x11-libs/libSM[${MULTILIB_USEDEP}]
+	x11-libs/libXi[${MULTILIB_USEDEP}]
+	x11-libs/libXtst[${MULTILIB_USEDEP}]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6 )
+	X? ( x11-libs/libX11[${MULTILIB_USEDEP}] )
+"
+RDEPEND="${COMMON_DEPEND}
+	abi_x86_32? (
+		!<=app-emulation/emul-linux-x86-gtklibs-20140508-r3
+		!app-emulation/emul-linux-x86-gtklibs[-abi_x86_32(-)]
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.40
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+"
+
+src_prepare() {
+	# disable teamspaces test since that requires Novell.ICEDesktop.Daemon
+	epatch "${FILESDIR}/${PN}-2.0.2-disable-teamspaces-test.patch"
+
+	gnome2_src_prepare
+}
+
+multilib_src_configure() {
+	# xevie is deprecated/broken since xorg-1.6/1.7
+	ECONF_SOURCE=${S} \
+	gnome2_src_configure \
+		--disable-xevie \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable X x11)
+
+	# work-around gtk-doc out-of-source brokedness
+	if multilib_is_native_abi; then
+		ln -s "${S}"/doc/libatspi/html doc/libatspi/html || die
+	fi
+}
+
+multilib_src_compile() { gnome2_src_compile; }
+multilib_src_install() { gnome2_src_install; }