From da9dbeff54b558ca85143193b039236865507bd7 Mon Sep 17 00:00:00 2001
From: Andrei Horodniceanu <a.horodniceanu@proton.me>
Date: Thu, 30 May 2024 20:12:31 +0300
Subject: dev-util/dub: drop 1.36.0-r1

Signed-off-by: Andrei Horodniceanu <a.horodniceanu@proton.me>
---
 dev-util/dub/Manifest             |   1 -
 dev-util/dub/dub-1.36.0-r1.ebuild | 162 --------------------------------------
 2 files changed, 163 deletions(-)
 delete mode 100644 dev-util/dub/dub-1.36.0-r1.ebuild

diff --git a/dev-util/dub/Manifest b/dev-util/dub/Manifest
index 0e73d93..598c49a 100644
--- a/dev-util/dub/Manifest
+++ b/dev-util/dub/Manifest
@@ -1,5 +1,4 @@
 DIST dub-1.35.1.tar.gz 1494965 BLAKE2B 400e210584660f7ac67732006ca6d88156adbbf2bf221aa244e317bf7c2772a6a01d9e141252fbf0cfde4c07302ee533593f3a2f418f9e120edc7359a83180cf SHA512 a371a7ec7003a4a4fb642a3567fce0685c99f4940a02de94d026bdc6fe4e84512b16e4bb57673da4d3b8e25177cc3df329da41862086cecc7b98aec1ebf9e4e7
-DIST dub-1.36.0.tar.gz 1502081 BLAKE2B 2ae9503d5c8725de801d65a06fab07e9e3b8fbb007159b1e90fda18d2ca1f0361b055cf2de4e4290828a7fb401168b15c1a85eca872a58d7ce0d5eb5f979ff4e SHA512 7a0e5c5432bbe6d67be8f98e8bc7ef0350e9eb358b13f795b9c18ef9a781dc3092074d88b7a846cf69e1ba648641c6acd8b766ec4bf119ce9b380d886f87b4c3
 DIST dub-1.37.0.tar.gz 1515440 BLAKE2B 13bb5b5541af6ae11e45cf130e9bfb706e7fb59797e497a33e419500262fd70ef1ac657b2b230224010d78b36361f7974d38b22fd36fa70f580c3b7f7a578457 SHA512 dc4331b77681d05bc5c6f36f5179d2a1220f3e1cbfc64ba27104fb2b716bd7e2b70c5b3b4d0e8b786caf36632c2fd774bbd51b235389ff38cfde87138fc9de18
 DIST gitcompatibledubpackage-1.0.1.zip 1354 BLAKE2B 60c3ff78c9cc0ca16f36bfdb4d91f6ec7e8d1bc7fb2fae9488e3f24b33fc3b578157f3c2fd9f892743b1fba7ec473267d9027febd3c27ac2af52733e146c341d SHA512 0adb8a97cce0aaac1dbaea978aacf801071457c06413e618b0feb1adaf4169c7a1acbfac2d9c192fada4f2f8bd44e1ea3b9fce8c7cb3fb8bf364eba75f559122
 DIST gitcompatibledubpackage-1.0.4.zip 2041 BLAKE2B 595080956881fd86753b17cdbb12108ab03161806ca51c748017f29251dd47a95a0aebde4442db1783602cfa67a9593014ebb6ca591dcfec2b08eef3d737e2cc SHA512 12057117be99bb4d2351af74cfd36c050734383bfc44b185cf5f9737d982e9fd6840f6968a3246b625d4ec90e9d30f5e394f8fa1febb85464429d771bc8062d0
diff --git a/dev-util/dub/dub-1.36.0-r1.ebuild b/dev-util/dub/dub-1.36.0-r1.ebuild
deleted file mode 100644
index 608e02a..0000000
--- a/dev-util/dub/dub-1.36.0-r1.ebuild
+++ /dev/null
@@ -1,162 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DESCRIPTION="Package and build management system for D"
-HOMEPAGE="https://code.dlang.org/"
-LICENSE="MIT"
-
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~x86"
-IUSE="doc test"
-RESTRICT="!test? ( test )"
-
-DLANG_COMPAT=( dmd-2_{106..107} gdc-13 ldc2-1_{35..36} )
-
-inherit dlang-single shell-completion
-
-REQUIRED_USE=${DLANG_REQUIRED_USE}
-DEPEND=${DLANG_DEPS}
-BDEPEND=${DLANG_DEPS}
-RDEPEND=${DLANG_DEPS}
-
-DUB_TEST_DEPS=(
-	gitcompatibledubpackage@1.0.1
-	gitcompatibledubpackage@1.0.4
-	urld@2.1.1
-)
-generate_dub_test_dependencies() {
-	local dep
-	for dep in "${DUB_TEST_DEPS[@]}"; do
-		local depName depVersion
-		depName="${dep%@*}"
-		depVersion="${dep#*@}"
-		echo "https://code.dlang.org/packages/${depName}/${depVersion}.zip -> ${depName}-${depVersion}.zip"
-	done
-}
-
-GITHUB_URI="https://codeload.github.com/dlang"
-SRC_URI="
-	${GITHUB_URI}/${PN}/tar.gz/v${PV} -> ${PN}-${PV}.tar.gz
-	test? (
-		$(generate_dub_test_dependencies)
-	)
-"
-
-PATCHES=(
-	"${FILESDIR}/${P}-fix-wno-error-not-applying.patch"
-)
-
-src_unpack() {
-	unpack "${P}.tar.gz"
-
-	if use test; then
-		# Copy the archives locally. Some tests do need to perform an
-		# actual fetch operation so make all of them available as
-		# archives and let dub figure out the rest.
-		local store="${T}/dub-test-deps"
-		mkdir -p "${store}" || die
-
-		local dep
-		for dep in "${DUB_TEST_DEPS[@]}"; do
-			local depName depVersion
-			depName="${dep%@*}"
-			depVersion="${dep#*@}"
-
-			cp "${DISTDIR}/${depName}-${depVersion}.zip" "${store}" || die
-		done
-
-		# Generate a settings.json file that points to the directory with all the deps.
-		cat <<EOF > "${T}/settings.json"
-{
-	"registryUrls": [
-		"file://${store}"
-	],
-	"skipRegistry": "all"
-}
-EOF
-	fi
-}
-
-src_compile() {
-	local imports=source versions="DubApplication DubUseCurl"
-	dlang_compile_bin bin/dub $(<build-files.txt)
-
-	# Generate man pages. Rebuids dub so put it behind a USE flag.
-	if use doc; then
-		einfo "Generating man pages"
-		# You're supposed to be able to do ./bin/dub scrips/man/gen_man.d
-		# but it gives linking errors with gdc.
-
-		# $imports is set up above.
-		versions=DubUseCurl
-		dlang_compile_bin scripts/man/gen_man{,.d} \
-						  $(sed '/^source\/app.d$/d' build-files.txt)
-		./scripts/man/gen_man || die "Could not generate man pages"
-	fi
-}
-
-src_test() {
-	# Setup the environment for the tests.
-	local -x DUB="${S}/bin/dub"
-	local -x DUB_HOME="${T}/dub-home" # where to put artifacts
-
-	# Note, disabling tests is possible yet very hard. You have to
-	# create a bash variable containing a regex (to be used in =~) that
-	# matches all the tests that you want *to* run. It's probably easier
-	# to delete the subdirectory under ${S}/test.
-
-	# Tries to connect to github.com and fails due to the network sandbox
-	rm -rf "${S}/test/git-dependency" || die
-	# Doesn't work on non amd64/x86
-	if [[ ${ARCH} == arm64 ]]; then
-		rm -rf test/issue1447-build-settings-vars || die
-	fi
-
-	local dropImportCTest
-	# We have an importC test and not all compilers pass it properly.
-	# gdc doesn't support #include's in its importC implementation yet.
-	# Only check == 13 since 12 is skipped by the script.
-	[[ ${EDC} == gdc* ]] && [[ $(dlang_get_be_version) == 13 ]] && dropImportCTest=1
-	# Nor does <=ldc2-1.32.
-	[[ ${EDC} == ldc* ]] && $(ver_test $(dlang_get_be_version) -le 1.32) && dropImportCTest=1
-	# dmd can do #include's but there are some other errors about
-	# __float128 in <=dmd-2.102 on x86.
-	[[ ${EDC} == dmd* ]] && $(ver_test $(dlang_get_be_version) -le 2.102) \
-		&& [[ ${ARCH} == x86 ]] && dropImportCTest=1
-	if [[ ${dropImportCTest} ]]; then
-		rm -rf "${S}/test/use-c-sources" || die
-	fi
-
-	# Put the configuration file relative to the dub binary:
-	# <dub-bin-dir>/../etc/dub/settings.json as per
-	# https://dub.pm/dub-reference/settings so that it's picked up
-	# automatically.
-	mkdir -p "${S}/bin/../etc/dub" || die
-	cp "${T}/settings.json" "${S}/bin/../etc/dub/" \
-		|| die "Could not copy dub configuration file"
-
-	# See https://bugs.gentoo.org/921581 we have to remove -op (preserve
-	# source path for output files) from the flags lest the sandbox
-	# trips us up. This shouldn't be a problem anymore with dlang-single.
-	dlang-filter-dflags "*" "--op" "-op"
-
-	# Append -Wno-error or equivalent
-	DCFLAGS+=" $(dlang_get_wno_error_flag)"
-
-	DFLAGS="${DCFLAGS}" FRONTEND="$(dlang_get_fe_version)" test/run-unittest.sh  \
-		|| die "Tests failed"
-}
-
-src_install() {
-	dobin bin/dub
-	dodoc README.md
-
-	# Make sure there are no man files in any other section.
-	use doc && doman scripts/man/*.1
-
-	newbashcomp scripts/bash-completion/${PN}.bash ${PN}
-	dozshcomp scripts/zsh-completion/_${PN}
-	dofishcomp scripts/fish-completion/${PN}.fish
-}
-- 
cgit v1.2.3-65-gdbad