Bump to 2.26.2. Translation updates. Clean up old revisions.

(Portage version: 2.2_rc33/cvs/Linux x86_64)

3 files changed, 77 insertions, 102 deletions

diff --git a/app-crypt/seahorse/ChangeLog b/app-crypt/seahorse/ChangeLog
index 2f6fb5f30bb5..6bce1f6fb216 100644
--- a/app-crypt/seahorse/ChangeLog
+++ b/app-crypt/seahorse/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for app-crypt/seahorse
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.115 2009/05/14 08:53:16 nirbheek Exp $
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/ChangeLog,v 1.116 2009/05/23 20:21:23 eva Exp $
+
+*seahorse-2.26.2 (23 May 2009)
+
+  23 May 2009; Gilles Dartiguelongue <eva@gentoo.org>
+  -seahorse-2.20.3.ebuild, +seahorse-2.26.2.ebuild:
+  Bump to 2.26.2. Translation updates. Clean up old revisions.
 
 *seahorse-2.26.1 (14 May 2009)
 
diff --git a/app-crypt/seahorse/seahorse-2.20.3.ebuild b/app-crypt/seahorse/seahorse-2.20.3.ebuild
deleted file mode 100644
index 48280e3b4aeb..000000000000
--- a/app-crypt/seahorse/seahorse-2.20.3.ebuild
+++ /dev/null
@@ -1,101 +0,0 @@
-# Copyright 1999-2008 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-2.20.3.ebuild,v 1.12 2008/06/15 12:24:26 eva Exp $
-
-EAPI="1"
-
-inherit eutils gnome2
-
-GNOME_TARBALL_SUFFIX="gz"
-
-DESCRIPTION="A GNOME application for managing encryption keys"
-HOMEPAGE="http://www.gnome.org/projects/seahorse/index.html"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="alpha amd64 ia64 ppc ppc64 sparc x86"
-IUSE="applet avahi dbus debug gedit gnome-keyring ldap libnotify nautilus"
-
-RDEPEND=">=gnome-base/libgnome-2.14
-		 >=gnome-base/libgnomeui-2.10
-		 >=gnome-base/gnome-vfs-2.0
-		 >=gnome-base/libglade-2.0
-		 >=gnome-base/gconf-2.0
-		 >=dev-libs/glib-2.10
-		 >=x11-libs/gtk+-2.10
-		 net-libs/libsoup:2.2
-		 >=dev-libs/libxml2-2.6.0
-		 || (
-				=app-crypt/gnupg-1.4*
-				=app-crypt/gnupg-2.0*
-			)
-		 >=app-crypt/gpgme-1.0.0
-		   net-misc/openssh
-		   x11-misc/shared-mime-info
-		 applet? ( >=gnome-base/gnome-panel-2.10 )
-		 avahi? ( >=net-dns/avahi-0.6 )
-		 dbus?	( ||	(
-							>=dev-libs/dbus-glib-0.72
-							( <sys-apps/dbus-0.90 >=sys-apps/dbus-0.60 )
-						)
-				)
-		 gedit? ( >=app-editors/gedit-2.16 )
-		 gnome-keyring? ( gnome-base/gnome-keyring )
-		 ldap? ( net-nds/openldap )
-		 libnotify? ( >=x11-libs/libnotify-0.3.2 )
-		 nautilus? ( >=gnome-base/nautilus-2.10 )"
-DEPEND="${RDEPEND}
-		sys-devel/gettext
-		>=app-text/gnome-doc-utils-0.3.2
-		>=app-text/scrollkeeper-0.3
-		>=dev-util/pkgconfig-0.20
-		>=dev-util/intltool-0.35"
-
-DOCS="AUTHORS ChangeLog NEWS README TODO THANKS"
-
-pkg_setup() {
-	if ! use dbus ; then
-		if use applet ; then
-			elog
-			elog "The panel applet requires that you build seahorse with DBUS support."
-			elog
-		fi
-
-		if use gedit ; then
-			elog
-			elog "The GEdit plugin requires that you build seahorse with DBUS support."
-			elog
-		fi
-
-		eerror "Please add dbus to your USE flags and re-emerge seahorse"
-		eerror "plugins require dbus support"
-	fi
-
-	G2CONF="${G2CONF}
-		--enable-ssh
-		--disable-update-mime-database
-		--enable-hkp --with-keyserver --enable-agent
-		--localstatedir="${D}"/var/lib/scrollkeeper/
-		--disable-epiphany
-		$(use_enable applet)
-		$(use_enable avahi sharing)
-		$(use_enable dbus)
-		$(use_enable debug)
-		$(use_enable gedit)
-		$(use_enable gnome-keyring)
-		$(use_enable ldap)
-		$(use_enable libnotify)
-		$(use_enable nautilus)"
-}
-
-src_unpack() {
-	gnome2_src_unpack
-	epatch "${FILESDIR}/${PN}-0.9.10-update-mime.patch"
-}
-
-src_install() {
-	gnome2_src_install
-
-	# remove conflicts with x11-misc/shared-mime-info
-	rm -rf "${D}/usr/share/mime/"{application,magic,globs,XMLnamespaces}
-}
diff --git a/app-crypt/seahorse/seahorse-2.26.2.ebuild b/app-crypt/seahorse/seahorse-2.26.2.ebuild
new file mode 100644
index 000000000000..2e4710f6786e
--- /dev/null
+++ b/app-crypt/seahorse/seahorse-2.26.2.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/app-crypt/seahorse/seahorse-2.26.2.ebuild,v 1.1 2009/05/23 20:21:23 eva Exp $
+
+EAPI="2"
+
+inherit gnome2
+
+DESCRIPTION="A GNOME application for managing encryption keys"
+HOMEPAGE="http://www.gnome.org/projects/seahorse/index.html"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="avahi debug doc ldap libnotify test"
+
+RDEPEND=">=gnome-base/libglade-2.0
+	>=gnome-base/gconf-2.0
+	>=dev-libs/glib-2.10
+	>=x11-libs/gtk+-2.10
+	>=dev-libs/dbus-glib-0.72
+	>=gnome-base/gnome-keyring-2.25.5
+	net-libs/libsoup:2.4
+	x11-misc/shared-mime-info
+
+	net-misc/openssh
+	>=app-crypt/gpgme-1.0.0
+	|| (
+		=app-crypt/gnupg-1.4*
+		=app-crypt/gnupg-2.0* )
+
+	avahi? ( >=net-dns/avahi-0.6 )
+	ldap? ( net-nds/openldap )
+	libnotify? ( >=x11-libs/libnotify-0.3.2 )"
+DEPEND="${RDEPEND}
+	sys-devel/gettext
+	>=app-text/gnome-doc-utils-0.3.2
+	>=app-text/scrollkeeper-0.3
+	>=dev-util/pkgconfig-0.20
+	>=dev-util/intltool-0.35
+	doc? ( >=dev-util/gtk-doc-1.9 )"
+
+DOCS="AUTHORS ChangeLog NEWS README TODO THANKS"
+
+pkg_setup() {
+	G2CONF="${G2CONF}
+		--enable-pgp
+		--enable-ssh
+		--enable-pkcs11
+		--disable-scrollkeeper
+		--disable-update-mime-database
+		--enable-hkp
+		$(use_enable avahi sharing)
+		$(use_enable debug)
+		$(use_enable ldap)
+		$(use_enable libnotify)
+		$(use_enable test tests)"
+}
+
+src_prepare() {
+	gnome2_src_prepare
+
+	# Fix intltoolize broken file, see upstream #577133
+	sed "s:'\^\$\$lang\$\$':\^\$\$lang\$\$:g" -i po/Makefile.in.in || die "sed failed"
+}
+
+pkg_postinst() {
+	einfo "The seahorse-agent tool has been moved to app-crypt/seahorse-plugins"
+	einfo "Use that if you want seahorse to manage your terminal SSH keys"
+}