Bump to 1.3.0 . Drop ~ppc and ~ppc64 keywords

(Portage version: 2.2_rc54/cvs/Linux x86_64)

3 files changed, 104 insertions, 1 deletions

diff --git a/dev-util/qt-creator/ChangeLog b/dev-util/qt-creator/ChangeLog
index a305292920f2..9c7cc0016192 100644
--- a/dev-util/qt-creator/ChangeLog
+++ b/dev-util/qt-creator/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-util/qt-creator
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v 1.31 2009/11/09 10:52:11 abcd Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/ChangeLog,v 1.32 2009/12/01 18:38:01 hwoarang Exp $
+
+*qt-creator-1.3.0 (01 Dec 2009)
+
+  01 Dec 2009; <hwoarang@gentoo.org> +qt-creator-1.3.0.ebuild:
+  Bump to 1.3.0 . Drop ~ppc and ~ppc64 keywords since qt-demo is not marked ~ach  for those arches
 
   09 Nov 2009; Jonathan Callen <abcd@gentoo.org>
   -files/add_missing_plugins.patch:
diff --git a/dev-util/qt-creator/metadata.xml b/dev-util/qt-creator/metadata.xml
index f824a8b30a7f..8b8ac7440ddf 100644
--- a/dev-util/qt-creator/metadata.xml
+++ b/dev-util/qt-creator/metadata.xml
@@ -14,6 +14,7 @@
 	<flag name="designer">enable designer plugin</flag>
 	<flag name="fakevim">enable vim-like key bindings plugin</flag>
 	<flag name="git">enable git plugin</flag>
+	<flag name="mercurial">enable mercurial plugin</flag>
 	<flag name="perforce">enable perforce software configuration manager plugin</flag>
 	<flag name="qtscript">enable qt script editor plugin</flag>
 	<flag name="subversion">enable subersion plugin</flag>
diff --git a/dev-util/qt-creator/qt-creator-1.3.0.ebuild b/dev-util/qt-creator/qt-creator-1.3.0.ebuild
new file mode 100644
index 000000000000..4154bb6f1e9f
--- /dev/null
+++ b/dev-util/qt-creator/qt-creator-1.3.0.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/qt-creator/qt-creator-1.3.0.ebuild,v 1.1 2009/12/01 18:38:01 hwoarang Exp $
+
+EAPI="2"
+
+inherit qt4 multilib
+MY_PN="${PN/-/}"
+
+DESCRIPTION="Lightweight IDE for C++ development centering around Qt"
+HOMEPAGE="http://labs.qtsoftware.com/page/Projects/Tools/QtCreator"
+SRC_URI="http://get.qt.nokia.com/qtcreator/${P}-src.zip"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="bineditor bookmarks +cmake cvs debug +debugger +designer doc examples fakevim git kde mercurial perforce qtscript subversion"
+
+DEPEND=">=x11-libs/qt-assistant-4.6.0_alpha_pre1:4
+	>=x11-libs/qt-gui-4.6.0_alpha_pre1:4[dbus,qt3support]"
+
+RDEPEND="${DEPEND}
+	>=x11-libs/qt-sql-4.6.0:4
+	>=x11-libs/qt-svg-4.6.0:4
+	>=x11-libs/qt-test-4.6.0:4
+	>=x11-libs/qt-webkit-4.6.0:4
+	!kde? ( || ( >=x11-libs/qt-phonon-4.6.0:4 media-sound/phonon ) )
+	kde? ( media-sound/phonon )
+	cmake? ( dev-util/cmake )
+	cvs? ( dev-util/cvs )
+	debugger? ( sys-devel/gdb )
+	examples? ( >=x11-libs/qt-demo-4.6.0:4 )
+	git? ( dev-util/git )
+	mercurial? ( dev-util/mercurial )
+	qtscript? ( >=x11-libs/qt-script-4.6.0:4 )
+	subversion? ( dev-util/subversion )"
+
+PLUGINS="bookmarks bineditor cmake cvs debugger designer fakevim git mercurial perforce qtscript subversion"
+
+LANGS="de es fr it ja pl ru sl"
+
+for x in ${LANGS}; do
+	IUSE="${IUSE} linguas_${x}"
+done
+
+src_prepare() {
+	qt4_src_prepare
+
+	# bug 263087
+	for plugin in ${PLUGINS};do
+		if ! use ${plugin};then
+			einfo "Disabling ${plugin} support"
+			if [[ ${plugin} == "cmake" ]];then
+				plugin="cmakeprojectmanager"
+			elif [[ ${plugin} == "qtscript" ]];then
+				plugin="qtscripteditor"
+			fi
+			sed -i "/plugin_${plugin}/s:^:#:" src/plugins/plugins.pro \
+				|| die "Failed to disable ${plugin} plugin"
+		fi
+	done
+
+	if use perforce;then
+		ewarn
+		ewarn "You have enabled perforce plugin."
+		ewarn "In order to use it, you need to manually"
+		ewarn "download perforce client from http://www.perforce.com/perforce/downloads/index.html"
+		ewarn
+		ebeep 5
+	fi
+}
+
+src_configure() {
+	eqmake4 ${MY_PN}.pro IDE_LIBRARY_BASENAME="$(get_libdir)"
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}/usr" install_subtargets || die "emake install failed"
+	# fix binary name bug 275859
+	mv "${D}"/usr/bin/${MY_PN}.bin "${D}"/usr/bin/${MY_PN} || die "failed to rename executable"
+	if use doc;then
+		emake INSTALL_ROOT="${D}/usr" install_qch_docs || die "emake install qch_docs failed"
+	fi
+	make_desktop_entry ${MY_PN} QtCreator qtcreator_logo_48 \
+		'Qt;Development;IDE' || die "make_desktop_entry failed"
+
+	# install translations
+	insinto /usr/share/${MY_PN}/translations/
+	for x in ${LINGUAS};do
+		for lang in ${LANGS};do
+			if [[ ${x} == ${lang} ]];then
+				doins share/${MY_PN}/translations/${MY_PN}_${x}.qm \
+					|| die "failed to install translations"
+			fi
+		done
+	done
+}