Version bump. Add ruby19. Drop arches due to bug 396547.

(Portage version: 2.1.10.41/cvs/Linux x86_64)

2 files changed, 62 insertions, 1 deletions

diff --git a/dev-ruby/mail/ChangeLog b/dev-ruby/mail/ChangeLog
index ec22e5d0815c..b68bd0f7a97a 100644
--- a/dev-ruby/mail/ChangeLog
+++ b/dev-ruby/mail/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for dev-ruby/mail
 # Copyright 1999-2011 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-ruby/mail/ChangeLog,v 1.16 2011/10/16 08:14:31 graaff Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/mail/ChangeLog,v 1.17 2011/12/30 19:44:10 graaff Exp $
+
+*mail-2.3.0 (30 Dec 2011)
+
+  30 Dec 2011; Hans de Graaff <graaff@gentoo.org> +mail-2.3.0.ebuild:
+  Version bump. Add ruby19. Drop arches due to bug 396547.
 
   16 Oct 2011; Hans de Graaff <graaff@gentoo.org> -mail-2.2.18.ebuild:
   Remove old version.
diff --git a/dev-ruby/mail/mail-2.3.0.ebuild b/dev-ruby/mail/mail-2.3.0.ebuild
new file mode 100644
index 000000000000..454a10841cce
--- /dev/null
+++ b/dev-ruby/mail/mail-2.3.0.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-ruby/mail/mail-2.3.0.ebuild,v 1.1 2011/12/30 19:44:10 graaff Exp $
+
+EAPI=4
+USE_RUBY="ruby18 ruby19 ree18"
+
+RUBY_FAKEGEM_TASK_TEST="spec"
+
+RUBY_FAKEGEM_DOCDIR="rdoc"
+RUBY_FAKEGEM_EXTRADOC="CHANGELOG.rdoc README.rdoc TODO.rdoc"
+
+RUBY_FAKEGEM_GEMSPEC="mail.gemspec"
+
+inherit ruby-fakegem
+
+GITHUB_USER="mikel"
+COMMIT="e8ec8d53c4f5c889691630d0422b9dc044762f1b"
+
+DESCRIPTION="An email handling library"
+HOMEPAGE="https://github.com/mikel/mail"
+SRC_URI="https://github.com/${GITHUB_USER}/mail/tarball/${COMMIT} -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="2.3"
+KEYWORDS="~amd64 ~x86 ~sparc-solaris ~x86-solaris"
+IUSE=""
+
+RUBY_S="${GITHUB_USER}-${PN}-*"
+
+ruby_add_rdepend "
+	>=dev-ruby/activesupport-2.3.6
+	>=dev-ruby/i18n-0.4.0
+	>=dev-ruby/mime-types-1.16
+	>=dev-ruby/treetop-1.4.8"
+
+ruby_add_bdepend "doc? ( dev-ruby/rspec:0 )
+	test? ( dev-ruby/rspec:0 )"
+
+all_ruby_prepare() {
+	sed -i -e '/[Bb]undle/d' -e '6d' Rakefile || die "Unable to remove Bundler code."
+
+	# Fix up dependencies to match our own.
+	sed -i -e 's/~>/>=/' mail.gemspec || die "Unable to fix up dependencies."
+}
+
+each_ruby_prepare() {
+	# Comment out failing specs on ruby19. Reported upstream:
+	# https://github.com/mikel/mail/issues/318
+	case ${RUBY} in
+		*ruby19)
+			sed -i -e '/should return itself on sort/,/end/ s:^:#:' spec/mail/parts_list_spec.rb || die
+			sed -i -e '/should encode a non us-ascii filename/,/^    end/ s:^:#:' spec/mail/fields/content_type_field_spec.rb || die
+			;;
+	esac
+}