From 4cfaa5c8c3ed8eeff5c512d967c776f2b1f266ef Mon Sep 17 00:00:00 2001
From: Michael Mair-Keimberger <mmk@levelnine.at>
Date: Tue, 13 Feb 2024 12:31:48 +0100
Subject: sci-visualization/xgraph: EAPI8 bump, use https

Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Closes: https://github.com/gentoo/gentoo/pull/35298
Signed-off-by: Andrew Ammerlaan <andrewammerlaan@gentoo.org>
---
 sci-visualization/xgraph/xgraph-12.1-r4.ebuild | 42 ------------------------
 sci-visualization/xgraph/xgraph-12.1-r5.ebuild | 44 ++++++++++++++++++++++++++
 2 files changed, 44 insertions(+), 42 deletions(-)
 delete mode 100644 sci-visualization/xgraph/xgraph-12.1-r4.ebuild
 create mode 100644 sci-visualization/xgraph/xgraph-12.1-r5.ebuild

(limited to 'sci-visualization')

diff --git a/sci-visualization/xgraph/xgraph-12.1-r4.ebuild b/sci-visualization/xgraph/xgraph-12.1-r4.ebuild
deleted file mode 100644
index ecb3cd30908b..000000000000
--- a/sci-visualization/xgraph/xgraph-12.1-r4.ebuild
+++ /dev/null
@@ -1,42 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools
-
-DEB_PR=16
-
-DESCRIPTION="X11 Plotting Utility"
-HOMEPAGE="http://www.isi.edu/nsnam/xgraph/"
-SRC_URI="http://www.isi.edu/nsnam/dist/${P}.tar.gz
-	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}-${DEB_PR}.debian.tar.gz"
-
-LICENSE="xgraph"
-SLOT="0"
-KEYWORDS="~amd64 ~arm64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
-IUSE="examples"
-RDEPEND="x11-libs/libSM
-	x11-libs/libX11"
-DEPEND="${RDEPEND}"
-
-PATCHES=( "${WORKDIR}"/debian/patches/debian-changes )
-
-src_prepare() {
-	default
-	rm -f configure.in Makefile.in || die
-	eautoreconf
-}
-
-src_install() {
-	default
-	dodoc "${WORKDIR}"/debian/changelog
-	if use examples; then
-		dodoc -r examples
-		docompress -x /usr/share/doc/${PF}/examples
-	fi
-	dodir /usr/share/man/man1
-	mv "${ED%/}"/usr/share/man/manm/xgraph.man \
-	   "${ED%/}"/usr/share/man/man1/xgraph.1 || die
-	rm -r "${ED%/}"/usr/share/man/manm || die
-}
diff --git a/sci-visualization/xgraph/xgraph-12.1-r5.ebuild b/sci-visualization/xgraph/xgraph-12.1-r5.ebuild
new file mode 100644
index 000000000000..9fbcd83e6526
--- /dev/null
+++ b/sci-visualization/xgraph/xgraph-12.1-r5.ebuild
@@ -0,0 +1,44 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DEB_PR=16
+
+DESCRIPTION="X11 Plotting Utility"
+HOMEPAGE="https://www.isi.edu/nsnam/xgraph/"
+SRC_URI="https://www.isi.edu/nsnam/dist/${P}.tar.gz
+	mirror://debian/pool/main/${PN:0:1}/${PN}/${PN}_${PV}-${DEB_PR}.debian.tar.gz"
+
+LICENSE="xgraph"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="examples"
+
+RDEPEND="x11-libs/libSM
+	x11-libs/libX11"
+DEPEND="${RDEPEND}"
+
+PATCHES=( "${WORKDIR}"/debian/patches/debian-changes )
+
+src_prepare() {
+	default
+	rm -f configure.in Makefile.in || die
+	eautoreconf
+}
+
+src_install() {
+	default
+	dodoc "${WORKDIR}"/debian/changelog
+	if use examples; then
+		dodoc -r examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+	dodir /usr/share/man/man1
+
+	mv "${ED}"/usr/share/man/manm/xgraph.man \
+	   "${ED}"/usr/share/man/man1/xgraph.1 || die
+	rm -r "${ED}"/usr/share/man/manm || die
+}
-- 
cgit v1.2.3-65-gdbad