blob: 16f18f40492e2db143ed730d11515f1e340b3105 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
VALA_USE_DEPEND="vapigen"
PYTHON_COMPAT=( python3_{7..9} )
inherit gnome.org gnome2-utils meson python-any-r1 vala xdg
DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
HOMEPAGE="https://gitlab.gnome.org/GNOME/gcr"
LICENSE="GPL-2+ LGPL-2+"
SLOT="0/1" # subslot = suffix of libgcr-base-3 and co
IUSE="gtk gtk-doc +introspection test +vala"
REQUIRED_USE="vala? ( introspection )"
RESTRICT="!test? ( test )"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
DEPEND="
>=dev-libs/glib-2.44.0:2
>=dev-libs/libgcrypt-1.2.2:0=
>=app-crypt/p11-kit-0.19.0
gtk? ( >=x11-libs/gtk+-3.12:3[X,introspection?] )
>=sys-apps/dbus-1
introspection? ( >=dev-libs/gobject-introspection-1.58:= )
"
RDEPEND="${DEPEND}"
PDEPEND="app-crypt/gnupg"
BDEPEND="
${PYTHON_DEPS}
gtk? ( dev-libs/libxml2:2 )
dev-util/gdbus-codegen
dev-util/glib-utils
gtk-doc? (
>=dev-util/gtk-doc-1.9
app-text/docbook-xml-dtd:4.1.2
)
>=sys-devel/gettext-0.19.8
test? ( app-crypt/gnupg )
virtual/pkgconfig
vala? ( $(vala_depend) )
"
PATCHES=(
"${FILESDIR}"/3.38.0-avoid-gnupg-circular-dep.patch
"${FILESDIR}"/3.38.0-optional-vapi.patch
)
pkg_setup() {
python-any-r1_pkg_setup
}
src_prepare() {
use vala && vala_src_prepare
xdg_src_prepare
}
src_configure() {
local emesonargs=(
$(meson_use introspection)
$(meson_use gtk)
$(meson_use gtk-doc gtk_doc)
-Dgpg_path="${EPREFIX}"/usr/bin/gpg
$(meson_use vala vapi)
)
meson_src_configure
}
src_test() {
dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}
|
GitWeb