Version Bump

(Portage version: 2.2.20/cvs/Linux x86_64, signed Manifest commit with key E9402A79B03529A2!)

2 files changed, 68 insertions, 1 deletions

diff --git a/dev-python/bpython/ChangeLog b/dev-python/bpython/ChangeLog
index 22d7373d601f..c5f0e028bd66 100644
--- a/dev-python/bpython/ChangeLog
+++ b/dev-python/bpython/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-python/bpython
 # Copyright 1999-2015 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-python/bpython/ChangeLog,v 1.54 2015/03/21 16:50:05 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-python/bpython/ChangeLog,v 1.55 2015/05/29 10:38:06 jlec Exp $
+
+*bpython-0.14.2 (29 May 2015)
+
+  29 May 2015; Justin Lecher <jlec@gentoo.org> +bpython-0.14.2.ebuild:
+  Version Bump
 
   21 Mar 2015; Justin Lecher <jlec@gentoo.org> bpython-0.13.1.ebuild,
   bpython-0.13.2.ebuild:
diff --git a/dev-python/bpython/bpython-0.14.2.ebuild b/dev-python/bpython/bpython-0.14.2.ebuild
new file mode 100644
index 000000000000..a9164ec99905
--- /dev/null
+++ b/dev-python/bpython/bpython-0.14.2.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/bpython/bpython-0.14.2.ebuild,v 1.1 2015/05/29 10:38:06 jlec Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 python3_{3,4} )
+
+PYTHON_REQ_USE="ncurses"
+
+inherit distutils-r1
+
+DESCRIPTION="Syntax highlighting and autocompletion for the Python interpreter"
+HOMEPAGE="http://www.bpython-interpreter.org/ https://bitbucket.org/bobf/bpython/ http://pypi.python.org/pypi/bpython"
+SRC_URI="
+	http://www.bpython-interpreter.org/releases/${P}.tar.gz
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND="
+	>=dev-python/curtsies-0.1.18[${PYTHON_USEDEP}]
+	<dev-python/curtsies-0.2.0[${PYTHON_USEDEP}]
+	dev-python/greenlet[${PYTHON_USEDEP}]
+	dev-python/jedi[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/six-1.5[${PYTHON_USEDEP}]
+	dev-python/urwid[${PYTHON_USEDEP}]
+	dev-python/watchdog[${PYTHON_USEDEP}]
+	"
+DEPEND="${RDEPEND}
+	doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( dev-python/mock[${PYTHON_USEDEP}] )"
+
+DOCS=( AUTHORS CHANGELOG sample.theme light.theme )
+
+# Req'd for clean build by each impl
+DISTUTILS_IN_SOURCE_BUILD=1
+
+python_compile_all() {
+	if use doc; then
+		sphinx-build -b html -c doc/sphinx/source/ \
+			doc/sphinx/source/ doc/sphinx/source/html || die "docs build failed"
+	fi
+}
+
+python_test() {
+	pushd build/lib > /dev/null
+	"${PYTHON}" -m unittest discover || die
+	popd > /dev/null
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( doc/sphinx/source/html/. )
+	distutils-r1_python_install_all
+}