From 2e71b4c24f5fde61148a019004bbf01dcd6e277e Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Fri, 30 Sep 2022 01:36:55 +0100
Subject: media-libs/stimg: fix configure with clang 16

Revbump for the jpeg dep.

Closes: https://bugs.gentoo.org/871486
Signed-off-by: Sam James <sam@gentoo.org>
---
 media-libs/stimg/stimg-0.1.0-r1.ebuild | 45 ++++++++++++++++++++++++++++++++++
 media-libs/stimg/stimg-0.1.0.ebuild    | 34 -------------------------
 2 files changed, 45 insertions(+), 34 deletions(-)
 create mode 100644 media-libs/stimg/stimg-0.1.0-r1.ebuild
 delete mode 100644 media-libs/stimg/stimg-0.1.0.ebuild

(limited to 'media-libs')

diff --git a/media-libs/stimg/stimg-0.1.0-r1.ebuild b/media-libs/stimg/stimg-0.1.0-r1.ebuild
new file mode 100644
index 000000000000..dd1d5aac1d48
--- /dev/null
+++ b/media-libs/stimg/stimg-0.1.0-r1.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools toolchain-funcs
+
+DESCRIPTION="Simple and tiny image loading library"
+HOMEPAGE="http://homepage3.nifty.com/slokar/fb/"
+SRC_URI="http://homepage3.nifty.com/slokar/stimg/${P}.tar.gz"
+
+LICENSE="LGPL-2+ MIT-with-advertising"
+SLOT="0"
+KEYWORDS="~alpha amd64 ppc x86"
+
+RDEPEND="
+	media-libs/libpng:=
+	media-libs/libjpeg-turbo:=
+	media-libs/tiff:=
+"
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-libpng15.patch
+)
+
+src_prepare() {
+	default
+
+	# bug #871486
+	eautoreconf
+}
+
+src_configure() {
+	tc-export CC
+
+	default
+}
+
+src_install() {
+	default
+
+	# No static archives
+	find "${ED}" -name '*.la' -delete || die
+}
diff --git a/media-libs/stimg/stimg-0.1.0.ebuild b/media-libs/stimg/stimg-0.1.0.ebuild
deleted file mode 100644
index 05c0e054bfcf..000000000000
--- a/media-libs/stimg/stimg-0.1.0.ebuild
+++ /dev/null
@@ -1,34 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-inherit toolchain-funcs
-
-DESCRIPTION="Simple and tiny image loading library"
-HOMEPAGE="http://homepage3.nifty.com/slokar/fb/"
-SRC_URI="http://homepage3.nifty.com/slokar/stimg/${P}.tar.gz"
-
-LICENSE="LGPL-2+ MIT-with-advertising"
-SLOT="0"
-KEYWORDS="~alpha amd64 ppc x86"
-
-RDEPEND="
-	media-libs/libpng:=
-	media-libs/tiff:=
-	virtual/jpeg"
-DEPEND="${RDEPEND}"
-
-PATCHES=( "${FILESDIR}"/${P}-libpng15.patch )
-
-src_configure() {
-	tc-export CC
-	econf --disable-static
-}
-
-src_install() {
-	default
-
-	# no static archives
-	find "${D}" -name '*.la' -delete || die
-}
-- 
cgit v1.2.3-65-gdbad