dev-php/PHP_CodeCoverage/PHP_CodeCoverage-7.0.10-r1.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66

# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=7

USE_PHP="php7-2 php7-3 php7-4"
MY_PN="php-code-coverage"

DESCRIPTION="Collection, processing, and rendering for PHP code coverage"
HOMEPAGE="https://phpunit.de"
SRC_URI="https://github.com/sebastianbergmann/${MY_PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
IUSE="test"

S="${WORKDIR}/${MY_PN}-${PV}"

RDEPEND="dev-php/fedora-autoloader
	>=dev-php/File_Iterator-2.0.2
	<dev-php/File_Iterator-3.0
	>=dev-php/Text_Template-1.2.1
	<dev-php/Text_Template-2.0
	>=dev-php/PHP_TokenStream-3.1.1
	<dev-php/PHP_TokenStream-4.0
	>=dev-php/sebastian-environment-4.2.2
	<dev-php/sebastian-environment-5.0
	>=dev-php/sebastian-version-2.0.1
	<dev-php/sebastian-version-3.0
	dev-php/sebastian-code-unit-reverse-lookup
	<dev-php/sebastian-code-unit-reverse-lookup-2.0
	>=dev-php/theseer-tokenizer-1.1.3
	<dev-php/theseer-tokenizer-2.0
	|| (
		dev-lang/php:7.2[xml(-),xmlwriter(-)]
		dev-lang/php:7.3[xml(-),xmlwriter(-)]
		dev-lang/php:7.4[xml(-),xmlwriter(-)]
	)"
BDEPEND="test? ( ${RDEPEND} dev-php/phpunit )"
# Test currently do not work.  Cannot find TestCase.php
RESTRICT="test"

src_install() {
	insinto /usr/share/php/PHP/CodeCoverage
	doins -r src/*
	newins "${FILESDIR}/autoload-7.0.10.php" autoload.php
}

src_test() {
	mkdir vendor || die
	cp "${FILESDIR}/autoload-7.0.10.php" vendor/autoload.php || die
	sed -i 's~__DIR__~__DIR__."/../src"~' vendor/autoload.php || die
	ln -s ../tests/TestCase.php src/TestCase.php || die
	for target in ${USE_PHP//-/.} ; do
		if [ -x /usr/bin/$target ] ; then
			${target} /usr/bin/phpunit -c phpunit.xml || die
		fi
	done
	rm src/TestCase.php || die
}

pkg_postinst() {
	ewarn "This library now loads via /usr/share/php/PHP/CodeCoverage/autoload.php"
	ewarn "Please update any scripts to require the autoloader"
}