sci-biology/biogrep/biogrep-1.0-r2.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36

# Copyright 1999-2016 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

inherit autotools

DESCRIPTION="Multithreaded tool for matching large sets of patterns against biosequence DBs"
HOMEPAGE="http://stephanopoulos.openwetware.org/BIOGREP.html"
SRC_URI="http://www.openwetware.org/images/3/3d/${P^}.tar.gz -> ${P}.tar.gz
	doc? ( http://www.openwetware.org/images/4/49/${PN^}.pdf -> ${P}.pdf )"

LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="doc examples"

src_prepare() {
	default
	mv configure.{in,ac} || die
	eautoreconf
}

src_install() {
	use doc && DOCS+=( "${DISTDIR}"/${P}.pdf )
	if use examples; then
		# remove cruft before installing examples
		find examples/ \( -name 'CVS' -o -name '*~' \) -exec rm -rf '{}' + || die

		DOCS+=( examples )
		docompress -x /usr/share/doc/${PF}/examples
	fi

	default
}