From 88d2a667b6762b788117ef7940f0f6c3daf963e3 Mon Sep 17 00:00:00 2001
From: Jakov Smolić <jsmolic@gentoo.org>
Date: Thu, 23 Feb 2023 12:37:14 +0100
Subject: media-sound/snapcast: add 0.27.0
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Closes: https://bugs.gentoo.org/893282
Signed-off-by: Jakov Smolić <jsmolic@gentoo.org>
---
 media-sound/snapcast/Manifest               |  1 +
 media-sound/snapcast/snapcast-0.27.0.ebuild | 69 +++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)
 create mode 100644 media-sound/snapcast/snapcast-0.27.0.ebuild

(limited to 'media-sound/snapcast')

diff --git a/media-sound/snapcast/Manifest b/media-sound/snapcast/Manifest
index 46dab3d3e54d..4a3bb3e7997b 100644
--- a/media-sound/snapcast/Manifest
+++ b/media-sound/snapcast/Manifest
@@ -1 +1,2 @@
 DIST snapcast-0.26.0.tar.gz 1537036 BLAKE2B f6ef4393f3601c749140a9505f57515582147aacf25072d9114491aafb108c202c3631142171858d2b8f914be8105bbd9c66054c6d36d0b4a443e5b9a642cf51 SHA512 fc7885e42a11794e33314544083251ffbb91a0cf160c6d4b854c56f57ffe9f38f75c7594478c9edabfe9076959938cd8de891dd456e66202692de664a75cde71
+DIST snapcast-0.27.0.tar.gz 1566337 BLAKE2B 77183cd2496beaf6808f8c1ff030cdb1e483c86ebafd57d0c75daa2dfe31030f0dd9704db40e2c0780b85c2b346e121ccd16c1cb75dea1f80e9834d3ae100fb8 SHA512 fd86f5b0d38bf308eb9cc1f3024676471176355a8cc91ee8c8d2dfe1aa0cde99fc7636133071b50304fe66ea42dee996e0088e013be7fa703f21c5bc2a35cfdd
diff --git a/media-sound/snapcast/snapcast-0.27.0.ebuild b/media-sound/snapcast/snapcast-0.27.0.ebuild
new file mode 100644
index 000000000000..0152b8427af0
--- /dev/null
+++ b/media-sound/snapcast/snapcast-0.27.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+DESCRIPTION="Synchronous multi-room audio player"
+HOMEPAGE="https://github.com/badaix/snapcast"
+SRC_URI="https://github.com/badaix/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+client +expat +flac +opus +server tremor +vorbis +zeroconf"
+REQUIRED_USE="|| ( server client )"
+
+RDEPEND="
+	dev-libs/boost:=
+	media-libs/alsa-lib
+	client? ( acct-user/snapclient )
+	expat? ( dev-libs/expat )
+	flac? ( media-libs/flac:= )
+	opus? ( media-libs/opus )
+	server? (
+		acct-group/snapserver
+		acct-user/snapserver
+	)
+	tremor? ( media-libs/tremor )
+	vorbis? ( media-libs/libvorbis )
+	zeroconf? ( net-dns/avahi[dbus] )
+"
+DEPEND="
+	${RDEPEND}
+	>=dev-cpp/aixlog-1.2.1
+	>=dev-cpp/asio-1.12.1
+	>=dev-cpp/popl-1.2.0
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_CLIENT=$(usex client)
+		-DBUILD_WITH_EXPAT=$(usex expat)
+		-DBUILD_WITH_FLAC=$(usex flac)
+		-DBUILD_WITH_OPUS=$(usex opus)
+		-DBUILD_SERVER=$(usex server)
+		-DBUILD_STATIC_LIBS=no
+		-DBUILD_TESTS=no
+		-DBUILD_WITH_TREMOR=$(usex tremor)
+		-DBUILD_WITH_VORBIS=$(usex vorbis)
+		-DBUILD_WITH_AVAHI=$(usex zeroconf)
+		-DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
+	)
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+
+	for bin in server client ; do
+		if use ${bin} ; then
+			doman "${bin}/snap${bin}.1"
+
+			newconfd "${FILESDIR}/snap${bin}.confd" "snap${bin}"
+			newinitd "${FILESDIR}/snap${bin}.initd" "snap${bin}"
+		fi
+	done
+}
-- 
cgit v1.2.3-65-gdbad