blob: 37f5ab5d3a6caf703f0e8da011561e8de4031c16 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools bash-completion-r1 fcaps flag-o-matic git-r3
DESCRIPTION="My TraceRoute, an Excellent network diagnostic tool"
HOMEPAGE="https://www.bitwizard.nl/mtr/"
EGIT_REPO_URI="https://github.com/traviscross/mtr"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS=""
IUSE="+gtk +ipinfo +ipv6 +jansson +ncurses"
RDEPEND="
gtk? (
dev-libs/glib:2
x11-libs/gtk+:3
)
jansson? ( dev-libs/jansson )
ncurses? ( sys-libs/ncurses:0= )
"
DEPEND="
${RDEPEND}
"
BDEPEND="
virtual/pkgconfig
"
DOCS=( AUTHORS FORMATS NEWS README.md SECURITY TODO )
FILECAPS=( cap_net_raw usr/sbin/mtr-packet )
PATCHES=(
"${FILESDIR}"/${PN}-0.88-tinfo.patch
)
RESTRICT="test"
src_prepare() {
default
eautoreconf
}
src_configure() {
# In the source's configure script -lresolv is commented out. Apparently it
# is still needed for 64-bit MacOS.
[[ ${CHOST} == *-darwin* ]] && append-libs -lresolv
econf \
$(use_enable ipv6) \
$(use_with gtk) \
$(use_with ipinfo) \
$(use_with jansson) \
$(use_with ncurses) \
--with-bashcompletiondir="$(get_bashcompdir)"
}
pkg_postinst() {
fcaps_pkg_postinst
if use prefix && [[ ${CHOST} == *-darwin* ]] ; then
ewarn "mtr needs root privileges to run. To grant them:"
ewarn " % sudo chown root ${EPREFIX}/usr/sbin/mtr"
ewarn " % sudo chmod u+s ${EPREFIX}/usr/sbin/mtr"
fi
}
|
GitWeb
