From 75d86279ce97ea8a958ace8a09dab1fd9b0cfdc4 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Tue, 11 Feb 2020 14:58:01 +0100
Subject: media-libs/openal: Bump to version 1.20.1

Package-Manager: Portage-2.3.88, Repoman-2.3.20
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>
---
 media-libs/openal/Manifest             |  1 +
 media-libs/openal/openal-1.20.1.ebuild | 68 ++++++++++++++++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 media-libs/openal/openal-1.20.1.ebuild

(limited to 'media-libs/openal')

diff --git a/media-libs/openal/Manifest b/media-libs/openal/Manifest
index e60193a3cb29..89840a7b0e0b 100644
--- a/media-libs/openal/Manifest
+++ b/media-libs/openal/Manifest
@@ -1,2 +1,3 @@
 DIST openal-soft-1.19.1.tar.bz2 577310 BLAKE2B f6ed5b2bce1bfcaa7f8085375d5d3e3323ea2f03896ba871fe3ec247e6e1bf524a9c5180399b0f0908aa69756a1f2ee8095f14a69e6a7eac55a25cc7c2ac545b SHA512 356a3f12bbe284bfac71f4f2a9f83d084083a832012222e73743042ac27812cf051c12b0ddcf53c010ff77e44ae2e9033cea9b9324d316a22a59a154307a64a4
 DIST openal-soft-1.20.0.tar.bz2 587550 BLAKE2B 4ce0b520db65e0298d334bae104dc0e38c2daf41680e40c259451741f7d4c8b06948f00b96efb31aec528e18b65e3f7099ea8b2fbc4cef963cf9a912f51c276a SHA512 7b103ffeeb8a6541d4bd31245ca5e34fec27d121fe04c21655480fb3907604f4171f912411f1e49622ec27db79d6cb85eb452ed78523abc906f18af57ffb755e
+DIST openal-soft-1.20.1.tar.bz2 512971 BLAKE2B be0abb32698d5ea77e8667e1b00fb123673325b0361c711d6c232d96d1add6d5c9a3e2ba7a3d04afcad27fe4f18ae803f690b14c98d198b77c75f1865679081f SHA512 a8a03a2162b5d35e66adc079e81d7fa075b83a3ee1cec3412cb40f7789263ed8bd005beefb7ef995f464dfa43aac22ea0f547b752dfc7533ed9120a95fb92513
diff --git a/media-libs/openal/openal-1.20.1.ebuild b/media-libs/openal/openal-1.20.1.ebuild
new file mode 100644
index 000000000000..08bda9c75751
--- /dev/null
+++ b/media-libs/openal/openal-1.20.1.ebuild
@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+CMAKE_ECLASS=cmake
+inherit cmake-multilib
+
+MY_P="${PN}-soft-${PV}"
+
+DESCRIPTION="A software implementation of the OpenAL 3D audio API"
+HOMEPAGE="https://www.openal-soft.org/"
+SRC_URI="https://www.openal-soft.org/openal-releases/${MY_P}.tar.bz2"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="
+	alsa coreaudio debug jack oss portaudio pulseaudio sdl qt5
+	cpu_flags_x86_sse cpu_flags_x86_sse2 cpu_flags_x86_sse4_1
+	cpu_flags_arm_neon
+"
+
+RDEPEND="
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	jack? ( virtual/jack[${MULTILIB_USEDEP}] )
+	portaudio? ( >=media-libs/portaudio-19_pre20111121-r1[${MULTILIB_USEDEP}] )
+	pulseaudio? ( >=media-sound/pulseaudio-2.1-r1[${MULTILIB_USEDEP}] )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)
+	sdl? ( media-libs/libsdl2[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	oss? ( virtual/os-headers )"
+
+S="${WORKDIR}/${MY_P}"
+
+DOCS=( alsoftrc.sample docs/env-vars.txt docs/hrtf.txt ChangeLog README.md )
+
+src_configure() {
+	# -DEXAMPLES=OFF to avoid FFmpeg dependency wrt #481670
+	my_configure() {
+		local mycmakeargs=(
+			-DALSOFT_REQUIRE_ALSA=$(usex alsa)
+			-DALSOFT_REQUIRE_COREAUDIO=$(usex coreaudio)
+			-DALSOFT_REQUIRE_JACK=$(usex jack)
+			-DALSOFT_REQUIRE_OSS=$(usex oss)
+			-DALSOFT_REQUIRE_PORTAUDIO=$(usex portaudio)
+			-DALSOFT_REQUIRE_PULSEAUDIO=$(usex pulseaudio)
+			-DALSOFT_REQUIRE_SDL2=$(usex sdl)
+			-DALSOFT_CPUEXT_SSE=$(usex cpu_flags_x86_sse)
+			-DALSOFT_CPUEXT_SSE2=$(usex cpu_flags_x86_sse2)
+			-DALSOFT_CPUEXT_SSE4_1=$(usex cpu_flags_x86_sse4_1)
+			-DALSOFT_UTILS=$(multilib_is_native_abi && echo "ON" || echo "OFF")
+			-DALSOFT_NO_CONFIG_UTIL=$(usex qt5 "$(multilib_is_native_abi && echo "OFF" || echo "ON")" ON)
+			-DALSOFT_EXAMPLES=OFF
+		)
+
+		use cpu_flags_arm_neon && mycmakeargs+=( -DALSOFT_CPUEXT_NEON=$(usex cpu_flags_arm_neon) )
+
+		cmake_src_configure
+	}
+
+	multilib_parallel_foreach_abi my_configure
+}
-- 
cgit v1.2.3-65-gdbad