From f1a9b2784876f4e62ac2f79f00f44821921d2dcd Mon Sep 17 00:00:00 2001
From: David Seifert <soap@gentoo.org>
Date: Wed, 29 Jun 2022 11:07:12 +0200
Subject: x11-wm/matwm2: update EAPI 6 -> 8

Signed-off-by: David Seifert <soap@gentoo.org>
---
 x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild | 65 -------------------------------
 x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild | 64 ++++++++++++++++++++++++++++++
 2 files changed, 64 insertions(+), 65 deletions(-)
 delete mode 100644 x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
 create mode 100644 x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild

(limited to 'x11-wm')

diff --git a/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild b/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
deleted file mode 100644
index c6e017074c9d..000000000000
--- a/x11-wm/matwm2/matwm2-0.1.2_pre3-r1.ebuild
+++ /dev/null
@@ -1,65 +0,0 @@
-# Copyright 1999-2017 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-inherit toolchain-funcs
-
-MY_PV="${PV//_/}"
-
-DESCRIPTION="Simple EWMH compatible window manager with titlebars and frames"
-HOMEPAGE="https://github.com/segin/matwm2"
-SRC_URI="https://github.com/segin/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug xft xinerama"
-S="${WORKDIR}/${PN}-${MY_PV}/${PN}"
-
-RDEPEND="
-	x11-libs/libXext
-	x11-libs/libX11
-	xft? ( x11-libs/libXft )
-	xinerama? ( x11-libs/libXinerama )
-"
-DEPEND="
-	${RDEPEND}
-	virtual/pkgconfig
-"
-
-PATCHES=( "${FILESDIR}/${P}-destdir-fix.patch" )
-
-src_prepare() {
-	default
-
-	# Let the package manager handle stripping
-	sed -e 's/install -s/install/g' -i Makefile.in || die
-}
-
-src_configure() {
-	# configure is not autotools based
-	local myconfigureargs=(
-		--prefix="${EPREFIX}/usr"
-		--mandir="${EPREFIX}/usr/share/man"
-		--cc="$(tc-getCC)"
-		$(usex debug "--enable-debug" "")
-		$(usex xft "" "--disable-xft")
-		$(usex xinerama "" "--disable-xinerama")
-	)
-
-	./configure "${myconfigureargs[@]}" || die
-}
-
-src_install() {
-	default
-
-	docompress -x "${EPREFIX}/usr/share/doc/${PF}"/default_matwmrc
-	dodoc default_matwmrc
-
-	insinto /usr/share/xsessions
-	doins "${FILESDIR}"/${PN}.desktop
-
-	echo ${PN} > "${T}"/${PN} || die
-	exeinto /etc/X11/Sessions
-	doexe "${T}"/${PN}
-}
diff --git a/x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild b/x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild
new file mode 100644
index 000000000000..468d8e602220
--- /dev/null
+++ b/x11-wm/matwm2/matwm2-0.1.2_pre3-r2.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo toolchain-funcs
+
+MY_PV="${PV//_/}"
+
+DESCRIPTION="Simple EWMH compatible window manager with titlebars and frames"
+HOMEPAGE="https://github.com/segin/matwm2"
+SRC_URI="https://github.com/segin/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${MY_PV}/${PN}"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug xft xinerama"
+
+RDEPEND="
+	x11-libs/libXext
+	x11-libs/libX11
+	xft? ( x11-libs/libXft )
+	xinerama? ( x11-libs/libXinerama )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${P}-destdir-fix.patch )
+
+src_prepare() {
+	default
+
+	# Let the package manager handle stripping
+	sed -e 's/install -s/install/g' -i Makefile.in || die
+}
+
+src_configure() {
+	# configure is not autotools based
+	local myconfigureargs=(
+		--prefix="${EPREFIX}/usr"
+		--mandir="${EPREFIX}/usr/share/man"
+		--cc="$(tc-getCC)"
+		$(usev debug --enable-debug)
+		$(usev !xft --disable-xft)
+		$(usev !xinerama --disable-xinerama)
+	)
+
+	edo ./configure "${myconfigureargs[@]}"
+}
+
+src_install() {
+	default
+
+	docompress -x /usr/share/doc/${PF}/default_matwmrc
+	dodoc default_matwmrc
+
+	insinto /usr/share/xsessions
+	doins "${FILESDIR}"/${PN}.desktop
+
+	exeinto /etc/X11/Sessions
+	newexe - matwm2 <<- _EOF_
+		matwm2
+	_EOF_
+}
-- 
cgit v1.2.3-65-gdbad