From b0a262afc8007eb7bea9fe968b6dfac545ec35df Mon Sep 17 00:00:00 2001
From: Arthur Zamarin <arthurzam@gentoo.org>
Date: Sat, 8 Jun 2024 22:26:26 +0300
Subject: sci-libs/libticables2: EAPI 6 -> 8

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
---
 sci-libs/libticables2/libticables2-1.3.5-r1.ebuild | 56 ++++++++++++++++++++++
 sci-libs/libticables2/libticables2-1.3.5.ebuild    | 53 --------------------
 2 files changed, 56 insertions(+), 53 deletions(-)
 create mode 100644 sci-libs/libticables2/libticables2-1.3.5-r1.ebuild
 delete mode 100644 sci-libs/libticables2/libticables2-1.3.5.ebuild

(limited to 'sci-libs')

diff --git a/sci-libs/libticables2/libticables2-1.3.5-r1.ebuild b/sci-libs/libticables2/libticables2-1.3.5-r1.ebuild
new file mode 100644
index 000000000000..f71abc217606
--- /dev/null
+++ b/sci-libs/libticables2/libticables2-1.3.5-r1.ebuild
@@ -0,0 +1,56 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools
+
+DESCRIPTION="Library to handle different link cables for TI calculators"
+HOMEPAGE="http://lpg.ticalc.org/prj_tilp/"
+SRC_URI="https://downloads.sourceforge.net/tilp/tilp2-linux/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
+IUSE="debug doc nls static-libs usb"
+
+RDEPEND="
+	dev-libs/glib:2
+	usb? ( virtual/libusb:1 )
+	nls? ( virtual/libintl )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+"
+
+DOCS=( AUTHORS LOGO NEWS README ChangeLog docs/api.txt )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-rpath
+		$(use_enable static-libs static)
+		$(use_enable debug logging)
+		$(use_enable nls)
+		$(use_enable usb libusb)
+		$(use_enable usb libusb10)
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	use doc && HTML_DOCS+=( docs/html/. )
+	default
+	find "${D}" -type f -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	elog "Please read README in ${EROOT}/usr/share/doc/${PF}"
+	elog "if you encounter any problem with a link cable"
+}
diff --git a/sci-libs/libticables2/libticables2-1.3.5.ebuild b/sci-libs/libticables2/libticables2-1.3.5.ebuild
deleted file mode 100644
index 7f0e4f959203..000000000000
--- a/sci-libs/libticables2/libticables2-1.3.5.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2024 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-inherit autotools
-
-DESCRIPTION="Library to handle different link cables for TI calculators"
-HOMEPAGE="http://lpg.ticalc.org/prj_tilp/"
-SRC_URI="https://downloads.sourceforge.net/tilp/tilp2-linux/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux"
-IUSE="debug doc nls static-libs usb"
-
-RDEPEND="
-	dev-libs/glib:2
-	usb? ( virtual/libusb:1 )
-	nls? ( virtual/libintl )"
-
-DEPEND="${RDEPEND}
-	virtual/pkgconfig
-	nls? ( sys-devel/gettext )"
-
-DOCS=( AUTHORS LOGO NEWS README ChangeLog docs/api.txt )
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	# --disable-libusb $(use_enable usb libusb10) would enable virtual/libusb:1
-	econf \
-		--disable-rpath \
-		$(use_enable static-libs static) \
-		$(use_enable debug logging) \
-		$(use_enable nls) \
-		$(use_enable usb libusb) \
-		$(use_enable usb libusb10)
-}
-
-src_install() {
-	use doc && HTML_DOCS+=( docs/html/. )
-	default
-	find "${D}" -name '*.la' -delete || die
-}
-
-pkg_postinst() {
-	elog "Please read README in ${EROOT%/}/usr/share/doc/${PF}"
-	elog "if you encounter any problem with a link cable"
-}
-- 
cgit v1.2.3-65-gdbad