net-libs/xrootd-ceph/xrootd-ceph-5.3.1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34

# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake

DESCRIPTION="xrootd OSS plug-in for interfacing with Ceph storage platform"
HOMEPAGE="https://xrootd.slac.stanford.edu/"
SRC_URI="https://github.com/xrootd/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="LGPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~amd64-linux"
IUSE="test"
RESTRICT="!test? ( test )"

DEPEND=">=net-libs/xrootd-5.0.0
	sys-cluster/ceph"
RDEPEND="${DEPEND}"
BDEPEND="test? ( dev-util/cppunit )"

# xrootd plugins are not intended to be linked with,
# they are to be loaded at runtime by xrootd,
# see https://github.com/xrootd/xrootd/issues/447
QA_SONAME="/usr/lib.*/libXrdCeph.*-$(ver_cut 1)\.so
	/usr/lib.*/libXrdCephTests\.so"

src_configure() {
	local mycmakeargs=(
		-DENABLE_TESTS=$(usex test)
	)
	cmake_src_configure
}