Bump to 3.0.1, from gnome overlay for GNOME 3, drop ~ppc, bug 379651

(Portage version: 2.2.0_alpha51/cvs/Linux x86_64)

3 files changed, 107 insertions, 2 deletions

diff --git a/net-wireless/gnome-bluetooth/ChangeLog b/net-wireless/gnome-bluetooth/ChangeLog
index 9dbd279e549c..1ae20f5cab41 100644
--- a/net-wireless/gnome-bluetooth/ChangeLog
+++ b/net-wireless/gnome-bluetooth/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-wireless/gnome-bluetooth
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v 1.98 2011/05/14 16:29:14 eva Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/ChangeLog,v 1.99 2011/08/19 15:19:10 nirbheek Exp $
+
+*gnome-bluetooth-3.0.1 (19 Aug 2011)
+
+  19 Aug 2011; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +gnome-bluetooth-3.0.1.ebuild, metadata.xml:
+  Bump to 3.0.1, from gnome overlay for GNOME 3, drop ~ppc, bug 379651
 
   14 May 2011; Gilles Dartiguelongue <eva@gentoo.org>
   gnome-bluetooth-2.32.0.ebuild:
diff --git a/net-wireless/gnome-bluetooth/gnome-bluetooth-3.0.1.ebuild b/net-wireless/gnome-bluetooth/gnome-bluetooth-3.0.1.ebuild
new file mode 100644
index 000000000000..d725c8fbfd50
--- /dev/null
+++ b/net-wireless/gnome-bluetooth/gnome-bluetooth-3.0.1.ebuild
@@ -0,0 +1,96 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-wireless/gnome-bluetooth/gnome-bluetooth-3.0.1.ebuild,v 1.1 2011/08/19 15:19:10 nirbheek Exp $
+
+EAPI="3"
+GCONF_DEBUG="yes"
+# libgnome-bluetooth-applet.la is needed by gnome-shell during compilation
+GNOME2_LA_PUNT="no"
+
+inherit eutils gnome2 multilib
+
+DESCRIPTION="Fork of bluez-gnome focused on integration with GNOME"
+HOMEPAGE="http://live.gnome.org/GnomeBluetooth"
+
+LICENSE="GPL-2 LGPL-2.1"
+SLOT="2"
+IUSE="doc +introspection sendto"
+KEYWORDS="~amd64 ~x86"
+
+COMMON_DEPEND=">=dev-libs/glib-2.25.7:2
+	>=x11-libs/gtk+-2.91.3:3[introspection?]
+	>=x11-libs/libnotify-0.7.0
+	>=dev-libs/dbus-glib-0.74
+	>=gnome-base/gnome-control-center-2.91
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.5 )
+	sendto? ( >=gnome-extra/nautilus-sendto-2.91 )
+"
+RDEPEND="${COMMON_DEPEND}
+	>=net-wireless/bluez-4.34
+	app-mobilephone/obexd
+	sys-fs/udev"
+DEPEND="${COMMON_DEPEND}
+	<gnome-base/gnome-control-center-3.1.4
+	!!net-wireless/bluez-gnome
+	app-text/docbook-xml-dtd:4.1.2
+	app-text/gnome-doc-utils
+	app-text/scrollkeeper
+	dev-libs/libxml2
+	>=dev-util/intltool-0.40.0
+	dev-util/pkgconfig
+	>=sys-devel/gettext-0.17
+	x11-libs/libX11
+	x11-libs/libXi
+	x11-proto/xproto
+	doc? ( >=dev-util/gtk-doc-1.9 )"
+# eautoreconf needs:
+#	gnome-base/gnome-common
+#	dev-util/gtk-doc-am
+
+pkg_setup() {
+	# FIXME: Add geoclue support
+	G2CONF="${G2CONF}
+		$(use_enable introspection)
+		$(use_enable sendto nautilus-sendto)
+		--disable-maintainer-mode
+		--disable-moblin
+		--disable-desktop-update
+		--disable-icon-update
+		--disable-schemas-compile
+		--disable-static"
+	DOCS="AUTHORS README NEWS ChangeLog"
+
+	enewgroup plugdev
+}
+
+src_prepare() {
+	# Add missing files for intltool checks
+	echo "sendto/bluetooth-sendto.desktop.in" >> po/POTFILES.in
+	echo "wizard/bluetooth-wizard.desktop.in" >> po/POTFILES.in
+
+	gnome2_src_prepare
+}
+
+src_install() {
+	gnome2_src_install
+
+	local la
+	for la in gnome-bluetooth/plugins/libgbtgeoclue.la \
+			 control-center-1/panels/libbluetooth.la \
+			 libgnome-bluetooth.la; do
+		rm -v "${ED}/usr/$(get_libdir)/${la}" || die
+	done
+
+	insinto /$(get_libdir)/udev/rules.d
+	doins "${FILESDIR}"/80-rfkill.rules || die "udev rules installation failed"
+}
+
+pkg_postinst() {
+	gnome2_pkg_postinst
+	# Notify about old libraries that might still be around
+	preserve_old_lib_notify /usr/$(get_libdir)/libgnome-bluetooth.so.7
+
+	elog "Don't forget to add yourself to the plugdev group "
+	elog "if you want to be able to control bluetooth transmitter."
+}
diff --git a/net-wireless/gnome-bluetooth/metadata.xml b/net-wireless/gnome-bluetooth/metadata.xml
index 25d54e0cae05..5357476f84f3 100644
--- a/net-wireless/gnome-bluetooth/metadata.xml
+++ b/net-wireless/gnome-bluetooth/metadata.xml
@@ -7,6 +7,9 @@
 <use>
 	<flag name="introspection">Use <pkg>dev-libs/gobject-introspection</pkg>
 		for introspection</flag>
-	<flag name='nautilus'>Build nautilus-sendto plugin</flag>
+	<flag name="nautilus">Build the <pkg>gnome-extra/nautilus-sendto</pkg>
+		plugin</flag>
+	<flag name="sendto">Build the <pkg>gnome-extra/nautilus-sendto</pkg>
+		plugin</flag>
 </use>
 </pkgmetadata>