dev-util/bcc/bcc-0.9.0-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

PYTHON_COMPAT=( python2_7 python3_{6,7} )

inherit cmake-utils linux-info python-single-r1

DESCRIPTION="Tools for BPF-based Linux IO analysis, networking, monitoring, and more"
HOMEPAGE="https://iovisor.github.io/bcc/"
EGIT_COMMIT="v${PV}"
SRC_URI="https://github.com/iovisor/bcc/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
	mirror://gentoo/bcc-0.9.0-linux-5-bpf.patch.xz"
RESTRICT="test"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~x86"
IUSE="+luajit"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"

RDEPEND="dev-libs/libbpf:=
	>=sys-kernel/linux-headers-4.18
	>=dev-libs/elfutils-0.166:=
	sys-devel/clang:=
	>=sys-devel/llvm-3.7.1:=[llvm_targets_BPF(+)]
	luajit? ( dev-lang/luajit )
	${PYTHON_DEPS}"
DEPEND="${RDEPEND}"
BDEPEND="dev-util/cmake
	virtual/pkgconfig"

S=${WORKDIR}/${PN}-${EGIT_COMMIT#v}

PATCHES=(
	"${FILESDIR}/bcc-0.9.0-system-libbpf.patch"
	"${FILESDIR}/bcc-0.9.0-no-luajit-automagic-dep.patch"
)

pkg_pretend() {
	local CONFIG_CHECK="~BPF ~BPF_SYSCALL ~NET_CLS_BPF ~NET_ACT_BPF
		~BPF_JIT ~BPF_EVENTS ~DEBUG_INFO ~FUNCTION_TRACER ~KALLSYMS_ALL
		~KPROBES"

	check_extra_config
}

pkg_setup() {
	python-single-r1_pkg_setup
}

src_prepare() {
	# needs bpf.h from linux-5.0 to build
	has_version '>=sys-kernel/linux-headers-5.0' || \
		eapply "${WORKDIR}/bcc-0.9.0-linux-5-bpf.patch"

	cmake-utils_src_prepare
}

src_configure() {
	local mycmakeargs=(
		-DREVISION=${PV%%_*}
		$(usex luajit '-DWITH_LUAJIT=1' '' '' '')
	)

	cmake-utils_src_configure
}

src_install() {
	cmake-utils_src_install
	python_fix_shebang "${ED}"
}