sci-libs/scikits_learn: Move to new python eclasses

(Portage version: 2.2.0_alpha161/cvs/Linux x86_64, signed Manifest commit with key 70EB7916)

3 files changed, 92 insertions, 3 deletions

diff --git a/sci-libs/scikits_learn/ChangeLog b/sci-libs/scikits_learn/ChangeLog
index 055d37ee592c..9c20b52502e8 100644
--- a/sci-libs/scikits_learn/ChangeLog
+++ b/sci-libs/scikits_learn/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sci-libs/scikits_learn
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.16 2013/01/30 17:42:10 bicatali Exp $
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/ChangeLog,v 1.17 2013/02/08 09:16:43 jlec Exp $
+
+*scikits_learn-0.13-r1 (08 Feb 2013)
+
+  08 Feb 2013; Justin Lecher <jlec@gentoo.org> +scikits_learn-0.13-r1.ebuild,
+  metadata.xml:
+  Move to new python eclasses
 
 *scikits_learn-0.13 (30 Jan 2013)
 
diff --git a/sci-libs/scikits_learn/metadata.xml b/sci-libs/scikits_learn/metadata.xml
index 087bbc4a99a7..0d35104aa69d 100644
--- a/sci-libs/scikits_learn/metadata.xml
+++ b/sci-libs/scikits_learn/metadata.xml
@@ -1,8 +1,8 @@
 <?xml version="1.0" encoding="UTF-8"?>
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
-<herd>sci</herd>
-<longdescription lang="en">
+  <herd>sci</herd>
+  <longdescription lang="en">
   scikits.learn is a python library for machine learning. It aims to
   implement classic machine learning algorithms while remaining simple
   and efficient.
diff --git a/sci-libs/scikits_learn/scikits_learn-0.13-r1.ebuild b/sci-libs/scikits_learn/scikits_learn-0.13-r1.ebuild
new file mode 100644
index 000000000000..6ee74ad153cd
--- /dev/null
+++ b/sci-libs/scikits_learn/scikits_learn-0.13-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sci-libs/scikits_learn/scikits_learn-0.13-r1.ebuild,v 1.1 2013/02/08 09:16:43 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7} )
+
+inherit distutils-r1 multilib flag-o-matic
+
+MYPN="${PN/scikits_/scikit-}"
+
+DESCRIPTION="Python modules for machine learning and data mining"
+HOMEPAGE="http://scikit-learn.org"
+SRC_URI="mirror://sourceforge/${MYPN}/${MYPN}-${PV}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc examples"
+
+RDEPEND="
+	sci-libs/scikits[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	dev-python/matplotlib[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/cython
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	sci-libs/scipy[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}] )"
+
+S="${WORKDIR}/${MYPN}-${PV}"
+
+python_prepare_all() {
+	# bug #397605
+	[[ ${CHOST} == *-darwin* ]] \
+		&& append-ldflags -bundle "-undefined dynamic_lookup" \
+		|| append-ldflags -shared
+
+	# scikits-learn now uses the horrible numpy.distutils automagic
+	export SCIPY_FCONFIG="config_fc --noopt --noarch"
+}
+
+python_compile() {
+	distutils-r1_python_compile ${SCIPY_FCONFIG}
+}
+
+python_compile_all() {
+	if use doc; then
+		cd "${S}/doc"
+		local d="${BUILD_DIR}"/lib
+		ln -s "${S}"/sklearn/datasets/{data,descr,images} \
+			"${d}"/sklearn/datasets
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${d}" \
+			emake html
+		rm -r "${d}"/sklearn/datasets/{data,desr,images}
+	fi
+}
+
+python_test() {
+	# doc builds and runs tests
+	use doc && return
+	esetup.py \
+		install --root="${T}/test-${EPYTHON}" \
+		--no-compile ${SCIPY_FCONFIG} || die
+	cd "${T}/test-${EPYTHON}/${EPREFIX}$(python_get_sitedir)" || die
+	PYTHONPATH=. nosetests-${EPYTHON} sklearn --exe || die
+}
+
+python_install() {
+	distutils-r1_python_install ${SCIPY_FCONFIG}
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete
+	insinto /usr/share/doc/${PF}
+	use doc && dohtml -r doc/_build/html
+	use examples && doins -r examples
+}