Version bump, many small bug fixes. http://releases.xfce.org/feeds/project/midori - bug 306987

(Portage version: 2.1.8/cvs/Linux x86_64)

2 files changed, 78 insertions, 1 deletions

diff --git a/www-client/midori/ChangeLog b/www-client/midori/ChangeLog
index f8899b48b8d1..f1e2fe7e193d 100644
--- a/www-client/midori/ChangeLog
+++ b/www-client/midori/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for www-client/midori
 # Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.25 2010/01/20 17:56:04 darkside Exp $
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/ChangeLog,v 1.26 2010/03/08 16:01:15 darkside Exp $
+
+*midori-0.2.4 (08 Mar 2010)
+
+  08 Mar 2010; Jeremy Olexa <darkside@gentoo.org> +midori-0.2.4.ebuild:
+  Version bump, many small bug fixes.
+  http://releases.xfce.org/feeds/project/midori - bug 306987
 
   20 Jan 2010; Jeremy Olexa <darkside@gentoo.org> midori-0.2.2.ebuild:
   Add missing bdep on dev-util/intltool, mandatory according to the build
diff --git a/www-client/midori/midori-0.2.4.ebuild b/www-client/midori/midori-0.2.4.ebuild
new file mode 100644
index 000000000000..f9e03f80e373
--- /dev/null
+++ b/www-client/midori/midori-0.2.4.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2010 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-client/midori/midori-0.2.4.ebuild,v 1.1 2010/03/08 16:01:15 darkside Exp $
+
+EAPI=2
+inherit xfconf multilib
+
+DESCRIPTION="A lightweight web browser based on WebKitGTK+"
+HOMEPAGE="http://www.twotoasts.de/index.php?/pages/midori_summary.html"
+SRC_URI="mirror://xfce/src/apps/${PN}/0.2/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86 ~x86-fbsd"
+IUSE="doc gnome html idn libnotify nls +sqlite +unique"
+
+RDEPEND="libnotify? ( x11-libs/libnotify )
+	>=net-libs/libsoup-2.25.2
+	>=net-libs/webkit-gtk-1.1.1
+	dev-libs/libxml2
+	>=x11-libs/gtk+-2.10:2
+	gnome? ( net-libs/libsoup[gnome] )
+	idn? ( net-dns/libidn )
+	sqlite? ( >=dev-db/sqlite-3.0 )
+	unique? ( dev-libs/libunique )"
+
+DEPEND="${RDEPEND}
+	dev-lang/python
+	dev-util/intltool
+	dev-util/pkgconfig
+	doc? ( dev-util/gtk-doc )
+	html? ( dev-python/docutils )
+	nls? ( sys-devel/gettext )"
+
+src_prepare() {
+	# moving docs to version-specific directory
+	sed -i -e "s:\${DOCDIR}/${PN}:\${DOCDIR}/${PF}/:g" wscript || die
+	sed -i -e "s:/${PN}/user/midori.html:/${PF}/user/midori.html:g" midori/midori-browser.c || die
+}
+
+src_configure() {
+	CCFLAGS="${CFLAGS}" LINKFLAGS="${LDFLAGS}" ./waf \
+		--prefix="/usr/" \
+		--libdir="/usr/$(get_libdir)" \
+		--disable-docs \
+		--enable-addons \
+		$(use_enable doc apidocs) \
+		$(use_enable html userdocs) \
+		$(use_enable idn libidn) \
+		$(use_enable libnotify) \
+		$(use_enable nls nls) \
+		$(use_enable sqlite) \
+		$(use_enable unique) \
+		configure || die "configure failed"
+}
+
+src_compile() {
+	NUMJOBS=$(sed -e 's/.*\(\-j[ 0-9]\+\) .*/\1/; s/--jobs=\?/-j/' <<< ${MAKEOPTS})
+	./waf build ${NUMJOBS} || die "build failed"
+}
+
+src_install() {
+	DESTDIR=${D} ./waf install || die "install failed"
+	dodoc AUTHORS ChangeLog INSTALL TODO || die "dodoc failed"
+}
+
+pkg_postinst() {
+	xfconf_pkg_postinst
+	ewarn "Midori tends to crash due to bugs in WebKit."
+	ewarn "Report bugs at http://www.twotoasts.de/bugs"
+}