From 79e2e8f04e6839fcaf0954de1085184f7f9fab51 Mon Sep 17 00:00:00 2001
From: Matt Turner <mattst88@gentoo.org>
Date: Sun, 6 Jun 2021 14:27:19 -0700
Subject: media-gfx/eog: Version bump to 40.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 media-gfx/eog/Manifest        |  1 +
 media-gfx/eog/eog-40.2.ebuild | 71 +++++++++++++++++++++++++++++++++++++++++++
 2 files changed, 72 insertions(+)
 create mode 100644 media-gfx/eog/eog-40.2.ebuild

(limited to 'media-gfx/eog')

diff --git a/media-gfx/eog/Manifest b/media-gfx/eog/Manifest
index 2f1ad22e19e7..6830e01de5a2 100644
--- a/media-gfx/eog/Manifest
+++ b/media-gfx/eog/Manifest
@@ -1 +1,2 @@
 DIST eog-40.1.tar.xz 3601652 BLAKE2B 6e3ec73742a0de864a131b25b2ed2c3346aecea9455ccbae701d70a50a45dace90d4002c56829e9a831a16ec827df6e1ab257c9ec5b755b863e98d63cd8a59bf SHA512 1fd2f6689f8a74254f4436fedf8a5ee7c1488d70b467dfb94c3ca3e0e269aaa75a77d15d5bb3544e699f5c8759e30a25942857188cb98b4d9537165b67d6d14c
+DIST eog-40.2.tar.xz 3601788 BLAKE2B ab66481d8fa5c076f0e12c3f16ff4a67d3a544b7483a2791833ea7d7f605898b20e8d8ed100a538e7a7f21a1359c74b96fa81aaf8712bfdb419df37fe711f7bf SHA512 e28c2deb320436606ebf0a971d845e536197ea23c2e7869d3d10dfe5174c8177c7977da37bf01178dc87f875cff2c3f0fbdad63c77578c2334dbfd9d354c19ad
diff --git a/media-gfx/eog/eog-40.2.ebuild b/media-gfx/eog/eog-40.2.ebuild
new file mode 100644
index 000000000000..e0fd2241d634
--- /dev/null
+++ b/media-gfx/eog/eog-40.2.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="The Eye of GNOME image viewer"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome"
+
+LICENSE="GPL-2+"
+SLOT="1"
+
+IUSE="+exif gtk-doc +introspection +jpeg lcms +svg xmp tiff"
+REQUIRED_USE="exif? ( jpeg )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.53.4:2
+	>=dev-libs/libpeas-0.7.4:=[gtk]
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	>=gnome-base/gsettings-desktop-schemas-2.91.92
+	>=x11-misc/shared-mime-info-0.20
+	>=x11-libs/gdk-pixbuf-2.36.5:2[jpeg?,tiff?]
+	>=x11-libs/gtk+-3.22.0:3[introspection,X]
+	sys-libs/zlib
+
+	exif? ( >=media-libs/libexif-0.6.14 )
+	lcms? ( media-libs/lcms:2 )
+	xmp? ( media-libs/exempi:2 )
+	jpeg? ( virtual/jpeg:0 )
+	introspection? ( >=dev-libs/gobject-introspection-1.54:= )
+	svg? ( >=gnome-base/librsvg-2.44.0:2 )
+
+	x11-libs/libX11
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	gtk-doc? ( >=dev-util/gtk-doc-1.16
+		app-text/docbook-xml-dtd:4.1.2 )
+	dev-util/glib-utils
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use exif libexif)
+		$(meson_use lcms cms)
+		$(meson_use xmp)
+		$(meson_use jpeg libjpeg)
+		$(meson_use svg librsvg)
+		$(meson_use gtk-doc gtk_doc)
+		$(meson_use introspection)
+		-Dinstalled_tests=false
+		-Dlibportal=false # Not packaged
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}
-- 
cgit v1.2.3-65-gdbad