Clean up old revisions. Add missing vala support for 0.13.3.

(Portage version: 2.2.0_alpha170/cvs/Linux x86_64, signed Manifest commit with key C6085806)

5 files changed, 31 insertions, 154 deletions

diff --git a/dev-libs/libgdata/ChangeLog b/dev-libs/libgdata/ChangeLog
index ce424afc671c..738567a5a2bb 100644
--- a/dev-libs/libgdata/ChangeLog
+++ b/dev-libs/libgdata/ChangeLog
@@ -1,6 +1,10 @@
 # ChangeLog for dev-libs/libgdata
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.62 2013/03/28 16:47:17 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/ChangeLog,v 1.63 2013/03/30 18:34:59 eva Exp $
+
+  30 Mar 2013; Gilles Dartiguelongue <eva@gentoo.org> -libgdata-0.10.2.ebuild,
+  -libgdata-0.12.0.ebuild, libgdata-0.13.3.ebuild, metadata.xml:
+  Clean up old revisions. Add missing vala support for 0.13.3.
 
 *libgdata-0.13.3 (28 Mar 2013)
 
diff --git a/dev-libs/libgdata/libgdata-0.10.2.ebuild b/dev-libs/libgdata/libgdata-0.10.2.ebuild
deleted file mode 100644
index d629520a4b9d..000000000000
--- a/dev-libs/libgdata/libgdata-0.10.2.ebuild
+++ /dev/null
@@ -1,69 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.10.2.ebuild,v 1.4 2012/12/19 04:08:55 tetromino Exp $
-
-EAPI="4"
-GCONF_DEBUG="yes"
-GNOME2_LA_PUNT="yes"
-
-inherit eutils gnome2
-
-DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
-HOMEPAGE="http://live.gnome.org/libgdata"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-IUSE="gnome +introspection static-libs"
-KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
-
-# gtk+ is needed for gdk
-# configure checks for gtk:3, but only uses it for demos which are not installed
-RDEPEND=">=dev-libs/glib-2.19:2
-	|| (
-		>=x11-libs/gdk-pixbuf-2.14:2
-		>=x11-libs/gtk+-2.14:2 )
-	app-misc/ca-certificates
-	>=dev-libs/libxml2-2:2
-	>=net-libs/libsoup-2.26.1:2.4[introspection?]
-	>=net-libs/liboauth-0.9.4
-	gnome? ( >=net-libs/libsoup-gnome-2.26.1:2.4[introspection?] )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )"
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.14
-	>=dev-util/intltool-0.40
-	virtual/pkgconfig"
-
-pkg_setup() {
-	DOCS="AUTHORS ChangeLog HACKING NEWS README"
-	G2CONF="${G2CONF}
-		--with-ca-certs=${EPREFIX}/etc/ssl/certs/ca-certificates.crt
-		$(use_enable static-libs static)
-		$(use_enable gnome)
-		$(use_enable introspection)"
-}
-
-src_prepare() {
-	gnome2_src_prepare
-
-	# Disable tests requiring network access, bug #307725
-	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf\nOLD_\1:' \
-		-i gdata/tests/Makefile.in || die "network test disable failed"
-}
-
-src_test() {
-	unset ORBIT_SOCKETDIR
-	unset DBUS_SESSION_BUS_ADDRESS
-	dbus-launch emake check || die "emake check failed"
-}
-
-pkg_preinst() {
-	gnome2_pkg_preinst
-	preserve_old_lib /usr/$(get_libdir)/libgdata.so.7
-	preserve_old_lib /usr/$(get_libdir)/libgdata.so.11
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.7
-	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.11
-}
diff --git a/dev-libs/libgdata/libgdata-0.12.0.ebuild b/dev-libs/libgdata/libgdata-0.12.0.ebuild
deleted file mode 100644
index cb56fa85caa7..000000000000
--- a/dev-libs/libgdata/libgdata-0.12.0.ebuild
+++ /dev/null
@@ -1,71 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.12.0.ebuild,v 1.2 2012/12/19 04:08:55 tetromino Exp $
-
-EAPI="4"
-GCONF_DEBUG="yes"
-GNOME2_LA_PUNT="yes"
-
-inherit eutils gnome2
-
-DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
-HOMEPAGE="http://live.gnome.org/libgdata"
-
-LICENSE="LGPL-2.1+"
-SLOT="0"
-IUSE="gnome +introspection static-libs"
-KEYWORDS="~amd64 ~x86"
-
-# gtk+ is needed for gdk
-# configure checks for gtk:3, but only uses it for demos which are not installed
-RDEPEND=">=dev-libs/glib-2.30:2
-	>=x11-libs/gdk-pixbuf-2.14:2
-	>=dev-libs/libxml2-2:2
-	>=net-libs/libsoup-2.37.91:2.4[introspection?]
-	>=net-libs/liboauth-0.9.4
-
-	gnome-base/gnome-keyring
-
-	gnome? ( >=net-libs/libsoup-gnome-2.37.91:2.4[introspection?] )
-	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )"
-DEPEND="${RDEPEND}
-	>=dev-util/gtk-doc-am-1.14
-	>=dev-util/intltool-0.40
-	virtual/pkgconfig"
-
-pkg_setup() {
-	DOCS="AUTHORS ChangeLog HACKING NEWS README"
-	G2CONF="${G2CONF}
-		$(use_enable static-libs static)
-		$(use_enable gnome)
-		$(use_enable introspection)"
-}
-
-src_prepare() {
-	# Regenerate marshalers for <glib-2.31 compat
-	rm -v gdata/gdata-marshal.{c,h} || die
-
-	gnome2_src_prepare
-
-	# Disable tests requiring network access, bug #307725
-	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf\nOLD_\1:' \
-		-i gdata/tests/Makefile.in || die "network test disable failed"
-}
-
-src_test() {
-	unset ORBIT_SOCKETDIR
-	unset DBUS_SESSION_BUS_ADDRESS
-	dbus-launch emake check || die "emake check failed"
-}
-
-pkg_preinst() {
-	gnome2_pkg_preinst
-	preserve_old_lib /usr/$(get_libdir)/libgdata.so.7
-	preserve_old_lib /usr/$(get_libdir)/libgdata.so.11
-}
-
-pkg_postinst() {
-	gnome2_pkg_postinst
-	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.7
-	preserve_old_lib_notify /usr/$(get_libdir)/libgdata.so.11
-}
diff --git a/dev-libs/libgdata/libgdata-0.13.3.ebuild b/dev-libs/libgdata/libgdata-0.13.3.ebuild
index c1f4a185b1d3..053f65140f47 100644
--- a/dev-libs/libgdata/libgdata-0.13.3.ebuild
+++ b/dev-libs/libgdata/libgdata-0.13.3.ebuild
@@ -1,19 +1,22 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.13.3.ebuild,v 1.1 2013/03/28 16:47:17 pacho Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/libgdata/libgdata-0.13.3.ebuild,v 1.2 2013/03/30 18:34:59 eva Exp $
 
 EAPI="5"
 GCONF_DEBUG="yes"
+VALA_MIN_API_VERSION="0.20"
+VALA_USE_DEPEND="vapigen"
 
-inherit gnome2
+inherit gnome2 vala
 
 DESCRIPTION="GLib-based library for accessing online service APIs using the GData protocol"
 HOMEPAGE="http://live.gnome.org/libgdata"
 
 LICENSE="LGPL-2.1+"
 SLOT="0/13" # subslot = libgdata soname version
-IUSE="gnome +introspection static-libs"
+IUSE="gnome +introspection static-libs vala"
 KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+REQUIRED_IUSE="vala? ( introspection )"
 
 # gtk+ is needed for gdk
 # configure checks for gtk:3, but only uses it for demos which are not installed
@@ -26,7 +29,9 @@ RDEPEND="
 	gnome? (
 		app-crypt/gcr:=
 		>=net-libs/gnome-online-accounts-3.2
-		>=net-libs/libsoup-gnome-2.37.91:2.4[introspection?] )
+		|| (
+			>=net-libs/libsoup-2.42
+			>=net-libs/libsoup-gnome-2.37.91:2.4[introspection?] ) )
 	introspection? ( >=dev-libs/gobject-introspection-0.9.7 )
 "
 DEPEND="${RDEPEND}
@@ -34,21 +39,26 @@ DEPEND="${RDEPEND}
 	>=dev-util/intltool-0.40
 	>=gnome-base/gnome-common-3.6
 	virtual/pkgconfig
+	vala? ( $(vala_depend) )
 "
 
 src_prepare() {
-	DOCS="AUTHORS ChangeLog HACKING NEWS README"
-	G2CONF="${G2CONF}
-		$(use_enable static-libs static)
-		$(use_enable gnome)
-		$(use_enable gnome goa)
-		$(use_enable introspection)"
+	# Disable tests requiring network access, bug #307725
+	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf\nOLD_\1:' \
+		-i gdata/tests/Makefile.{am,in} || die "network test disable failed"
 
+	vala_src_prepare
 	gnome2_src_prepare
+}
 
-	# Disable tests requiring network access, bug #307725
-	sed -e '/^TEST_PROGS = / s:\(.*\):TEST_PROGS = general perf\nOLD_\1:' \
-		-i gdata/tests/Makefile.in || die "network test disable failed"
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_configure \
+		$(use_enable gnome) \
+		$(use_enable gnome goa) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(use_enable static-libs static)
 }
 
 src_test() {
diff --git a/dev-libs/libgdata/metadata.xml b/dev-libs/libgdata/metadata.xml
index dad9001338dc..005177ffff8f 100644
--- a/dev-libs/libgdata/metadata.xml
+++ b/dev-libs/libgdata/metadata.xml
@@ -2,4 +2,7 @@
 <!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
 <pkgmetadata>
 	<herd>gnome</herd>
+	<use>
+		<flag name="vala">Enable bindings for dev-lang/vala</flag>
+	</use>
 </pkgmetadata>