app-backup/restic/restic-0.4.0.ebuild


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43

# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$

EAPI=6

DESCRIPTION="restic is a backup program that is fast, efficient and secure"
HOMEPAGE="https://restic.github.io/"
SRC_URI="https://github.com/restic/restic/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="BSD-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="test"

DOCS=( README.md CONTRIBUTING.md doc/Design.md doc/FAQ.md doc/index.md doc/Manual.md doc/REST_backend.md )

DEPEND="dev-lang/go
	test? ( sys-fs/fuse )"

RDEPEND="sys-fs/fuse"

src_compile() {
	local mygoargs=(
		-v
		-work
		-x
		-tags release
		-ldflags "-w -X main.version=${PV}"
		-o "${S}"/restic cmds/restic
	)

	GOPATH="${S}:${S}/vendor" go build "${mygoargs[@]}" || die
}

src_test() {
	GOPATH="${S}:${S}/vendor" go test -v -work -x restic/... cmds/... || die
}

src_install() {
	dobin restic
	einstalldocs
}