Convert to distutils-r1. Install winpdb only when wxwidgets is available for the impl.

(Portage version: 2.2.15/cvs/Linux x86_64, signed Manifest commit with key EFB4464E!)

2 files changed, 44 insertions, 3 deletions

diff --git a/dev-python/winpdb/ChangeLog b/dev-python/winpdb/ChangeLog
index f32bcd8544cf..27f805d9cc1e 100644
--- a/dev-python/winpdb/ChangeLog
+++ b/dev-python/winpdb/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-python/winpdb
-# Copyright 1999-2010 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/winpdb/ChangeLog,v 1.25 2010/10/29 19:33:12 arfrever Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/winpdb/ChangeLog,v 1.26 2014/12/15 21:11:09 mgorny Exp $
+
+*winpdb-1.4.8-r1 (15 Dec 2014)
+
+  15 Dec 2014; Michał Górny <mgorny@gentoo.org> +winpdb-1.4.8-r1.ebuild:
+  Convert to distutils-r1. Install winpdb only when wxwidgets is available for
+  the impl.
 
   29 Oct 2010; Arfrever Frehtes Taifersar Arahesis <arfrever@gentoo.org>
   -winpdb-1.4.6.ebuild:
@@ -113,4 +119,3 @@
 
   12 Aug 2005; Rob Cakebread <pythonhead@gentoo.org> +winpdb-1.0.1.ebuild:
   Initial commit.
-
diff --git a/dev-python/winpdb/winpdb-1.4.8-r1.ebuild b/dev-python/winpdb/winpdb-1.4.8-r1.ebuild
new file mode 100644
index 000000000000..aab88363467c
--- /dev/null
+++ b/dev-python/winpdb/winpdb-1.4.8-r1.ebuild
@@ -0,0 +1,36 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/winpdb/winpdb-1.4.8-r1.ebuild,v 1.1 2014/12/15 21:11:09 mgorny Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_7,3_3,3_4} )
+
+inherit distutils-r1
+
+DESCRIPTION="Graphical Python debugger"
+HOMEPAGE="http://winpdb.org/ http://code.google.com/p/winpdb/ http://pypi.python.org/pypi/winpdb"
+SRC_URI="http://${PN}.googlecode.com/files/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ia64 ~x86"
+IUSE="+wxwidgets"
+
+DEPEND=">=dev-python/pycrypto-2.0.1[${PYTHON_USEDEP}]
+	wxwidgets? ( dev-python/wxpython:2.8[$(python_gen_usedep 'python2*')] )"
+RDEPEND="${DEPEND}"
+
+REQUIRED_USE="wxwidgets? ( $(python_gen_useflags 'python2*') )"
+
+python_install() {
+	distutils-r1_python_install
+
+	if ! use wxwidgets || python_is_python3; then
+		find "${D%/}$(python_get_sitedir)" -name 'winpdb*.py*' -delete || die
+		rm "${D%/}$(python_get_scriptdir)"/winpdb || die
+		if ! use wxwidgets; then
+			rm "${ED%/}"/usr/bin/winpdb || die
+		fi
+	fi
+}