From 56d1a297fe8932e6d2fb2cab47b2f0a0b1a37c27 Mon Sep 17 00:00:00 2001
From: Paul Zander <negril.nx+gentoo@gmail.com>
Date: Sat, 2 Sep 2023 14:03:04 +0200
Subject: net-wireless/iw: add rdepend on wireless-regdb

iw can bring up a wireless device so it needs to depend on
net-wireless/wireless-regdb.

Fix the compile flags, so they are actually fully honored.

Signed-off-by: Paul Zander <negril.nx+gentoo@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/32562
Signed-off-by: Sam James <sam@gentoo.org>
---
 net-wireless/iw/iw-5.19-r1.ebuild | 40 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 net-wireless/iw/iw-5.19-r1.ebuild

(limited to 'net-wireless')

diff --git a/net-wireless/iw/iw-5.19-r1.ebuild b/net-wireless/iw/iw-5.19-r1.ebuild
new file mode 100644
index 000000000000..f1bbe2108630
--- /dev/null
+++ b/net-wireless/iw/iw-5.19-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="nl80211 configuration utility for wireless devices using the mac80211 stack"
+HOMEPAGE="https://wireless.wiki.kernel.org/en/users/Documentation/iw"
+SRC_URI="https://mirrors.edge.kernel.org/pub/software/network/${PN}/${P}.tar.xz"
+
+LICENSE="ISC"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86 ~amd64-linux ~x86-linux"
+
+DEPEND="dev-libs/libnl:="
+RDEPEND="
+	${DEPEND}
+	net-wireless/wireless-regdb
+"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+	tc-export CC LD PKG_CONFIG
+
+	# do not compress man pages by default.
+	sed 's@\(iw\.8\)\.gz@\1@' -i Makefile || die
+}
+
+src_compile() {
+	# Set flags prior so they are honored
+	CFLAGS="${CFLAGS:+${CFLAGS} }${CPPFLAGS}"
+	LDFLAGS="${CFLAGS:+${CFLAGS} }${LDFLAGS}"
+	emake V=1
+}
+
+src_install() {
+	emake V=1 DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+}
-- 
cgit v1.2.3-65-gdbad