blob: 7e2d4e9bfdb547588316bfee9acd1308fe78582c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI="6"
inherit toolchain-funcs flag-o-matic eutils versionator
DESCRIPTION="The PowerDNS Recursor"
HOMEPAGE="https://www.powerdns.com/"
SRC_URI="https://downloads.powerdns.com/releases/${P/_/-}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
IUSE="libressl luajit protobuf snmp sodium systemd"
DEPEND="!luajit? ( >=dev-lang/lua-5.1:= )
luajit? ( dev-lang/luajit:= )
protobuf? (
dev-libs/protobuf
>=dev-libs/boost-1.42:=
)
systemd? ( sys-apps/systemd:0= )
snmp? ( net-analyzer/net-snmp )
sodium? ( dev-libs/libsodium:= )
libressl? ( dev-libs/libressl:= )
!libressl? ( dev-libs/openssl:= )
>=dev-libs/boost-1.35:="
RDEPEND="${DEPEND}
!<net-dns/pdns-2.9.20-r1"
DEPEND="${DEPEND}
virtual/pkgconfig"
S="${WORKDIR}"/${P/_/-}
pkg_setup() {
filter-flags -ftree-vectorize
}
src_configure() {
econf \
--sysconfdir=/etc/powerdns \
$(use_enable systemd) \
$(use_enable sodium libsodium) \
$(use_with !luajit lua) \
$(use_with luajit luajit) \
$(use_with protobuf) \
$(use_with snmp net-snmp)
}
src_install() {
default
mv "${D}"/etc/powerdns/recursor.conf{-dist,}
# set defaults: setuid=nobody, setgid=nobody
sed -i \
-e 's/^# set\([ug]\)id=$/set\1id=nobody/' \
-e 's/^# quiet=$/quiet=on/' \
-e 's/^# chroot=$/chroot=\/var\/lib\/powerdns/' \
"${D}"/etc/powerdns/recursor.conf
newinitd "${FILESDIR}"/pdns-recursor-r1 pdns-recursor
keepdir /var/lib/powerdns
}
pkg_postinst() {
local old
for old in ${REPLACING_VERSIONS}; do
version_compare ${old} 4.0.0-r1
[[ $? -eq 1 ]] || continue
ewarn "Starting with 4.0.0-r1 the init script has been renamed from precursor"
ewarn "to pdns-recursor, please update your runlevels accordingly."
break
done
}
|
GitWeb