From 212ba90044f3be8b80ca904ffb6f0e75e1edaef5 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Fri, 20 Jul 2018 10:32:06 +0200
Subject: media-sound/bluez-alsa: Bump to version 1.3.0

Closes: https://bugs.gentoo.org/661534
Package-Manager: Portage-2.3.43, Repoman-2.3.10
---
 media-sound/bluez-alsa/Manifest                |  1 +
 media-sound/bluez-alsa/bluez-alsa-1.3.0.ebuild | 60 ++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)
 create mode 100644 media-sound/bluez-alsa/bluez-alsa-1.3.0.ebuild

(limited to 'media-sound')

diff --git a/media-sound/bluez-alsa/Manifest b/media-sound/bluez-alsa/Manifest
index 8be814a6d6d3..9bf03a8915f1 100644
--- a/media-sound/bluez-alsa/Manifest
+++ b/media-sound/bluez-alsa/Manifest
@@ -1,2 +1,3 @@
 DIST bluez-alsa-1.1.0.tar.gz 73676 BLAKE2B 6db4b1475223f12af66617881e6093a4ae957cdc17482fec13c3dd628a02cdff74f9ff173472231aecf6e58b368fa8ffa335d38a31b1c50c8ea198af091a5d63 SHA512 167fa45994b57b0b44d5827762638d36ef782d7789c229e5c1ca99b59c13636dc53161cd45bec41e61890acd38b44d20778bc2085385582329a1c666530b21f1
 DIST bluez-alsa-1.2.0.tar.gz 63662 BLAKE2B 79549c9848f910e083b88058e6798e10d193a3bfcbc087b41e17aa5f43444f425b5932c6440a5c7416068bd0c562a744f3cbfb3008582f56988e756ee74395a3 SHA512 a6bf0068b3fb88acaa11990db411f1d3be7ad19219e7bdfd091fe81acc2ba5d5992dfb377e4fcc332ac330bb7e5ab5e4f4a9cee3e700e366fd983e81a272a5b4
+DIST bluez-alsa-1.3.0.tar.gz 86109 BLAKE2B 0a026c590a3e8f655db367e38891142d757eabc8ba647c655451e7b5ff9beabcc71ec33e16522ee7818be7513c9ecc4c5512ce6a2358651b4d8e77cd90f6a25f SHA512 f355873622290bc0193799a77660adf1e3622d3ad77a8e0cbf46d59b3c015009c8b3318c414b855c569d40bbe450a490f53c8d5382350beadfff6e65ab8e58bc
diff --git a/media-sound/bluez-alsa/bluez-alsa-1.3.0.ebuild b/media-sound/bluez-alsa/bluez-alsa-1.3.0.ebuild
new file mode 100644
index 000000000000..6c59d2ee4e2f
--- /dev/null
+++ b/media-sound/bluez-alsa/bluez-alsa-1.3.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit autotools multilib-minimal
+
+DESCRIPTION="Bluetooth Audio ALSA Backend"
+HOMEPAGE="https://github.com/Arkq/bluez-alsa"
+
+if [[ ${PV} == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/Arkq/${PN}"
+else
+	SRC_URI="https://github.com/Arkq/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="aac debug hcitop static-libs"
+
+RDEPEND=">=dev-libs/glib-2.26[dbus,${MULTILIB_USEDEP}]
+	>=media-libs/alsa-lib-1.0[${MULTILIB_USEDEP}]
+	>=media-libs/sbc-1.2[${MULTILIB_USEDEP}]
+	>=net-wireless/bluez-5.0[${MULTILIB_USEDEP}]
+	aac? ( >=media-libs/fdk-aac-0.1.1[${MULTILIB_USEDEP}] )
+	hcitop? (
+		dev-libs/libbsd
+		sys-libs/ncurses:0=
+	)"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	local myeconfargs=(
+		--enable-rfcomm
+		$(use_enable aac)
+		$(use_enable debug)
+		$(use_enable static-libs static)
+		$(multilib_native_use_enable hcitop)
+	)
+	ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
+}
+
+multilib_src_install_all() {
+	default
+	find "${ED}" -name "*.la" -delete || die
+
+	newinitd "${FILESDIR}"/bluealsa-init.d bluealsa
+	newconfd "${FILESDIR}"/bluealsa-conf.d-2 bluealsa
+}
+
+pkg_postinst() {
+	elog "Users can use this service when they are members of the \"audio\" group."
+}
-- 
cgit v1.2.3-65-gdbad