Version bump.

(Portage version: 2.1.3.15)

3 files changed, 308 insertions, 1 deletions

diff --git a/sys-libs/glibc/ChangeLog b/sys-libs/glibc/ChangeLog
index a940f6e89650..7ca1d7da7490 100644
--- a/sys-libs/glibc/ChangeLog
+++ b/sys-libs/glibc/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for sys-libs/glibc
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-libs/glibc/ChangeLog,v 1.558 2007/10/17 16:48:59 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/glibc/ChangeLog,v 1.559 2007/10/22 17:10:09 vapier Exp $
+
+*glibc-2.7 (22 Oct 2007)
+
+  22 Oct 2007; Mike Frysinger <vapier@gentoo.org> +glibc-2.7.ebuild:
+  Version bump.
 
   17 Oct 2007; Raúl Porcel <armin76@gentoo.org> glibc-2.6.1.ebuild:
   alpha/ia64/sparc stable wrt #195427
diff --git a/sys-libs/glibc/files/digest-glibc-2.7 b/sys-libs/glibc/files/digest-glibc-2.7
new file mode 100644
index 000000000000..817564b32b42
--- /dev/null
+++ b/sys-libs/glibc/files/digest-glibc-2.7
@@ -0,0 +1,12 @@
+MD5 b7ff01b9532a35dcd2d0f33233d1fa51 glibc-2.7-patches-1.0.tar.bz2 85492
+RMD160 4ce6bde232829b415d3cec6dbadc9e00e0c47db5 glibc-2.7-patches-1.0.tar.bz2 85492
+SHA256 2d0d147bec11273ace68e8d662dddbde66823a4702a1e2b80499e4fa6c5b8476 glibc-2.7-patches-1.0.tar.bz2 85492
+MD5 065c5952b439deba40083ccd67bcc8f7 glibc-2.7.tar.bz2 15976860
+RMD160 c5c0b5a611d26956c46a289478b3349cea2ebf72 glibc-2.7.tar.bz2 15976860
+SHA256 4224a522ac4ee0fd89eb337e7505e280dfb05e2fe1ad44339ba8874081c0451a glibc-2.7.tar.bz2 15976860
+MD5 226809992fb1f3dc6ea23e0f26952ea4 glibc-libidn-2.7.tar.bz2 101939
+RMD160 17a9692cc59d9f41d6b9fcd68f283f401e206483 glibc-libidn-2.7.tar.bz2 101939
+SHA256 07de78810a5320d696792b67131c4cf3d6654aee015a6b74820d66fb00799000 glibc-libidn-2.7.tar.bz2 101939
+MD5 eaeb8527b8fa286c2d887157214f9998 glibc-ports-2.7.tar.bz2 435392
+RMD160 b9b96b357a394f29d5617aaa26a2c000bcf88874 glibc-ports-2.7.tar.bz2 435392
+SHA256 3e481996259af87c3581da23481970a27de679e3c87cfa9a5a59751cd20c7b44 glibc-ports-2.7.tar.bz2 435392
diff --git a/sys-libs/glibc/glibc-2.7.ebuild b/sys-libs/glibc/glibc-2.7.ebuild
new file mode 100644
index 000000000000..da9f251d40f0
--- /dev/null
+++ b/sys-libs/glibc/glibc-2.7.ebuild
@@ -0,0 +1,290 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-libs/glibc/glibc-2.7.ebuild,v 1.1 2007/10/22 17:10:09 vapier Exp $
+
+inherit eutils versionator libtool toolchain-funcs flag-o-matic gnuconfig multilib
+
+DESCRIPTION="GNU libc6 (also called glibc2) C library"
+HOMEPAGE="http://www.gnu.org/software/libc/libc.html"
+
+LICENSE="LGPL-2"
+#KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+RESTRICT="strip" # strip ourself #46186
+EMULTILIB_PKG="true"
+
+# Configuration variables
+RELEASE_VER=$(get_version_component_range 1-3) # major glibc version
+BRANCH_UPDATE=$(get_version_component_range 4) # upstream cvs snaps
+MANPAGE_VER=""                                 # pregenerated manpages
+INFOPAGE_VER=""                                # pregenerated infopages
+PATCH_VER="1.0"                                # Gentoo patchset
+PATCH_GLIBC_VER=${RELEASE_VER}                 # glibc version in patchset
+PORTS_VER=${RELEASE_VER}                       # version of glibc ports addon
+LT_VER=""                                      # version of linuxthreads addon
+NPTL_KERN_VER=${NPTL_KERN_VER:-"2.6.9"}        # min kernel version nptl requires
+#LT_KERN_VER=${LT_KERN_VER:-"2.4.1"}           # min kernel version linuxthreads requires
+
+[[ ${CTARGET} == hppa* ]] && NPTL_KERN_VER=${NPTL_KERN_VER:-2.6.20}
+
+IUSE="debug nls hardened multilib selinux glibc-omitfp profile glibc-compat20 ${LT_VER:+nptl nptlonly}"
+S=${WORKDIR}/glibc-${RELEASE_VER}
+
+# Here's how the cross-compile logic breaks down ...
+#  CTARGET - machine that will target the binaries
+#  CHOST   - machine that will host the binaries
+#  CBUILD  - machine that will build the binaries
+# If CTARGET != CHOST, it means you want a libc for cross-compiling.
+# If CHOST != CBUILD, it means you want to cross-compile the libc.
+#  CBUILD = CHOST = CTARGET    - native build/install
+#  CBUILD != (CHOST = CTARGET) - cross-compile a native build
+#  (CBUILD = CHOST) != CTARGET - libc for cross-compiler
+#  CBUILD != CHOST != CTARGET  - cross-compile a libc for a cross-compiler
+# For install paths:
+#  CHOST = CTARGET  - install into /
+#  CHOST != CTARGET - install into /usr/CTARGET/
+
+export CBUILD=${CBUILD:-${CHOST}}
+export CTARGET=${CTARGET:-${CHOST}}
+if [[ ${CTARGET} == ${CHOST} ]] ; then
+	if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
+		export CTARGET=${CATEGORY/cross-}
+	fi
+fi
+
+is_crosscompile() {
+	[[ ${CHOST} != ${CTARGET} ]]
+}
+alt_libdir() {
+	if is_crosscompile ; then
+		echo /usr/${CTARGET}/$(get_libdir)
+	else
+		echo /$(get_libdir)
+	fi
+}
+
+if is_crosscompile ; then
+	SLOT="${CTARGET}-2.2"
+else
+	# Why SLOT 2.2 you ask yourself while sippin your tea ?
+	# Everyone knows 2.2 > 0, duh.
+	SLOT="2.2"
+	PROVIDE="virtual/libc"
+fi
+
+# General: We need a new-enough binutils for as-needed
+# arch: we need to make sure our binutils/gcc supports TLS
+DEPEND=">=sys-devel/gcc-3.4.4
+	arm? ( >=sys-devel/binutils-2.16.90 >=sys-devel/gcc-4.1.0 )
+	ppc? ( >=sys-devel/gcc-4.1.0 )
+	ppc64? ( >=sys-devel/gcc-4.1.0 )
+	>=sys-devel/binutils-2.15.94
+	${LT_VER:+nptl? (} >=sys-kernel/linux-headers-${NPTL_KERN_VER} ${LT_VER:+)}
+	|| ( >=sys-devel/gcc-config-1.3.12 app-admin/eselect-compiler )
+	>=app-misc/pax-utils-0.1.10
+	virtual/os-headers
+	nls? ( sys-devel/gettext )
+	>=sys-apps/portage-2.1.2
+	selinux? ( sys-libs/libselinux )"
+RDEPEND="nls? ( sys-devel/gettext )
+	selinux? ( sys-libs/libselinux )"
+
+if [[ ${CATEGORY/cross-} != ${CATEGORY} ]] ; then
+	DEPEND="${DEPEND} ${CATEGORY}/gcc"
+	[[ ${CATEGORY} == *-linux* ]] && DEPEND="${DEPEND} ${CATEGORY}/linux-headers"
+else
+	DEPEND="${DEPEND} >=sys-libs/timezone-data-2007c"
+	RDEPEND="${RDEPEND} sys-libs/timezone-data"
+fi
+
+SRC_URI=$(
+	upstream_uris() {
+		echo mirror://gnu/glibc/$1 ftp://sources.redhat.com/pub/glibc/{releases,snapshots}/$1
+	}
+	gentoo_uris() {
+		local devspace="HTTP~vapier/dist/URI HTTP~azarah/glibc/URI"
+		devspace=${devspace//HTTP/http://dev.gentoo.org/}
+		echo mirror://gentoo/$1 ${devspace//URI/$1}
+	}
+
+	upstream_uris glibc-${RELEASE_VER}.tar.bz2
+	upstream_uris glibc-libidn-${RELEASE_VER}.tar.bz2
+
+	[[ -n ${PORTS_VER}     ]] && upstream_uris glibc-ports-${PORTS_VER}.tar.bz2
+	[[ -n ${LT_VER}        ]] && upstream_uris glibc-linuxthreads-${LT_VER}.tar.bz2
+	[[ -n ${BRANCH_UPDATE} ]] && gentoo_uris glibc-${RELEASE_VER}-branch-update-${BRANCH_UPDATE}.patch.bz2
+	[[ -n ${PATCH_VER}     ]] && gentoo_uris glibc-${PATCH_GLIBC_VER}-patches-${PATCH_VER}.tar.bz2
+	[[ -n ${MANPAGE_VER}   ]] && gentoo_uris glibc-manpages-${MANPAGE_VER}.tar.bz2
+	[[ -n ${INFOPAGE_VER}  ]] && gentoo_uris glibc-infopages-${INFOPAGE_VER}.tar.bz2
+)
+
+# eblit-include [--skip] <function> [version]
+eblit-include() {
+	local skipable=false
+	[[ $1 == "--skip" ]] && skipable=true && shift
+
+	local e v func=$1 ver=$2
+	[[ -z ${func} ]] && die "Usage: eblit-include <function> [version]"
+	for v in ${ver:+-}${ver} -${PVR} -${PV} "" ; do
+		e="${FILESDIR}/eblits/${func}${v}.eblit"
+		if [[ -e ${e} ]] ; then
+			source "${e}"
+			return 0
+		fi
+	done
+	${skipable} && return 0
+	die "Could not locate requested eblit '${func}' in ${FILESDIR}/eblits/"
+}
+
+# eblit-run <function> [version]
+# aka: src_unpack() { eblit-run src_unpack ; }
+eblit-run() {
+	eblit-include --skip common "${*:2}"
+	eblit-include "$@"
+	eblit-${PN}-$1 || die
+}
+
+src_unpack()  { eblit-run src_unpack  ; }
+src_compile() { eblit-run src_compile ; }
+src_test()    { eblit-run src_test    ; }
+src_install() { eblit-run src_install ; }
+
+pkg_setup() {
+	die "Review 196720 before upgrading mmmkay"
+
+	# prevent native builds from downgrading ... maybe update to allow people
+	# to change between diff -r versions ? (2.3.6-r4 -> 2.3.6-r2)
+	if [[ ${ROOT} != "/" ]] && ! tc-is-cross-compiler ; then
+		if has_version '>'${CATEGORY}/${PF} ; then
+			eerror "Sanity check to keep you from breaking your system:"
+			eerror " Downgrading glibc is not supported and a sure way to destruction"
+			die "aborting to save your system"
+		fi
+	fi
+
+	# users have had a chance to phase themselves, time to give em the boot
+	if [[ -e ${ROOT}/etc/locale.gen ]] && [[ -e ${ROOT}/etc/locales.build ]] ; then
+		eerror "You still haven't deleted ${ROOT}/etc/locales.build."
+		eerror "Do so now after making sure ${ROOT}/etc/locale.gen is kosher."
+		die "lazy upgrader detected"
+	fi
+
+	if [[ ${CTARGET} == i386-* ]] ; then
+		eerror "i386 CHOSTs are no longer supported."
+		eerror "Chances are you don't actually want/need i386."
+		eerror "Please read http://www.gentoo.org/doc/en/change-chost.xml"
+		die "please fix your CHOST"
+	fi
+
+	if [[ -n ${LT_VER} ]] ; then
+		if use nptlonly && ! use nptl ; then
+			eerror "If you want nptlonly, add nptl to your USE too ;p"
+			die "nptlonly without nptl"
+		fi
+	fi
+
+	if [[ -e /proc/xen ]] && [[ $(tc-arch) == "x86" ]] && ! is-flag -mno-tls-direct-seg-refs ; then
+		ewarn "You are using Xen but don't have -mno-tls-direct-seg-refs in your CFLAGS."
+		ewarn "This will result in a 50% performance penalty, which is probably not what you want."
+	fi
+
+	use hardened && ! gcc-specs-pie && \
+		ewarn "PIE hardening not applied, as your compiler doesn't default to PIE"
+}
+
+fix_lib64_symlinks() {
+	# the original Gentoo/AMD64 devs decided that since 64bit is the native
+	# bitdepth for AMD64, lib should be used for 64bit libraries. however,
+	# this ignores the FHS and breaks multilib horribly... especially
+	# since it wont even work without a lib64 symlink anyways. *rolls eyes*
+	# see bug 59710 for more information.
+	# Travis Tilley <lv@gentoo.org> (08 Aug 2004)
+	if [ -L ${ROOT}/lib64 ] ; then
+		ewarn "removing /lib64 symlink and moving lib to lib64..."
+		ewarn "dont hit ctrl-c until this is done"
+		rm ${ROOT}/lib64
+		# now that lib64 is gone, nothing will run without calling ld.so
+		# directly. luckily the window of brokenness is almost non-existant
+		use amd64 && /lib/ld-linux-x86-64.so.2 /bin/mv ${ROOT}/lib ${ROOT}/lib64
+		use ppc64 && /lib/ld64.so.1 /bin/mv ${ROOT}/lib ${ROOT}/lib64
+		# all better :)
+		ldconfig
+		ln -s lib64 ${ROOT}/lib
+		einfo "done! :-)"
+		einfo "fixed broken lib64/lib symlink in ${ROOT}"
+	fi
+	if [ -L ${ROOT}/usr/lib64 ] ; then
+		rm ${ROOT}/usr/lib64
+		mv ${ROOT}/usr/lib ${ROOT}/usr/lib64
+		ln -s lib64 ${ROOT}/usr/lib
+		einfo "fixed broken lib64/lib symlink in ${ROOT}/usr"
+	fi
+	if [ -L ${ROOT}/usr/X11R6/lib64 ] ; then
+		rm ${ROOT}/usr/X11R6/lib64
+		mv ${ROOT}/usr/X11R6/lib ${ROOT}/usr/X11R6/lib64
+		ln -s lib64 ${ROOT}/usr/X11R6/lib
+		einfo "fixed broken lib64/lib symlink in ${ROOT}/usr/X11R6"
+	fi
+}
+
+pkg_preinst() {
+	# PPC64+others may want to eventually be added to this logic if they
+	# decide to be multilib compatible and FHS compliant. note that this
+	# chunk of FHS compliance only applies to 64bit archs where 32bit
+	# compatibility is a major concern (not IA64, for example).
+
+	# amd64's 2005.0 is the first amd64 profile to not need this code.
+	# 2005.0 is setup properly, and this is executed as part of the
+	# 2004.3 -> 2005.0 upgrade script.
+	# It can be removed after 2004.3 has been purged from portage.
+	{ use amd64 || use ppc64; } && [ "$(get_libdir)" == "lib64" ] && ! has_multilib_profile && fix_lib64_symlinks
+
+	# it appears that /lib/tls is sometimes not removed.  See bug
+	# 69258 for more info.
+	if [[ -d ${ROOT}/$(alt_libdir)/tls ]] && [[ ! -d ${D}/$(alt_libdir)/tls ]] ; then
+		ewarn "nptlonly or -nptl in USE, removing /${ROOT}$(alt_libdir)/tls..."
+		rm -r "${ROOT}"/$(alt_libdir)/tls || die
+	fi
+
+	# Shouldnt need to keep this updated
+	[[ -e ${ROOT}/etc/locale.gen ]] && rm -f "${D}"/etc/locale.gen
+
+	# simple test to make sure our new glibc isnt completely broken.
+	# make sure we don't test with statically built binaries since
+	# they will fail.  also, skip if this glibc is a cross compiler.
+	[[ ${ROOT} != "/" ]] && return 0
+	[[ -d ${D}/$(get_libdir) ]] || return 0
+	local x striptest
+	for x in date env ls true uname ; do
+		x=$(type -p ${x})
+		[[ -z ${x} ]] && continue
+		striptest=$(LC_ALL="C" file -L ${x} 2>/dev/null)
+		[[ -z ${striptest} ]] && continue
+		[[ ${striptest} == *"statically linked"* ]] && continue
+		"${D}"/$(get_libdir)/ld-*.so \
+			--library-path "${D}"/$(get_libdir) \
+			${x} > /dev/null \
+			|| die "simple run test (${x}) failed"
+	done
+}
+
+pkg_postinst() {
+	if ! tc-is-cross-compiler && [[ -x ${ROOT}/usr/sbin/iconvconfig ]] ; then
+		# Generate fastloading iconv module configuration file.
+		"${ROOT}"/usr/sbin/iconvconfig --prefix="${ROOT}"
+	fi
+
+	if ! is_crosscompile && [[ ${ROOT} == "/" ]] ; then
+		# Reload init ...
+		/sbin/telinit U
+
+		# if the host locales.gen contains no entries, we'll install everything
+		local locale_list="${ROOT}etc/locale.gen"
+		if [[ -z $(locale-gen --list --config "${locale_list}") ]] ; then
+			ewarn "Generating all locales; edit /etc/locale.gen to save time/space"
+			locale_list="${ROOT}usr/share/i18n/SUPPORTED"
+		fi
+		local x jobs
+		for x in ${MAKEOPTS} ; do [[ ${x} == -j* ]] && jobs=${x#-j} ; done
+		locale-gen -j ${jobs:-1} --config "${locale_list}"
+	fi
+}