Make FLAC++ optional, enabled by default thanks to EAPI=1

(Portage version: 2.1.3.19)

3 files changed, 68 insertions, 1 deletions

diff --git a/media-libs/flac/ChangeLog b/media-libs/flac/ChangeLog
index 17e57f3722a5..bdcaab2608e5 100644
--- a/media-libs/flac/ChangeLog
+++ b/media-libs/flac/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for media-libs/flac
 # Copyright 2002-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/ChangeLog,v 1.132 2007/11/01 19:07:17 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/ChangeLog,v 1.133 2007/11/18 19:22:16 aballier Exp $
+
+*flac-1.2.1-r2 (18 Nov 2007)
+
+  18 Nov 2007; Alexis Ballier <aballier@gentoo.org> +flac-1.2.1-r2.ebuild:
+  Make FLAC++ optional, enabled by default thanks to EAPI=1
 
   01 Nov 2007; Raúl Porcel <armin76@gentoo.org> flac-1.2.1-r1.ebuild:
   sparc stable, thanks to Alex Maclean for testing
diff --git a/media-libs/flac/files/digest-flac-1.2.1-r2 b/media-libs/flac/files/digest-flac-1.2.1-r2
new file mode 100644
index 000000000000..061357afea8b
--- /dev/null
+++ b/media-libs/flac/files/digest-flac-1.2.1-r2
@@ -0,0 +1,3 @@
+MD5 153c8b15a54da428d1f0fadc756c22c7 flac-1.2.1.tar.gz 2009217
+RMD160 bd3223c848054f0a75d11200b30f903bdd375bfc flac-1.2.1.tar.gz 2009217
+SHA256 9635a44bceb478bbf2ee8a785cf6986fba525afb5fad1fd4bba73cf71f2d3edf flac-1.2.1.tar.gz 2009217
diff --git a/media-libs/flac/flac-1.2.1-r2.ebuild b/media-libs/flac/flac-1.2.1-r2.ebuild
new file mode 100644
index 000000000000..7bff4e7a0a34
--- /dev/null
+++ b/media-libs/flac/flac-1.2.1-r2.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/flac/flac-1.2.1-r2.ebuild,v 1.1 2007/11/18 19:22:16 aballier Exp $
+
+EAPI="1"
+
+inherit autotools eutils
+
+DESCRIPTION="free lossless audio encoder and decoder"
+HOMEPAGE="http://flac.sourceforge.net"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-2 LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~x86-fbsd"
+IUSE="3dnow altivec +cxx debug doc ogg sse"
+
+RDEPEND="ogg? ( >=media-libs/libogg-1.1.3 )"
+DEPEND="${RDEPEND}
+	x86? ( dev-lang/nasm )
+	sys-apps/gawk
+	sys-devel/gettext
+	dev-util/pkgconfig"
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	# Stop using upstream CFLAGS. Fix building with
+	# ldflag asneeded on non glibc systems. Fix
+	# broken asm causing text relocations.
+	epatch "${FILESDIR}"/${P}-asneeded.patch
+	epatch "${FILESDIR}"/${P}-cflags.patch
+	epatch "${FILESDIR}"/${P}-asm.patch
+
+	AT_M4DIR="m4" eautoreconf
+}
+
+src_compile() {
+	econf $(use_enable ogg) \
+		$(use_enable sse) \
+		$(use_enable 3dnow) \
+		$(use_enable altivec) \
+		$(use_enable debug) \
+		$(use_enable cxx cpplibs) \
+		--disable-doxygen-docs \
+		--disable-dependency-tracking \
+		--disable-xmms-plugin
+
+	emake || die "emake failed."
+}
+
+src_install() {
+	emake DESTDIR="${D}" install || die "emake install failed."
+
+	rm -rf "${D}"/usr/share/doc/flac-1.2.1
+	dodoc AUTHORS README
+	use doc && dohtml -r doc/html/*
+}