Revision bump. Fixed initscript #223853.

(Portage version: 2.1.5.2)

3 files changed, 147 insertions, 1 deletions

diff --git a/dev-util/buildbot/ChangeLog b/dev-util/buildbot/ChangeLog
index cbe0a55c7186..2bb1c66feb95 100644
--- a/dev-util/buildbot/ChangeLog
+++ b/dev-util/buildbot/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-util/buildbot
 # Copyright 1999-2008 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.20 2008/05/27 16:45:29 corsair Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/ChangeLog,v 1.21 2008/05/27 18:02:47 hawking Exp $
+
+*buildbot-0.7.7-r1 (27 May 2008)
+
+  27 May 2008; Ali Polatel <hawking@gentoo.org> +files/buildbot.initd-r1,
+  +buildbot-0.7.7-r1.ebuild:
+  Revision bump. Fixed initscript #223853.
 
   27 May 2008; Markus Rothe <corsair@gentoo.org> buildbot-0.7.6.ebuild:
   Stable on ppc64; bug #223437
diff --git a/dev-util/buildbot/buildbot-0.7.7-r1.ebuild b/dev-util/buildbot/buildbot-0.7.7-r1.ebuild
new file mode 100644
index 000000000000..8f399f4eee30
--- /dev/null
+++ b/dev-util/buildbot/buildbot-0.7.7-r1.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2008 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/buildbot-0.7.7-r1.ebuild,v 1.1 2008/05/27 18:02:47 hawking Exp $
+
+NEED_PYTHON="2.3"
+
+inherit distutils eutils
+
+DESCRIPTION="A Python system to automate the compile/test cycle to validate code changes"
+HOMEPAGE="http://buildbot.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86"
+IUSE="doc irc mail test web"
+
+CDEPEND=">=dev-python/twisted-2.0.1"
+RDEPEND="${CDEPEND}
+	mail? ( dev-python/twisted-mail )
+	irc? ( dev-python/twisted-words )
+	web? ( dev-python/twisted-web )"
+DEPEND="${CDEPEND}
+	test? ( dev-python/twisted-web
+		dev-python/twisted-mail )
+	doc? ( =dev-python/epydoc-2* )"
+
+pkg_setup() {
+	enewuser buildbot
+}
+
+src_unpack() {
+	unpack ${A}
+	cd "${S}"
+
+	epatch "${FILESDIR}/${PN}-0.7.5-root-skip-tests.patch"
+}
+
+src_compile() {
+	distutils_src_compile
+	if use doc; then
+		PYTHONPATH=. "${python}" docs/epyrun -o docs/reference || \
+			die "epyrun failed"
+	fi
+}
+
+src_test() {
+	local trialopts
+	if ! has_version ">=dev-python/twisted-2.2"; then
+		trialopts=-R
+	fi
+	PYTHONPATH=. trial ${trialopts} buildbot || die "tests failed!"
+}
+
+src_install() {
+	distutils_src_install
+	doinfo docs/buildbot.info
+	dohtml -r docs/buildbot.html docs/images
+
+	insinto /usr/share/doc/${PF}
+	doins -r docs/examples
+
+	use doc && doins -r docs/reference
+
+	newconfd "${FILESDIR}/buildslave.confd" buildslave
+	newinitd "${FILESDIR}/buildbot.initd-r1" buildslave
+	newconfd "${FILESDIR}/buildmaster.confd" buildmaster
+	newinitd "${FILESDIR}/buildbot.initd-r1" buildmaster
+
+	# Make it print the right names when you start/stop the script.
+	sed -i -e 's/@buildbot@/buildslave/' \
+		"${D}/etc/init.d/buildslave" || die "buildslave sed failed"
+	sed -i -e 's/@buildbot@/buildmaster/' \
+		"${D}/etc/init.d/buildmaster" || die "buildmaster sed failed"
+}
+
+pkg_postinst() {
+	elog 'The "buildbot" user and the "buildmaster" and "buildslave" init'
+	elog "scripts were added to support starting buildbot through gentoo's"
+	elog "init system.  To use this set up your build master or build slave"
+	elog "following the buildbot documentation, make sure the resulting"
+	elog 'directories are owned by the "buildbot" user and point'
+	elog "${ROOT}etc/conf.d/buildmaster or ${ROOT}etc/conf.d/buildslave"
+	elog "at the right location.  The scripts can run as a different user"
+	elog "if desired.  If you need to run more than one master or slave"
+	elog "just copy the scripts."
+	elog ""
+	elog "Upstream recommends the following when upgrading:"
+	elog "Each time you install a new version of Buildbot, you should run the new"
+	elog "'buildbot upgrade-master' command on each of your pre-existing buildmasters."
+	elog "This will add files and fix (or at least detect) incompatibilities between"
+	elog "your old config and the new code."
+}
diff --git a/dev-util/buildbot/files/buildbot.initd-r1 b/dev-util/buildbot/files/buildbot.initd-r1
new file mode 100644
index 000000000000..167e4279d2a6
--- /dev/null
+++ b/dev-util/buildbot/files/buildbot.initd-r1
@@ -0,0 +1,48 @@
+#!/sbin/runscript
+# Copyright 1999-2006 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-util/buildbot/files/buildbot.initd-r1,v 1.1 2008/05/27 18:02:47 hawking Exp $
+
+depend() {
+	need net
+}
+
+checkconfig() {
+	if [ -z "${BASEDIR}" ]; then
+		eerror "BASEDIR not set"
+		return 1
+	fi
+	if [ -z "${USERNAME}" ]; then
+		eerror "USERNAME not set"
+		return 1
+	fi
+	if [ ! -d "${BASEDIR}" ]; then
+		eerror "${BASEDIR} is not a directory"
+		return 1
+	fi
+	if [ ! -e "${BASEDIR}/buildbot.tac" ]; then
+		eerror "${BASEDIR} does not contain buildbot.tac"
+		return 1
+	fi
+}
+
+start() {
+	checkconfig || return 1
+	ebegin "Starting @buildbot@ in ${BASEDIR}"
+	# We set HOME here to make something valid show up in the env of child
+	# processes spawned by the buildslave.
+	start-stop-daemon --start -c "${USERNAME}" --quiet \
+		--env HOME="${BASEDIR}" \
+		--exec /usr/bin/python -- /usr/bin/twistd \
+		--no_save \
+		--logfile="${BASEDIR}/twistd.log" \
+		--pidfile="${BASEDIR}/@buildbot@.pid" \
+		--python="${BASEDIR}/buildbot.tac"
+	eend $?
+}
+
+stop() {
+	ebegin "Stopping @buildbot@ in ${BASEDIR}"
+	start-stop-daemon --stop --quiet --pidfile "${BASEDIR}/@buildbot@.pid"
+	eend $?
+}